lib/CPANPLUS/Dist/Gentoo.pm

   1 package CPANPLUS::Dist::Gentoo;
   2
   3 use strict;
   4 use warnings;
   5
   6 use Cwd qw/abs_path/;
   7 use File::Copy qw/copy/;
   8 use File::Path qw/mkpath/;
   9 use File::Spec::Functions qw/catdir catfile/;
  10
  11 use IPC::Cmd qw/run can_run/;
  12
  13 use CPANPLUS::Error;
  14
  15 use base qw/CPANPLUS::Dist::Base/;
  16
  17 =head1 NAME
  18
  19 CPANPLUS::Dist::Gentoo - CPANPLUS backend generating Gentoo ebuilds.
  20
  21 =head1 VERSION
  22
  23 Version 0.04
  24
  25 =cut
  26
  27 our $VERSION = '0.04';
  28
  29 =head1 SYNOPSIS
  30
  31     cpan2dist --format=CPANPLUS::Dist::Gentoo \
  32               --dist-opts overlay=/usr/local/portage \
  33               --dist-opts distdir=/usr/portage/distfiles \
  34               --dist-opts manifest=yes \
  35               --dist-opts keywords=x86 \
  36               --dist-opts header="# Copyright 1999-2008 Gentoo Foundation" \
  37               --dist-opts footer="# End" \
  38               Any::Module You::Like
  39
  40 =head1 DESCRPITON
  41
  42 This module is a CPANPLUS backend that recursively generates Gentoo ebuilds for a given package in the specified overlay (defaults to F</usr/local/portage>), updates the manifest, and even emerges it (together with its dependencies) if the user requires it. You need write permissions on the directory where Gentoo fetches its source files (usually F</usr/portage/distfiles>). The valid C<KEYWORDS> for the generated ebuilds are by default those given in C<ACCEPT_KEYWORDS>, but you can specify your own with the C<keywords> dist-option.
  43
  44 The generated ebuilds are placed into the C<perl-gcpanp> category. They favour depending on C<perl-core>, C<dev-perl> or C<perl-gcpan> (in that order) rather than C<perl-gcpanp>.
  45
  46 =head1 INSTALLATION
  47
  48 After installing this module, you should append C<perl-gcpanp> to your F</etc/portage/categories> file.
  49
  50 =head1 METHODS
  51
  52 All the methods are inherited from L<CPANPLUS::Dist::Base>. Please refer to its documentation for precise information on what's done at each step.
  53
  54 =cut
  55
  56 use constant CATEGORY => 'perl-gcpanp';
  57
  58 my $overlays;
  59 my $default_keywords;
  60
  61 sub format_available {
  62  for my $prog (qw/emerge ebuild/) {
  63   unless (can_run($prog)) {
  64    error "$prog is required to write ebuilds -- aborting";
  65    return 0;
  66   }
  67  }
  68
  69  if (IPC::Cmd->can_capture_buffer) {
  70   my ($success, $errmsg, $output) = run command => [ qw/emerge --info/ ],
  71                                         verbose => 0;
  72   if ($success) {
  73    for (@{$output || []}) {
  74     if (/^PORTDIR_OVERLAY=(.*)$/m) {
  75      my $o = $1;
  76      $o =~ s/^["']*//;
  77      $o =~ s/["']*$//;
  78      $overlays = [ map abs_path($_), grep length, split /:/, $o ];
  79     }
  80     if (/^ACCEPT_KEYWORDS=(.*)$/m) {
  81      my $k = $1;
  82      $k =~ s/^["']*//;
  83      $k =~ s/["']*$//;
  84      $default_keywords = [ split ' ', $k ];
  85     }
  86    }
  87   } else {
  88    error $errmsg;
  89   }
  90  }
  91
  92  $default_keywords = [ 'x86' ] unless defined $default_keywords;
  93
  94  return 1;
  95 }
  96
  97 sub init {
  98  my ($self) = @_;
  99  my $stat = $self->status;
 100  my $conf = $self->parent->parent->configure_object;
 101
 102  $stat->mk_accessors(qw/name version author distribution desc uri license
 103                         deps eb_name eb_version eb_dir eb_file fetched_arch
 104                         portdir_overlay
 105                         overlay distdir keywords do_manifest header footer
 106                         force verbose/);
 107
 108  $stat->force($conf->get_conf('force'));
 109  $stat->verbose($conf->get_conf('verbose'));
 110
 111  return 1;
 112 }
 113
 114 my %gentooism = (
 115  'ANSIColor'               => 'Term-ANSIColor',
 116  'Audio-CD'                => 'Audio-CD-disc-cover',
 117  'CGI-Simple'              => 'Cgi-Simple',
 118  'Cache-Mmap'              => 'cache-mmap',
 119  'Class-Loader'            => 'class-loader',
 120  'Class-ReturnValue'       => 'class-returnvalue',
 121  'Config-General'          => 'config-general',
 122  'Convert-ASCII-Armour'    => 'convert-ascii-armour',
 123  'Convert-PEM'             => 'convert-pem',
 124  'Crypt-CBC'               => 'crypt-cbc',
 125  'Crypt-DES_EDE3'          => 'crypt-des-ede3',
 126  'Crypt-DH'                => 'crypt-dh',
 127  'Crypt-DSA'               => 'crypt-dsa',
 128  'Crypt-IDEA'              => 'crypt-idea',
 129  'Crypt-Primes'            => 'crypt-primes',
 130  'Crypt-RSA'               => 'crypt-rsa',
 131  'Crypt-Random'            => 'crypt-random',
 132  'DBIx-SearchBuilder'      => 'dbix-searchbuilder',
 133  'Data-Buffer'             => 'data-buffer',
 134  'Digest'                  => 'digest-base',
 135  'Digest-BubbleBabble'     => 'digest-bubblebabble',
 136  'Digest-MD2'              => 'digest-md2',
 137  'ExtUtils-Depends'        => 'extutils-depends',
 138  'ExtUtils-PkgConfig'      => 'extutils-pkgconfig',
 139  'Frontier-RPC'            => 'frontier-rpc',
 140  'Gimp'                    => 'gimp-perl',
 141  'Glib'                    => 'glib-perl',
 142  'Gnome2-Canvas'           => 'gnome2-canvas',
 143  'Gnome2-GConf'            => 'gnome2-gconf',
 144  'Gnome2-Print'            => 'gnome2-print',
 145  'Gnome2-VFS'              => 'gnome2-vfs-perl',
 146  'Gnome2-Wnck'             => 'gnome2-wnck',
 147  'Gtk2'                    => 'gtk2-perl',
 148  'Gtk2-Ex-FormFactory'     => 'gtk2-ex-formfactory',
 149  'Gtk2-GladeXML'           => 'gtk2-gladexml',
 150  'Gtk2-Spell'              => 'gtk2-spell',
 151  'Gtk2-TrayIcon'           => 'gtk2-trayicon',
 152  'Gtk2-TrayManager'        => 'gtk2-traymanager',
 153  'Gtk2Fu'                  => 'gtk2-fu',
 154  'I18N-LangTags'           => 'i18n-langtags',
 155  'Image-Info'              => 'ImageInfo',
 156  'Image-Size'              => 'ImageSize',
 157  'Inline-Files'            => 'inline-files',
 158  'Locale-Maketext'         => 'locale-maketext',
 159  'Locale-Maketext-Fuzzy'   => 'locale-maketext-fuzzy',
 160  'Locale-Maketext-Lexicon' => 'locale-maketext-lexicon',
 161  'Log-Dispatch'            => 'log-dispatch',
 162  'Math-Pari'               => 'math-pari',
 163  'Module-Info'             => 'module-info',
 164  'Net-Ping'                => 'net-ping',
 165  'Net-SFTP'                => 'net-sftp',
 166  'Net-SSH-Perl'            => 'net-ssh-perl',
 167  'Net-Server'              => 'net-server',
 168  'OLE-Storage_Lite'        => 'OLE-StorageLite',
 169  'Ogg-Vorbis-Header'       => 'ogg-vorbis-header',
 170  'PathTools'               => 'File-Spec',
 171  'Pod-Parser'              => 'PodParser',
 172  'Regexp-Common'           => 'regexp-common',
 173  'SDL_Perl'                => 'sdl-perl',
 174  'Set-Scalar'              => 'set-scalar',
 175  'String-CRC32'            => 'string-crc32',
 176  'Text-Autoformat'         => 'text-autoformat',
 177  'Text-Reform'             => 'text-reform',
 178  'Text-Template'           => 'text-template',
 179  'Text-Wrapper'            => 'text-wrapper',
 180  'Tie-EncryptedHash'       => 'tie-encryptedhash',
 181  'Tk'                      => 'perl-tk',
 182  'Wx'                      => 'wxperl',
 183  'YAML'                    => 'yaml',
 184  'gettext'                 => 'Locale-gettext',
 185  'txt2html'                => 'TextToHTML',
 186 );
 187
 188 sub prepare {
 189  my $self = shift;
 190  my $mod  = $self->parent;
 191  my $stat = $self->status;
 192  my $int  = $mod->parent;
 193  my $conf = $int->configure_object;
 194
 195  my %opts = @_;
 196
 197  $stat->prepared(0);
 198
 199  my $keywords = delete $opts{'keywords'};
 200  if (defined $keywords) {
 201   $keywords = [ split ' ', $keywords ];
 202  } else {
 203   $keywords = $default_keywords;
 204  }
 205  $stat->keywords($keywords);
 206
 207  my $manifest = delete $opts{'manifest'};
 208  $manifest = 1 unless defined $manifest;
 209  $manifest = 0 if $manifest =~ /^\s*no?\s*$/i;
 210  $stat->do_manifest($manifest);
 211
 212  my $header = delete $opts{'header'};
 213  if (defined $header) {
 214   1 while chomp $header;
 215   $header .= "\n\n";
 216  } else {
 217   $header = '';
 218  }
 219  $stat->header($header);
 220
 221  my $footer = delete $opts{'footer'};
 222  if (defined $footer) {
 223   $footer = "\n" . $footer;
 224  } else {
 225   $footer = '';
 226  }
 227  $stat->footer($footer);
 228
 229  my $overlay = delete $opts{'overlay'};
 230  $overlay = (defined $overlay) ? abs_path $overlay : '/usr/local/portage';
 231  $stat->overlay($overlay);
 232
 233  my $distdir = delete $opts{'distdir'};
 234  $distdir = (defined $distdir) ? abs_path $distdir : '/usr/portage/distfiles';
 235  $stat->distdir($distdir);
 236
 237  if ($stat->do_manifest && !-w $stat->distdir) {
 238   error 'distdir isn\'t writable -- aborting';
 239   return 0;
 240  }
 241  $stat->fetched_arch($mod->status->fetch);
 242
 243  my $cur = File::Spec::Functions::curdir();
 244  my $portdir_overlay;
 245  for (@$overlays) {
 246   if ($_ eq $overlay or File::Spec::Functions::abs2rel($overlay, $_) eq $cur) {
 247    $portdir_overlay = join ':', @$overlays;
 248    last;
 249   }
 250  }
 251  $portdir_overlay = join ':', @$overlays, $overlay
 252                                                 unless defined $portdir_overlay;
 253  $stat->portdir_overlay($portdir_overlay);
 254
 255  my $name = $mod->package_name;
 256  $stat->name($name);
 257
 258  my $version = $mod->package_version;
 259  $stat->version($version);
 260
 261  my $author = $mod->author->cpanid;
 262  $stat->author($author);
 263
 264  $stat->distribution($name . '-' . $version);
 265
 266  $version =~ s/[^\d._]+//g;
 267  $version =~ s/^[._]*//;
 268  $version =~ s/[._]*$//;
 269  $version =~ s/[._]*_[._]*/_/g;
 270  {
 271   ($version, my $patch, my @rest) = split /_/, $version;
 272   $version .= '_p' . $patch if defined $patch;
 273   $version .= join('.', '', @rest) if @rest;
 274  }
 275  $stat->eb_version($version);
 276
 277  $stat->eb_name($gentooism{$name} || $name);
 278
 279  $stat->eb_dir(catdir($stat->overlay, CATEGORY, $stat->eb_name));
 280
 281  my $file = catfile($stat->eb_dir,
 282                     $stat->eb_name . '-' . $stat->eb_version . '.ebuild');
 283  $stat->eb_file($file);
 284
 285  if (-e $file) {
 286   my $skip = 1;
 287   if ($stat->force) {
 288    if (-w $file) {
 289     1 while unlink $file;
 290     $skip = 0;
 291    } else {
 292     error "Can't force rewriting of $file -- skipping";
 293    }
 294   } else {
 295    msg 'Ebuild already generated for ' . $stat->distribution . ' -- skipping';
 296   }
 297   if ($skip) {
 298    $stat->prepared(1);
 299    $stat->created(1);
 300    $stat->dist($file);
 301    return 1;
 302   }
 303  }
 304
 305  $self->SUPER::prepare(%opts);
 306
 307  $stat->prepared(0);
 308
 309  my $desc = $mod->description;
 310  ($desc = $name) =~ s/-+/::/g unless $desc;
 311  $stat->desc($desc);
 312
 313  $stat->uri('http://search.cpan.org/dist/' . $name);
 314
 315  $stat->license([ qw/Artistic GPL-2/ ]);
 316
 317  my $prereqs = $mod->status->prereqs;
 318  my @depends;
 319  for my $prereq (sort keys %$prereqs) {
 320   next if $prereq =~ /^perl(?:-|\z)/;
 321   my $obj = $int->module_tree($prereq);
 322   unless ($obj) {
 323    error 'Wrong module object -- aborting';
 324    return 0;
 325   }
 326   next if $obj->package_is_perl_core;
 327   {
 328    my $version;
 329    if ($prereqs->{$prereq}) {
 330     if ($obj->installed_version && $obj->installed_version < $obj->version) {
 331      $version = $obj->installed_version;
 332     } else {
 333      $version = $obj->package_version;
 334     }
 335    }
 336    push @depends, [ $obj , $version ];
 337   }
 338  }
 339  $stat->deps(\@depends);
 340
 341  $stat->prepared(1);
 342  return 1;
 343 }
 344
 345 sub create {
 346  my $self = shift;
 347  my $stat = $self->status;
 348
 349  unless ($stat->prepared) {
 350   error 'Can\'t create ' . $stat->distribution . ' since it was never prepared -- aborting';
 351   $stat->created(0);
 352   $stat->dist(undef);
 353   return 0;
 354  }
 355
 356  if ($stat->created) {
 357   msg $stat->distribution . ' was already created -- skipping';
 358   $stat->dist($stat->eb_file);
 359   return 1;
 360  }
 361
 362  $stat->created(0);
 363  $stat->dist(undef);
 364
 365  $self->SUPER::create(@_);
 366
 367  $stat->created(0);
 368  $stat->dist(undef);
 369
 370  my $dir = $stat->eb_dir;
 371  unless (-d $dir) {
 372   eval { mkpath $dir };
 373   if ($@) {
 374    error "mkpath($dir): $@";
 375    return 0;
 376   }
 377  }
 378
 379  my $d = $stat->header;
 380  $d   .= "# Generated by CPANPLUS::Dist::Gentoo version $VERSION\n\n";
 381  $d   .= 'MODULE_AUTHOR="' . $stat->author . "\"\ninherit perl-module\n\n";
 382  $d   .= 'DESCRIPTION="' . $stat->desc . "\"\n";
 383  $d   .= 'HOMEPAGE="' . $stat->uri . "\"\n\n";
 384  $d   .= "SLOT=\"0\"\n";
 385  $d   .= 'LICENSE="|| ( ' . join(' ', sort @{$stat->license}) . " )\"\n";
 386  $d   .= 'KEYWORDS="' . join(' ', sort @{$stat->keywords}) . "\"\n";
 387  $d   .= 'DEPEND="' . join "\n",
 388   'dev-lang/perl',
 389   map {
 390    my $a = $_->[0]->package_name;
 391    $a = $gentooism{$a} || $a;
 392    my $x = '';
 393    if (defined $_->[1]) {
 394     $x  = '>=';
 395     $a .= '-' . $_->[1];
 396    }
 397    '|| ( ' . join(' ', map "$x$_/$a",
 398                            qw/perl-core dev-perl perl-gcpan/, CATEGORY)
 399            . ' )';
 400   } @{$stat->deps};
 401  $d   .= "\"\n";
 402  $d   .= "SRC_TEST=\"do\"\n";
 403  $d   .= $stat->footer;
 404
 405  my $file = $stat->eb_file;
 406  open my $eb, '>', $file or do {
 407   error "open($file): $! -- aborting";
 408   return 0;
 409  };
 410  print $eb $d;
 411  close $eb;
 412
 413  if ($stat->do_manifest) {
 414   unless (copy $stat->fetched_arch, $stat->distdir) {
 415    error "Couldn\'t copy the distribution file to distdir ($!) -- aborting";
 416    1 while unlink $file;
 417    return 0;
 418   }
 419
 420   msg 'Adding Manifest entry for ' . $stat->distribution;
 421   unless ($self->_run([ 'ebuild', $file, 'manifest' ], 0)) {
 422    1 while unlink $file;
 423    return 0;
 424   }
 425  }
 426
 427  $stat->created(1);
 428  $stat->dist($file);
 429  return 1;
 430 }
 431
 432 sub install {
 433  my $self = shift;
 434  my $stat = $self->status;
 435  my $conf = $self->parent->parent->configure_object;
 436
 437  my $sudo = $conf->get_program('sudo');
 438  my @cmd = ('emerge', '=' . $stat->eb_name . '-' . $stat->eb_version);
 439  unshift @cmd, $sudo if $sudo;
 440
 441  my $success = $self->_run(\@cmd, 1);
 442  $stat->installed($success);
 443
 444  return $success;
 445 }
 446
 447 sub uninstall {
 448  my $self = shift;
 449  my $stat = $self->status;
 450  my $conf = $self->parent->parent->configure_object;
 451
 452  my $sudo = $conf->get_program('sudo');
 453  my @cmd = ('emerge', '-C', '=' . $stat->eb_name . '-' . $stat->eb_version);
 454  unshift @cmd, $sudo if $sudo;
 455
 456  my $success = $self->_run(\@cmd, 1);
 457  $stat->uninstalled($success);
 458
 459  return $success;
 460 }
 461
 462 sub _run {
 463  my ($self, $cmd, $verbose) = @_;
 464  my $stat = $self->status;
 465
 466  my ($success, $errmsg, $output) = do {
 467   local $ENV{PORTDIR_OVERLAY}     = $stat->portdir_overlay;
 468   local $ENV{PORTAGE_RO_DISTDIRS} = $stat->distdir;
 469   run command => $cmd, verbose => $verbose;
 470  };
 471
 472  unless ($success) {
 473   error "$errmsg -- aborting";
 474   if (not $verbose and defined $output and $self->status->verbose) {
 475    my $msg = join '', @$output;
 476    1 while chomp $msg;
 477    error $msg;
 478   }
 479  }
 480
 481  return $success;
 482 }
 483
 484 =head1 DEPENDENCIES
 485
 486 Gentoo (L<http://gentoo.org>).
 487
 488 L<CPANPLUS>, L<IPC::Cmd> (core modules since 5.9.5).
 489
 490 L<Cwd> (since perl 5) L<File::Path> (5.001), L<File::Copy> (5.002), L<File::Spec::Functions> (5.00504).
 491
 492 =head1 SEE ALSO
 493
 494 L<cpan2dist>.
 495
 496 L<CPANPLUS::Dist::Base>, L<CPANPLUS::Dist::Deb>, L<CPANPLUS::Dist::Mdv>.
 497
 498 =head1 AUTHOR
 499
 500 Vincent Pit, C<< <perl at profvince.com> >>, L<http://www.profvince.com>.
 501
 502 You can contact me by mail or on C<irc.perl.org> (vincent).
 503
 504 =head1 BUGS
 505
 506 Please report any bugs or feature requests to C<bug-cpanplus-dist-gentoo at rt.cpan.org>, or through the web interface at L<http://rt.cpan.org/NoAuth/ReportBug.html?Queue=CPANPLUS-Dist-Gentoo>.  I will be notified, and then you'll automatically be notified of progress on your bug as I make changes.
 507
 508 =head1 SUPPORT
 509
 510 You can find documentation for this module with the perldoc command.
 511
 512     perldoc CPANPLUS::Dist::Gentoo
 513
 514 =head1 ACKNOWLEDGEMENTS
 515
 516 The module is to some extend cargo-culted from L<CPANPLUS::Dist::Deb> and L<CPANPLUS::Dist::Mdv>.
 517
 518 Kent Fredric, for testing and suggesting improvements.
 519
 520 =head1 COPYRIGHT & LICENSE
 521
 522 Copyright 2008 Vincent Pit, all rights reserved.
 523
 524 This program is free software; you can redistribute it and/or modify it under the same terms as Perl itself.
 525
 526 =cut
 527
 528 1; # End of CPANPLUS::Dist::Gentoo