lib/CPANPLUS/Dist/Gentoo/Atom.pm

   1 package CPANPLUS::Dist::Gentoo::Atom;
   2
   3 use strict;
   4 use warnings;
   5
   6 =head1 NAME
   7
   8 CPANPLUS::Dist::Gentoo::Atom - Gentoo atom object.
   9
  10 =head1 VERSION
  11
  12 Version 0.10
  13
  14 =cut
  15
  16 our $VERSION = '0.10';
  17
  18 =head1 DESCRIPTION
  19
  20 This class models Gentoo atoms.
  21
  22 =cut
  23
  24 use Carp         ();
  25 use Scalar::Util ();
  26
  27 use overload (
  28  '<=>' => \&_spaceship,
  29  'cmp' => \&_cmp,
  30  '""'  => \&_stringify,
  31 );
  32
  33 use CPANPLUS::Dist::Gentoo::Version;
  34
  35 my $range_rx    = qr/(?:<|<=|=|>=|>)/;
  36 my $name_rx     = qr/[a-zA-Z0-9_+-]+/;
  37 my $category_rx = $name_rx;
  38 my $version_rx  = $CPANPLUS::Dist::Gentoo::Version::version_rx;
  39
  40 =head1 METHODS
  41
  42 =head2 C<< new category => $category, name => $name [, version => $version, range => $range, ebuild => $ebuild ] >>
  43
  44 Creates a new L<CPANPLUS::Dist::Gentoo::Atom> object from the supplied C<$category>, C<$name>, C<$version>, C<$range> and C<$ebuild>.
  45
  46 =cut
  47
  48 sub new {
  49  my $class = shift;
  50  $class = ref($class) || $class;
  51
  52  my %args = @_;
  53
  54  my ($range, $category, $name, $version);
  55  if (defined $args{name}) {
  56   ($range, $category, $name, $version) = @args{qw/range category name version/};
  57   Carp::confess('Category unspecified') unless defined $category;
  58   Carp::confess('Invalid category')     unless $category =~ /^$category_rx$/o;
  59   Carp::confess('Invalid name')         unless $name     =~ /^$name_rx$/o;
  60  } elsif (defined $args{atom}) {
  61   my $atom = $args{atom};
  62   $atom =~ m{^($range_rx)?($category_rx)/($name_rx)(?:-v?($version_rx))?$}o
  63                                                or Carp::confess('Invalid atom');
  64   ($range, $category, $name, $version) = ($1, $2, $3, $4);
  65  } else {
  66   Carp::confess('Not enough information for building an atom object');
  67  }
  68
  69  if (defined $version) {
  70   unless (Scalar::Util::blessed($version)
  71                               and $_->isa('CPANPLUS::Dist::Gentoo::Version')) {
  72    $version = CPANPLUS::Dist::Gentoo::Version->new($version);
  73   }
  74  }
  75
  76  if (defined $version) {
  77   if (defined $range) {
  78    Carp::confess("Invalid range $range") unless $range =~ /^$range_rx$/o;
  79   } else {
  80    $range = '>=';
  81   }
  82  } else {
  83   Carp::confess('Range atoms require a valid version')
  84                                             if defined $range and length $range;
  85  }
  86
  87  bless {
  88   category => $category,
  89   name     => $name,
  90   version  => $version,
  91   range    => $range,
  92   ebuild   => $args{ebuild},
  93  }, $class;
  94 }
  95
  96 =head2 C<new_from_ebuild $ebuild>
  97
  98 Creates a new L<CPANPLUS::Dist::Gentoo::Atom> object by inferring the category, name and version from the given C<$ebuild>
  99
 100 =cut
 101
 102 sub new_from_ebuild {
 103  my $class = shift;
 104  $class = ref($class) || $class;
 105
 106  my $ebuild = shift;
 107  $ebuild = '' unless defined $ebuild;
 108
 109  $ebuild =~ m{/($category_rx)/($name_rx)/\2-v?($version_rx)\.ebuild$}o
 110                                              or Carp::confess('Invalid ebuild');
 111  my ($category, $name, $version) = ($1, $2, $3);
 112
 113  return $class->new(
 114   category => $category,
 115   name     => $name,
 116   version  => $version,
 117   ebuild   => $ebuild,
 118  );
 119 }
 120
 121 BEGIN {
 122  eval "sub $_ { \$_[0]->{$_} }" for qw/category name version range ebuild/;
 123 }
 124
 125 =head2 C<category>
 126
 127 Read-only accessor to the atom category.
 128
 129 =head2 C<name>
 130
 131 Read-only accessor to the atom name.
 132
 133 =head2 C<version>
 134
 135 Read-only accessor to the L<CPANPLUS::Dist::Gentoo::Version> object associated with the atom.
 136
 137 =head2 C<range>
 138
 139 Read-only accessor to the atom range.
 140
 141 =head2 C<ebuild>
 142
 143 Read-only accessor to the path of an optional ebuild associated with the atom.
 144
 145 =head2 C<qualified_name>
 146
 147 Returns the qualified name for the atom, i.e. C<$category/$name>.
 148
 149 =cut
 150
 151 sub qualified_name { join '/', $_[0]->category, $_[0]->name }
 152
 153 sub _spaceship {
 154  my ($a1, $a2, $r) = @_;
 155
 156  my $v1 = $a1->version;
 157
 158  my $v2;
 159  my $blessed = Scalar::Util::blessed($a2);
 160  unless ($blessed and $a2->isa(__PACKAGE__)) {
 161   if ($blessed and $a2->isa('CPANPLUS::Dist::Gentoo::Version')) {
 162    $v2 = $a2;
 163    $a2 = undef;
 164   } else {
 165    my $maybe_atom = eval { __PACKAGE__->new(atom => $a2) };
 166    if (my $err = $@) {
 167     $v2 = eval { CPANPLUS::Dist::Gentoo::Version->new($a2) };
 168     Carp::confess("Can't compare an atom against something that's not an atom, an atom string ($err), a version or a version string ($@)") if $@;
 169     $a2 = undef;
 170    } else {
 171     $a2 = $maybe_atom;
 172    }
 173   }
 174  }
 175
 176  if (defined $a2) {
 177   $v2 = $a2->version;
 178
 179   my $p1 = $a1->qualified_name;
 180   my $p2 = $a2->qualified_name;
 181   Carp::confess("Atoms for different packages $p1 and $p2") unless $p1 eq $p2;
 182  }
 183
 184  ($v1, $v2) = ($v2, $v1) if $r;
 185
 186  return (defined $v1 or 0) <=> (defined $v2 or 0) unless defined $v1
 187                                                      and defined $v2;
 188
 189  return $v1 <=> $v2;
 190 }
 191
 192 sub _cmp {
 193  my ($a1, $a2, $r) = @_;
 194
 195  my $s1 = $a1->qualified_name;
 196  my $v1 = $a1->version;
 197  $s1   .= "-$v1" if defined $v1;
 198
 199  my $s2;
 200  if (Scalar::Util::blessed($a2) and $a2->isa(__PACKAGE__)) {
 201   $s2    = $a2->qualified_name;
 202   my $v2 = $a2->version;
 203   $s2   .= "-$v2" if defined $v2;
 204  } else {
 205   $s2 = $a2;
 206  }
 207
 208  $s1 cmp $s2;
 209 }
 210
 211 sub _stringify {
 212  my ($a) = @_;
 213
 214  my $atom = $a->qualified_name;
 215
 216  my $version = $a->version;
 217  $atom = $a->range . $atom . '-' . $version if defined $version;
 218
 219  return $atom;
 220 }
 221
 222 my %order = (
 223  '<'  => -2,
 224  '<=' => -1,
 225   '=' =>  0,
 226  '>=' =>  1,
 227  '>'  =>  2,
 228 );
 229
 230 =head2 C<and @atoms>
 231
 232 Compute the ranged atom representing the logical AND between C<@atoms> with the same category and name.
 233
 234 =cut
 235
 236 sub and {
 237  shift unless length ref $_[0];
 238
 239  my $a1 = shift;
 240  return $a1 unless @_;
 241
 242  my $a2 = shift;
 243  $a2 = $a2->and(@_) if @_;
 244
 245  my $p1 = $a1->qualified_name;
 246  my $p2 = $a2->qualified_name;
 247  Carp::confess("Atoms for different packages $p1 and $p2") unless $p1 eq $p2;
 248
 249  my $v1 = $a1->version;
 250  return $a2 unless defined $v1;
 251  my $r1 = $a1->range; # Defined if $v1 is defined
 252
 253  my $v2 = $a2->version;
 254  return $a1 unless defined $v2;
 255  my $r2 = $a2->range; # defined if $v2 is defined
 256
 257  my $o1 = $order{$r1};
 258  my $o2 = $order{$r2};
 259
 260  Carp::confess("Incompatible ranges $r1$p1 and $r2$p2") if $o1 * $o2 < 0;
 261
 262  if ($r2 eq '=') {
 263   ($a1, $a2) = ($a2, $a1);
 264   ($v1, $v2) = ($v2, $v1);
 265   ($r1, $r2) = ($r2, $r1);
 266   ($o1, $o2) = ($o2, $o1);
 267  }
 268
 269  if ($r1 eq '=') {
 270   my $r = $r2 eq '=' ? '==' : $r2;
 271   Carp::confess("Version mismatch $v1 $r $v2") unless eval "\$a1 $r \$a2";
 272   return $a1;
 273  } elsif ($o1 > 0) {
 274   return $a1 < $a2 ? $a2 : $a1;
 275  } else {
 276   return $a1 < $a2 ? $a1 : $a2;
 277  }
 278 }
 279
 280 =head2 C<fold @atoms>
 281
 282 Returns a list built from C<@atoms> but where there's only one atom for a given category and name.
 283
 284 =cut
 285
 286 sub fold {
 287  shift unless length ref $_[0];
 288
 289  my %seen;
 290  for my $atom (@_) {
 291   my $key = $atom->qualified_name;
 292
 293   my $cur = $seen{$key};
 294   $seen{$key} = defined $cur ? $cur->and($atom) : $atom;
 295  }
 296
 297  return values %seen;
 298 }
 299
 300 =pod
 301
 302 This class provides overloaded methods for numerical comparison, string comparison and strigification.
 303
 304 =head1 SEE ALSO
 305
 306 L<CPANPLUS::Dist::Gentoo>, L<CPANPLUS::Dist::Gentoo::Version>.
 307
 308 =head1 AUTHOR
 309
 310 Vincent Pit, C<< <perl at profvince.com> >>, L<http://www.profvince.com>.
 311
 312 You can contact me by mail or on C<irc.perl.org> (vincent).
 313
 314 =head1 BUGS
 315
 316 Please report any bugs or feature requests to C<bug-cpanplus-dist-gentoo at rt.cpan.org>, or through the web interface at L<http://rt.cpan.org/NoAuth/ReportBug.html?Queue=CPANPLUS-Dist-Gentoo>.
 317 I will be notified, and then you'll automatically be notified of progress on your bug as I make changes.
 318
 319 =head1 SUPPORT
 320
 321 You can find documentation for this module with the perldoc command.
 322
 323     perldoc CPANPLUS::Dist::Gentoo
 324
 325 =head1 COPYRIGHT & LICENSE
 326
 327 Copyright 2009,2010 Vincent Pit, all rights reserved.
 328
 329 This program is free software; you can redistribute it and/or modify it under the same terms as Perl itself.
 330
 331 =cut
 332
 333 1; # End of CPANPLUS::Dist::Gentoo::Atom