lib/CPANPLUS/Dist/Gentoo.pm

   1 package CPANPLUS::Dist::Gentoo;
   2
   3 use strict;
   4 use warnings;
   5
   6 use File::Copy qw/copy/;
   7 use File::Path qw/mkpath/;
   8 use File::Spec::Functions qw/catdir catfile/;
   9
  10 use IPC::Cmd qw/run can_run/;
  11
  12 use CPANPLUS::Error;
  13
  14 use base qw/CPANPLUS::Dist::Base/;
  15
  16 =head1 NAME
  17
  18 CPANPLUS::Dist::Gentoo - CPANPLUS backend generating Gentoo ebuilds.
  19
  20 =head1 VERSION
  21
  22 Version 0.02_01
  23
  24 =cut
  25
  26 our $VERSION = '0.02_01';
  27
  28 =head1 SYNOPSIS
  29
  30     cpan2dist --format=CPANPLUS::Dist::Gentoo \
  31               --dist-opts overlay=/usr/local/portage \
  32               --dist-opts distdir=/usr/portage/distfiles \
  33               --dist-opts manifest=yes \
  34               --dist-opts keywords=x86 \
  35               Any::Module You::Like
  36
  37 =head1 DESCRPITON
  38
  39 This module is a CPANPLUS backend that recursively generates Gentoo ebuilds for a given package in the specified overlay (defaults to C</usr/local/portage>), update the manifest, and even emerge it (together with its dependencies) if the user requires it. You need write permissions on the directory where Gentoo fetches its source files (usually C</usr/portage/distfiles>).
  40
  41 The generated ebuilds are placed into the section C<perl-gcpanp>. They favour depending on C<perl-core> or C<dev-perl> rather than C<perl-gcpanp>.
  42
  43 =head1 INSTALLATION
  44
  45 After installing this module, you should append C<perl-gcpanp> to your F</etc/portage/categories> file.
  46
  47 =head1 METHODS
  48
  49 All the methods are inherited from L<CPANPLUS::Dist::Base>. Please refer to its perldoc for precise information on what's done at each step.
  50
  51 =cut
  52
  53 use constant CATEGORY => 'perl-gcpanp';
  54
  55 sub format_available {
  56  for my $prog (qw/emerge ebuild/) {
  57   unless (can_run($prog)) {
  58    error "$prog is required to write ebuilds -- aborting";
  59    return 0;
  60   }
  61  }
  62  return 1;
  63 }
  64
  65 sub init {
  66  my ($self) = @_;
  67  my $stat = $self->status;
  68  my $conf = $self->parent->parent->configure_object;
  69
  70  $stat->mk_accessors(qw/name version dist desc uri src license deps
  71                         eb_name eb_version eb_dir eb_file fetched_arch
  72                         overlay distdir keywords do_manifest
  73                         force verbose/);
  74
  75  $stat->force($conf->get_conf('force'));
  76  $stat->verbose($conf->get_conf('verbose'));
  77
  78  return 1;
  79 }
  80
  81 my %gentooism = (
  82  'Digest'            => 'digest-base',
  83  'Locale-Maketext'   => 'locale-maketext',
  84  'Net-Ping'          => 'net-ping',
  85  'PathTools'         => 'File-Spec',
  86  'PodParser'         => 'Pod-Parser',
  87  'Set-Scalar'        => 'set-scalar',
  88  'Tie-EncryptedHash' => 'tie-encryptedhash',
  89 );
  90
  91 sub prepare {
  92  my $self = shift;
  93  my $mod  = $self->parent;
  94  my $stat = $self->status;
  95  my $int  = $mod->parent;
  96  my $conf = $int->configure_object;
  97
  98  my %opts = @_;
  99
 100  my $keywords = delete $opts{'keywords'};
 101  $keywords = 'x86' unless defined $keywords;
 102  $keywords = [ split ' ', $keywords ];
 103  $stat->keywords($keywords);
 104
 105  my $manifest = delete $opts{'manifest'};
 106  $manifest = 1 unless defined $manifest;
 107  $manifest = 0 if $manifest =~ /^\s*no?\s*$/i;
 108  $stat->do_manifest($manifest);
 109
 110  my $overlay = catdir(delete($opts{'overlay'}) || '/usr/local/portage',
 111                       CATEGORY);
 112  $stat->overlay($overlay);
 113
 114  $stat->distdir(delete($opts{'distdir'}) || '/usr/portage/distfiles');
 115  if ($stat->do_manifest && !-w $stat->distdir) {
 116   error 'distdir isn\'t writable -- aborting';
 117   return 0;
 118  }
 119  $stat->fetched_arch($mod->status->fetch);
 120
 121  my $name = $mod->package_name;
 122  $stat->name($name);
 123
 124  my $version = $mod->package_version;
 125  $stat->version($version);
 126  $stat->dist($name . '-' . $version);
 127  my $f = 1;
 128  $version =~ s/_+/$f ? do { $f = 0; '_p' } : ''/ge;
 129  1 while $version =~ s/(_p[^.]*)\.+/$1/;
 130  $stat->eb_version($version);
 131
 132  $stat->eb_name($gentooism{$stat->name} || $stat->name);
 133  $stat->eb_dir(catdir($overlay, $stat->eb_name));
 134  $stat->eb_file(catfile($stat->eb_dir,
 135                         $stat->eb_name . '-' . $stat->eb_version . '.ebuild'));
 136  if (-r $stat->eb_file) {
 137   msg 'Ebuild already generated for ' . $stat->dist . ' -- skipping';
 138   $stat->prepared(1);
 139   $stat->created(1);
 140   return 1;
 141  }
 142
 143  $self->SUPER::prepare(%opts);
 144
 145  my $desc = $mod->description;
 146  ($desc = $name) =~ s/-+/::/g unless $desc;
 147  $stat->desc($desc);
 148  $stat->uri('http://search.cpan.org/dist/' . $name);
 149  unless ($name =~ /^([^-]+)/) {
 150   error 'Wrong distribution name -- aborting';
 151   return 0;
 152  }
 153  $stat->src('mirror://cpan/modules/by-module/' . $1 . '/' . $mod->package);
 154  $stat->license([ qw/Artistic GPL-2/ ]);
 155
 156  my $prereqs = $mod->status->prereqs;
 157  $prereqs = { map { ($gentooism{$_} || $_) => $prereqs->{$_} } keys %$prereqs };
 158  my @depends;
 159  for my $prereq (sort keys %$prereqs) {
 160   next if $prereq =~ /^perl(?:-|\z)/;
 161   my $obj = $int->module_tree($prereq);
 162   unless ($obj) {
 163    error 'Wrong module object -- aborting';
 164    return 0;
 165   }
 166   next if $obj->package_is_perl_core;
 167   {
 168    my $version;
 169    if ($prereqs->{$prereq}) {
 170     if ($obj->installed_version && $obj->installed_version < $obj->version) {
 171      $version = $obj->installed_version;
 172     } else {
 173      $version = $obj->package_version;
 174     }
 175    }
 176    push @depends, [ $obj , $version ];
 177   }
 178  }
 179  $stat->deps(\@depends);
 180
 181  return 1;
 182 }
 183
 184 sub create {
 185  my $self = shift;
 186  my $stat = $self->status;
 187
 188  unless ($stat->prepared) {
 189   error 'Can\'t create ' . $stat->dist . ' since it was never prepared -- aborting';
 190   return 0;
 191  }
 192
 193  if ($stat->created) {
 194   msg $stat->dist . ' was already created -- skipping';
 195   return 1;
 196  }
 197
 198  $self->SUPER::create(@_);
 199
 200  my $dir = $stat->eb_dir;
 201  unless (-d $dir) {
 202   eval { mkpath $dir };
 203   if ($@) {
 204    error "mkpath($dir): $@";
 205    return 0;
 206   }
 207  }
 208
 209  my $d = "# Generated by CPANPLUS::Dist::Gentoo\n\ninherit perl-module\n\n";
 210  $d   .= 'S="${WORKDIR}/' . $stat->dist . "\"\n";
 211  $d   .= 'DESCRIPTION="' . $stat->desc . "\"\n";
 212  $d   .= 'HOMEPAGE="' . $stat->uri . "\"\n";
 213  $d   .= 'SRC_URI="' . $stat->src . "\"\n";
 214  $d   .= "SLOT=\"0\"\n";
 215  $d   .= 'LICENSE="|| ( ' . join(' ', sort @{$stat->license}) . " )\"\n";
 216  $d   .= 'KEYWORDS="' . join(' ', sort @{$stat->keywords}) . "\"\n";
 217  $d   .= 'DEPEND="' . join "\n",
 218   'dev-lang/perl',
 219   map {
 220    my $a = $_->[0]->package_name;
 221    my $x = '';
 222    if (defined $_->[1]) {
 223     $x  = '>=';
 224     $a .= '-' . $_->[1];
 225    }
 226    '|| ( ' . join(' ', map "$x$_/$a",
 227                            qw/perl-core dev-perl perl-gcpan/, CATEGORY)
 228            . ' )';
 229   } @{$stat->deps};
 230  $d   .= "\"\n";
 231
 232  my $file = $stat->eb_file;
 233  open my $eb, '>', $file or do {
 234   error "open($file): $! -- aborting";
 235   return 0;
 236  };
 237  print $eb $d;
 238  close $eb;
 239
 240  if ($stat->do_manifest) {
 241   unless (copy $stat->fetched_arch, $stat->distdir) {
 242    error "Couldn\'t copy the distribution file to distdir ($!) -- aborting";
 243    1 while unlink $file;
 244    return 0;
 245   }
 246
 247   msg 'Adding Manifest entry for ' . $stat->dist;
 248   unless ($self->_run([ 'ebuild', $file, 'manifest' ], 0)) {
 249    1 while unlink $file;
 250    return 0;
 251   }
 252  }
 253
 254  return 1;
 255 }
 256
 257 sub install {
 258  my $self = shift;
 259  my $stat = $self->status;
 260  my $conf = $self->parent->parent->configure_object;
 261
 262  my $sudo = $conf->get_program('sudo');
 263  my @cmd = ('emerge', '=' . $stat->eb_name . '-' . $stat->eb_version);
 264  unshift @cmd, $sudo if $sudo;
 265
 266  return $self->_run(\@cmd, 1);
 267 }
 268
 269 sub uninstall {
 270  my $self = shift;
 271  my $stat = $self->status;
 272  my $conf = $self->parent->parent->configure_object;
 273
 274  my $sudo = $conf->get_program('sudo');
 275  my @cmd = ('emerge', '-C', '=' . $stat->eb_name . '-' . $stat->eb_version);
 276  unshift @cmd, $sudo if $sudo;
 277
 278  return $self->_run(\@cmd, 1);
 279 }
 280
 281 sub _run {
 282  my ($self, $cmd, $verbose) = @_;
 283  my $stat = $self->status;
 284
 285  my ($success, $errmsg, $output) = do {
 286   local $ENV{PORTDIR_OVERLAY}     = $stat->overlay;
 287   local $ENV{PORTAGE_RO_DISTDIRS} = $stat->distdir;
 288   run command => $cmd, verbose => $verbose;
 289  };
 290
 291  unless ($success) {
 292   error "$errmsg -- aborting";
 293   if (not $verbose and defined $output and $self->status->verbose) {
 294    my $msg = join '', @$output;
 295    1 while chomp $msg;
 296    error $msg;
 297   }
 298  }
 299
 300  return $success;
 301 }
 302
 303 =head1 DEPENDENCIES
 304
 305 Gentoo (L<http://gentoo.org>).
 306
 307 L<CPANPLUS>, L<IPC::Cmd> (core modules since 5.9.5).
 308
 309 L<File::Path> (since 5.001), L<File::Copy> (5.002), L<File::Spec::Functions> (5.00504).
 310
 311 =head1 SEE ALSO
 312
 313 L<cpan2dist>.
 314
 315 L<CPANPLUS::Dist::Base>, L<CPANPLUS::Dist::Deb>, L<CPANPLUS::Dist::Mdv>.
 316
 317 =head1 AUTHOR
 318
 319 Vincent Pit, C<< <perl at profvince.com> >>, L<http://www.profvince.com>.
 320
 321 You can contact me by mail or on C<irc.perl.org> (vincent).
 322
 323 =head1 BUGS
 324
 325 Please report any bugs or feature requests to C<bug-cpanplus-dist-gentoo at rt.cpan.org>, or through the web interface at L<http://rt.cpan.org/NoAuth/ReportBug.html?Queue=CPANPLUS-Dist-Gentoo>.  I will be notified, and then you'll automatically be notified of progress on your bug as I make changes.
 326
 327 =head1 SUPPORT
 328
 329 You can find documentation for this module with the perldoc command.
 330
 331     perldoc CPANPLUS::Dist::Gentoo
 332
 333 =head1 ACKNOWLEDGEMENTS
 334
 335 The module is to some extend cargo-culted from L<CPANPLUS::Dist::Deb> and L<CPANPLUS::Dist::Mdv>.
 336
 337 =head1 COPYRIGHT & LICENSE
 338
 339 Copyright 2008 Vincent Pit, all rights reserved.
 340
 341 This program is free software; you can redistribute it and/or modify it under the same terms as Perl itself.
 342
 343 =cut
 344
 345 1; # End of CPANPLUS::Dist::Gentoo