lib/CPANPLUS/Dist/Gentoo.pm

   1 package CPANPLUS::Dist::Gentoo;
   2
   3 use strict;
   4 use warnings;
   5
   6 use Cwd qw/abs_path/;
   7 use File::Copy qw/copy/;
   8 use File::Path qw/mkpath/;
   9 use File::Spec::Functions qw/catdir catfile/;
  10
  11 use IPC::Cmd qw/run can_run/;
  12
  13 use CPANPLUS::Error;
  14
  15 use base qw/CPANPLUS::Dist::Base/;
  16
  17 =head1 NAME
  18
  19 CPANPLUS::Dist::Gentoo - CPANPLUS backend generating Gentoo ebuilds.
  20
  21 =head1 VERSION
  22
  23 Version 0.04
  24
  25 =cut
  26
  27 our $VERSION = '0.04';
  28
  29 =head1 SYNOPSIS
  30
  31     cpan2dist --format=CPANPLUS::Dist::Gentoo \
  32               --dist-opts overlay=/usr/local/portage \
  33               --dist-opts distdir=/usr/portage/distfiles \
  34               --dist-opts manifest=yes \
  35               --dist-opts keywords=x86 \
  36               --dist-opts header="# Copyright 1999-2008 Gentoo Foundation" \
  37               --dist-opts footer="# End" \
  38               Any::Module You::Like
  39
  40 =head1 DESCRPITON
  41
  42 This module is a CPANPLUS backend that recursively generates Gentoo ebuilds for a given package in the specified overlay (defaults to F</usr/local/portage>), updates the manifest, and even emerges it (together with its dependencies) if the user requires it. You need write permissions on the directory where Gentoo fetches its source files (usually F</usr/portage/distfiles>). You also need to specify the correct keyword for your architecture if it differs from the default C<x86>.
  43
  44 The generated ebuilds are placed into the C<perl-gcpanp> category. They favour depending on C<perl-core>, C<dev-perl> or C<perl-gcpan> (in that order) rather than C<perl-gcpanp>.
  45
  46 =head1 INSTALLATION
  47
  48 After installing this module, you should append C<perl-gcpanp> to your F</etc/portage/categories> file.
  49
  50 =head1 METHODS
  51
  52 All the methods are inherited from L<CPANPLUS::Dist::Base>. Please refer to its documentation for precise information on what's done at each step.
  53
  54 =cut
  55
  56 use constant CATEGORY => 'perl-gcpanp';
  57
  58 sub format_available {
  59  for my $prog (qw/emerge ebuild/) {
  60   unless (can_run($prog)) {
  61    error "$prog is required to write ebuilds -- aborting";
  62    return 0;
  63   }
  64  }
  65  return 1;
  66 }
  67
  68 sub init {
  69  my ($self) = @_;
  70  my $stat = $self->status;
  71  my $conf = $self->parent->parent->configure_object;
  72
  73  $stat->mk_accessors(qw/name version author dist desc uri src license deps
  74                         eb_name eb_version eb_dir eb_file fetched_arch
  75                         overlay distdir keywords do_manifest header footer
  76                         force verbose/);
  77
  78  $stat->force($conf->get_conf('force'));
  79  $stat->verbose($conf->get_conf('verbose'));
  80
  81  return 1;
  82 }
  83
  84 my %gentooism = (
  85  'Crypt-RSA'         => 'crypt-rsa',
  86  'Digest'            => 'digest-base',
  87  'Locale-Maketext'   => 'locale-maketext',
  88  'Math-Pari'         => 'math-pari',
  89  'Net-Ping'          => 'net-ping',
  90  'PathTools'         => 'File-Spec',
  91  'PodParser'         => 'Pod-Parser',
  92  'Set-Scalar'        => 'set-scalar',
  93  'Tie-EncryptedHash' => 'tie-encryptedhash',
  94  'YAML'              => 'yaml',
  95 );
  96
  97 sub prepare {
  98  my $self = shift;
  99  my $mod  = $self->parent;
 100  my $stat = $self->status;
 101  my $int  = $mod->parent;
 102  my $conf = $int->configure_object;
 103
 104  my %opts = @_;
 105
 106  my $keywords = delete $opts{'keywords'};
 107  $keywords = 'x86' unless defined $keywords;
 108  $keywords = [ split ' ', $keywords ];
 109  $stat->keywords($keywords);
 110
 111  my $manifest = delete $opts{'manifest'};
 112  $manifest = 1 unless defined $manifest;
 113  $manifest = 0 if $manifest =~ /^\s*no?\s*$/i;
 114  $stat->do_manifest($manifest);
 115
 116  my $header = delete $opts{'header'};
 117  if (defined $header) {
 118   1 while chomp $header;
 119   $header .= "\n\n";
 120  } else {
 121   $header = '';
 122  }
 123  $stat->header($header);
 124
 125  my $footer = delete $opts{'footer'};
 126  if (defined $footer) {
 127   $footer = "\n" . $footer;
 128  } else {
 129   $footer = '';
 130  }
 131  $stat->footer($footer);
 132
 133  my $overlay = delete $opts{'overlay'};
 134  $overlay = (defined $overlay) ? abs_path $overlay : '/usr/local/portage';
 135  $stat->overlay($overlay);
 136
 137  my $distdir = delete $opts{'distdir'};
 138  $distdir = (defined $distdir) ? abs_path $distdir : '/usr/portage/distfiles';
 139  $stat->distdir($distdir);
 140
 141  if ($stat->do_manifest && !-w $stat->distdir) {
 142   error 'distdir isn\'t writable -- aborting';
 143   return 0;
 144  }
 145  $stat->fetched_arch($mod->status->fetch);
 146
 147  my $name = $mod->package_name;
 148  $stat->name($name);
 149
 150  my $version = $mod->package_version;
 151  $stat->version($version);
 152
 153  my $author = $mod->author->cpanid;
 154  $stat->author($author);
 155
 156  $stat->dist($name . '-' . $version);
 157
 158  $version =~ s/[^\d._]+//g;
 159  $version =~ s/^[._]*//;
 160  $version =~ s/[._]*$//;
 161  $version =~ s/[._]*_[._]*/_/g;
 162  {
 163   ($version, my $patch, my @rest) = split /_/, $version;
 164   $version .= '_p' . $patch if defined $patch;
 165   $version .= join('.', '', @rest) if @rest;
 166  }
 167  $stat->eb_version($version);
 168
 169  $stat->eb_name($gentooism{$name} || $name);
 170
 171  $stat->eb_dir(catdir($stat->overlay, CATEGORY, $stat->eb_name));
 172
 173  my $file = catfile($stat->eb_dir,
 174                     $stat->eb_name . '-' . $stat->eb_version . '.ebuild');
 175  if (-e $file) {
 176   my $skip = 1;
 177   if ($stat->force) {
 178    if (-w $file) {
 179     1 while unlink $file;
 180     $skip = 0;
 181    } else {
 182     error "Can't force rewriting of $file -- skipping";
 183    }
 184   } else {
 185    msg 'Ebuild already generated for ' . $stat->dist . ' -- skipping';
 186   }
 187   if ($skip) {
 188    $stat->prepared(1);
 189    $stat->created(1);
 190    return 1;
 191   }
 192  }
 193  $stat->eb_file($file);
 194
 195  $self->SUPER::prepare(%opts);
 196
 197  my $desc = $mod->description;
 198  ($desc = $name) =~ s/-+/::/g unless $desc;
 199  $stat->desc($desc);
 200
 201  $stat->uri('http://search.cpan.org/dist/' . $name);
 202
 203  unless ($author =~ /^(.)(.)/) {
 204   error 'Wrong author name -- aborting';
 205   return 0;
 206  }
 207  $stat->src("mirror://cpan/modules/by-authors/id/$1/$1$2/$author/"
 208             . $mod->package);
 209
 210  $stat->license([ qw/Artistic GPL-2/ ]);
 211
 212  my $prereqs = $mod->status->prereqs;
 213  my @depends;
 214  for my $prereq (sort keys %$prereqs) {
 215   next if $prereq =~ /^perl(?:-|\z)/;
 216   my $obj = $int->module_tree($prereq);
 217   unless ($obj) {
 218    error 'Wrong module object -- aborting';
 219    return 0;
 220   }
 221   next if $obj->package_is_perl_core;
 222   {
 223    my $version;
 224    if ($prereqs->{$prereq}) {
 225     if ($obj->installed_version && $obj->installed_version < $obj->version) {
 226      $version = $obj->installed_version;
 227     } else {
 228      $version = $obj->package_version;
 229     }
 230    }
 231    push @depends, [ $obj , $version ];
 232   }
 233  }
 234  $stat->deps(\@depends);
 235
 236  return 1;
 237 }
 238
 239 sub create {
 240  my $self = shift;
 241  my $stat = $self->status;
 242
 243  unless ($stat->prepared) {
 244   error 'Can\'t create ' . $stat->dist . ' since it was never prepared -- aborting';
 245   return 0;
 246  }
 247
 248  if ($stat->created) {
 249   msg $stat->dist . ' was already created -- skipping';
 250   return 1;
 251  }
 252
 253  $self->SUPER::create(@_);
 254
 255  my $dir = $stat->eb_dir;
 256  unless (-d $dir) {
 257   eval { mkpath $dir };
 258   if ($@) {
 259    error "mkpath($dir): $@";
 260    return 0;
 261   }
 262  }
 263
 264  my $d = $stat->header;
 265  $d   .= "# Generated by CPANPLUS::Dist::Gentoo version $VERSION\n\n";
 266  $d   .= 'MODULE_AUTHOR="' . $stat->author . "\"\ninherit perl-module\n\n";
 267  $d   .= 'S="${WORKDIR}/' . $stat->dist . "\"\n";
 268  $d   .= 'DESCRIPTION="' . $stat->desc . "\"\n";
 269  $d   .= 'HOMEPAGE="' . $stat->uri . "\"\n";
 270  $d   .= 'SRC_URI="' . $stat->src . "\"\n";
 271  $d   .= "SLOT=\"0\"\n";
 272  $d   .= 'LICENSE="|| ( ' . join(' ', sort @{$stat->license}) . " )\"\n";
 273  $d   .= 'KEYWORDS="' . join(' ', sort @{$stat->keywords}) . "\"\n";
 274  $d   .= 'DEPEND="' . join "\n",
 275   'dev-lang/perl',
 276   map {
 277    my $a = $_->[0]->package_name;
 278    $a = $gentooism{$a} || $a;
 279    my $x = '';
 280    if (defined $_->[1]) {
 281     $x  = '>=';
 282     $a .= '-' . $_->[1];
 283    }
 284    '|| ( ' . join(' ', map "$x$_/$a",
 285                            qw/perl-core dev-perl perl-gcpan/, CATEGORY)
 286            . ' )';
 287   } @{$stat->deps};
 288  $d   .= "\"\n";
 289  $d   .= "SRC_TEST=\"do\"\n";
 290  $d   .= $stat->footer;
 291
 292  my $file = $stat->eb_file;
 293  open my $eb, '>', $file or do {
 294   error "open($file): $! -- aborting";
 295   return 0;
 296  };
 297  print $eb $d;
 298  close $eb;
 299
 300  if ($stat->do_manifest) {
 301   unless (copy $stat->fetched_arch, $stat->distdir) {
 302    error "Couldn\'t copy the distribution file to distdir ($!) -- aborting";
 303    1 while unlink $file;
 304    return 0;
 305   }
 306
 307   msg 'Adding Manifest entry for ' . $stat->dist;
 308   unless ($self->_run([ 'ebuild', $file, 'manifest' ], 0)) {
 309    1 while unlink $file;
 310    return 0;
 311   }
 312  }
 313
 314  return 1;
 315 }
 316
 317 sub install {
 318  my $self = shift;
 319  my $stat = $self->status;
 320  my $conf = $self->parent->parent->configure_object;
 321
 322  my $sudo = $conf->get_program('sudo');
 323  my @cmd = ('emerge', '=' . $stat->eb_name . '-' . $stat->eb_version);
 324  unshift @cmd, $sudo if $sudo;
 325
 326  return $self->_run(\@cmd, 1);
 327 }
 328
 329 sub uninstall {
 330  my $self = shift;
 331  my $stat = $self->status;
 332  my $conf = $self->parent->parent->configure_object;
 333
 334  my $sudo = $conf->get_program('sudo');
 335  my @cmd = ('emerge', '-C', '=' . $stat->eb_name . '-' . $stat->eb_version);
 336  unshift @cmd, $sudo if $sudo;
 337
 338  return $self->_run(\@cmd, 1);
 339 }
 340
 341 sub _run {
 342  my ($self, $cmd, $verbose) = @_;
 343  my $stat = $self->status;
 344
 345  my ($success, $errmsg, $output) = do {
 346   local $ENV{PORTDIR_OVERLAY}     = $stat->overlay;
 347   local $ENV{PORTAGE_RO_DISTDIRS} = $stat->distdir;
 348   run command => $cmd, verbose => $verbose;
 349  };
 350
 351  unless ($success) {
 352   error "$errmsg -- aborting";
 353   if (not $verbose and defined $output and $self->status->verbose) {
 354    my $msg = join '', @$output;
 355    1 while chomp $msg;
 356    error $msg;
 357   }
 358  }
 359
 360  return $success;
 361 }
 362
 363 =head1 DEPENDENCIES
 364
 365 Gentoo (L<http://gentoo.org>).
 366
 367 L<CPANPLUS>, L<IPC::Cmd> (core modules since 5.9.5).
 368
 369 L<Cwd> (since perl 5) L<File::Path> (5.001), L<File::Copy> (5.002), L<File::Spec::Functions> (5.00504).
 370
 371 =head1 SEE ALSO
 372
 373 L<cpan2dist>.
 374
 375 L<CPANPLUS::Dist::Base>, L<CPANPLUS::Dist::Deb>, L<CPANPLUS::Dist::Mdv>.
 376
 377 =head1 AUTHOR
 378
 379 Vincent Pit, C<< <perl at profvince.com> >>, L<http://www.profvince.com>.
 380
 381 You can contact me by mail or on C<irc.perl.org> (vincent).
 382
 383 =head1 BUGS
 384
 385 Please report any bugs or feature requests to C<bug-cpanplus-dist-gentoo at rt.cpan.org>, or through the web interface at L<http://rt.cpan.org/NoAuth/ReportBug.html?Queue=CPANPLUS-Dist-Gentoo>.  I will be notified, and then you'll automatically be notified of progress on your bug as I make changes.
 386
 387 =head1 SUPPORT
 388
 389 You can find documentation for this module with the perldoc command.
 390
 391     perldoc CPANPLUS::Dist::Gentoo
 392
 393 =head1 ACKNOWLEDGEMENTS
 394
 395 The module is to some extend cargo-culted from L<CPANPLUS::Dist::Deb> and L<CPANPLUS::Dist::Mdv>.
 396
 397 Kent Fredric, for testing and suggesting improvements.
 398
 399 =head1 COPYRIGHT & LICENSE
 400
 401 Copyright 2008 Vincent Pit, all rights reserved.
 402
 403 This program is free software; you can redistribute it and/or modify it under the same terms as Perl itself.
 404
 405 =cut
 406
 407 1; # End of CPANPLUS::Dist::Gentoo