lib/CPANPLUS/Dist/Gentoo.pm

   1 package CPANPLUS::Dist::Gentoo;
   2
   3 use strict;
   4 use warnings;
   5
   6 use Cwd qw/abs_path/;
   7 use File::Copy qw/copy/;
   8 use File::Path qw/mkpath/;
   9 use File::Spec::Functions qw/catdir catfile/;
  10
  11 use IPC::Cmd qw/run can_run/;
  12
  13 use CPANPLUS::Error;
  14
  15 use base qw/CPANPLUS::Dist::Base/;
  16
  17 =head1 NAME
  18
  19 CPANPLUS::Dist::Gentoo - CPANPLUS backend generating Gentoo ebuilds.
  20
  21 =head1 VERSION
  22
  23 Version 0.04
  24
  25 =cut
  26
  27 our $VERSION = '0.04';
  28
  29 =head1 SYNOPSIS
  30
  31     cpan2dist --format=CPANPLUS::Dist::Gentoo \
  32               --dist-opts overlay=/usr/local/portage \
  33               --dist-opts distdir=/usr/portage/distfiles \
  34               --dist-opts manifest=yes \
  35               --dist-opts keywords=x86 \
  36               --dist-opts header="# Copyright 1999-2008 Gentoo Foundation" \
  37               --dist-opts footer="# End" \
  38               Any::Module You::Like
  39
  40 =head1 DESCRPITON
  41
  42 This module is a CPANPLUS backend that recursively generates Gentoo ebuilds for a given package in the specified overlay (defaults to F</usr/local/portage>), updates the manifest, and even emerges it (together with its dependencies) if the user requires it. You need write permissions on the directory where Gentoo fetches its source files (usually F</usr/portage/distfiles>). You also need to specify the correct keyword for your architecture if it differs from the default C<x86>.
  43
  44 The generated ebuilds are placed into the C<perl-gcpanp> category. They favour depending on C<perl-core>, C<dev-perl> or C<perl-gcpan> (in that order) rather than C<perl-gcpanp>.
  45
  46 =head1 INSTALLATION
  47
  48 After installing this module, you should append C<perl-gcpanp> to your F</etc/portage/categories> file.
  49
  50 =head1 METHODS
  51
  52 All the methods are inherited from L<CPANPLUS::Dist::Base>. Please refer to its documentation for precise information on what's done at each step.
  53
  54 =cut
  55
  56 use constant CATEGORY => 'perl-gcpanp';
  57
  58 sub format_available {
  59  for my $prog (qw/emerge ebuild/) {
  60   unless (can_run($prog)) {
  61    error "$prog is required to write ebuilds -- aborting";
  62    return 0;
  63   }
  64  }
  65  return 1;
  66 }
  67
  68 sub init {
  69  my ($self) = @_;
  70  my $stat = $self->status;
  71  my $conf = $self->parent->parent->configure_object;
  72
  73  $stat->mk_accessors(qw/name version author dist desc uri src license deps
  74                         eb_name eb_version eb_dir eb_file fetched_arch
  75                         overlay distdir keywords do_manifest header footer
  76                         force verbose/);
  77
  78  $stat->force($conf->get_conf('force'));
  79  $stat->verbose($conf->get_conf('verbose'));
  80
  81  return 1;
  82 }
  83
  84 my %gentooism = (
  85  'Crypt-RSA'         => 'crypt-rsa',
  86  'Digest'            => 'digest-base',
  87  'Locale-Maketext'   => 'locale-maketext',
  88  'Math-Pari'         => 'math-pari',
  89  'Net-Ping'          => 'net-ping',
  90  'PathTools'         => 'File-Spec',
  91  'PodParser'         => 'Pod-Parser',
  92  'Set-Scalar'        => 'set-scalar',
  93  'Tie-EncryptedHash' => 'tie-encryptedhash',
  94  'YAML'              => 'yaml',
  95 );
  96
  97 sub prepare {
  98  my $self = shift;
  99  my $mod  = $self->parent;
 100  my $stat = $self->status;
 101  my $int  = $mod->parent;
 102  my $conf = $int->configure_object;
 103
 104  my %opts = @_;
 105
 106  $stat->prepared(0);
 107
 108  my $keywords = delete $opts{'keywords'};
 109  $keywords = 'x86' unless defined $keywords;
 110  $keywords = [ split ' ', $keywords ];
 111  $stat->keywords($keywords);
 112
 113  my $manifest = delete $opts{'manifest'};
 114  $manifest = 1 unless defined $manifest;
 115  $manifest = 0 if $manifest =~ /^\s*no?\s*$/i;
 116  $stat->do_manifest($manifest);
 117
 118  my $header = delete $opts{'header'};
 119  if (defined $header) {
 120   1 while chomp $header;
 121   $header .= "\n\n";
 122  } else {
 123   $header = '';
 124  }
 125  $stat->header($header);
 126
 127  my $footer = delete $opts{'footer'};
 128  if (defined $footer) {
 129   $footer = "\n" . $footer;
 130  } else {
 131   $footer = '';
 132  }
 133  $stat->footer($footer);
 134
 135  my $overlay = delete $opts{'overlay'};
 136  $overlay = (defined $overlay) ? abs_path $overlay : '/usr/local/portage';
 137  $stat->overlay($overlay);
 138
 139  my $distdir = delete $opts{'distdir'};
 140  $distdir = (defined $distdir) ? abs_path $distdir : '/usr/portage/distfiles';
 141  $stat->distdir($distdir);
 142
 143  if ($stat->do_manifest && !-w $stat->distdir) {
 144   error 'distdir isn\'t writable -- aborting';
 145   return 0;
 146  }
 147  $stat->fetched_arch($mod->status->fetch);
 148
 149  my $name = $mod->package_name;
 150  $stat->name($name);
 151
 152  my $version = $mod->package_version;
 153  $stat->version($version);
 154
 155  my $author = $mod->author->cpanid;
 156  $stat->author($author);
 157
 158  $stat->dist($name . '-' . $version);
 159
 160  $version =~ s/[^\d._]+//g;
 161  $version =~ s/^[._]*//;
 162  $version =~ s/[._]*$//;
 163  $version =~ s/[._]*_[._]*/_/g;
 164  {
 165   ($version, my $patch, my @rest) = split /_/, $version;
 166   $version .= '_p' . $patch if defined $patch;
 167   $version .= join('.', '', @rest) if @rest;
 168  }
 169  $stat->eb_version($version);
 170
 171  $stat->eb_name($gentooism{$name} || $name);
 172
 173  $stat->eb_dir(catdir($stat->overlay, CATEGORY, $stat->eb_name));
 174
 175  my $file = catfile($stat->eb_dir,
 176                     $stat->eb_name . '-' . $stat->eb_version . '.ebuild');
 177  if (-e $file) {
 178   my $skip = 1;
 179   if ($stat->force) {
 180    if (-w $file) {
 181     1 while unlink $file;
 182     $skip = 0;
 183    } else {
 184     error "Can't force rewriting of $file -- skipping";
 185    }
 186   } else {
 187    msg 'Ebuild already generated for ' . $stat->dist . ' -- skipping';
 188   }
 189   if ($skip) {
 190    $stat->prepared(1);
 191    $stat->created(1);
 192    return 1;
 193   }
 194  }
 195  $stat->eb_file($file);
 196
 197  $self->SUPER::prepare(%opts);
 198
 199  my $desc = $mod->description;
 200  ($desc = $name) =~ s/-+/::/g unless $desc;
 201  $stat->desc($desc);
 202
 203  $stat->uri('http://search.cpan.org/dist/' . $name);
 204
 205  unless ($author =~ /^(.)(.)/) {
 206   error 'Wrong author name -- aborting';
 207   return 0;
 208  }
 209  $stat->src("mirror://cpan/modules/by-authors/id/$1/$1$2/$author/"
 210             . $mod->package);
 211
 212  $stat->license([ qw/Artistic GPL-2/ ]);
 213
 214  my $prereqs = $mod->status->prereqs;
 215  my @depends;
 216  for my $prereq (sort keys %$prereqs) {
 217   next if $prereq =~ /^perl(?:-|\z)/;
 218   my $obj = $int->module_tree($prereq);
 219   unless ($obj) {
 220    error 'Wrong module object -- aborting';
 221    return 0;
 222   }
 223   next if $obj->package_is_perl_core;
 224   {
 225    my $version;
 226    if ($prereqs->{$prereq}) {
 227     if ($obj->installed_version && $obj->installed_version < $obj->version) {
 228      $version = $obj->installed_version;
 229     } else {
 230      $version = $obj->package_version;
 231     }
 232    }
 233    push @depends, [ $obj , $version ];
 234   }
 235  }
 236  $stat->deps(\@depends);
 237
 238  $stat->prepared(1);
 239  return 1;
 240 }
 241
 242 sub create {
 243  my $self = shift;
 244  my $stat = $self->status;
 245
 246  unless ($stat->prepared) {
 247   error 'Can\'t create ' . $stat->dist . ' since it was never prepared -- aborting';
 248   $stat->created(0);
 249   return 0;
 250  }
 251
 252  if ($stat->created) {
 253   msg $stat->dist . ' was already created -- skipping';
 254   return 1;
 255  }
 256
 257  $stat->created(0);
 258
 259  $self->SUPER::create(@_);
 260
 261  my $dir = $stat->eb_dir;
 262  unless (-d $dir) {
 263   eval { mkpath $dir };
 264   if ($@) {
 265    error "mkpath($dir): $@";
 266    return 0;
 267   }
 268  }
 269
 270  my $d = $stat->header;
 271  $d   .= "# Generated by CPANPLUS::Dist::Gentoo version $VERSION\n\n";
 272  $d   .= 'MODULE_AUTHOR="' . $stat->author . "\"\ninherit perl-module\n\n";
 273  $d   .= 'S="${WORKDIR}/' . $stat->dist . "\"\n";
 274  $d   .= 'DESCRIPTION="' . $stat->desc . "\"\n";
 275  $d   .= 'HOMEPAGE="' . $stat->uri . "\"\n";
 276  $d   .= 'SRC_URI="' . $stat->src . "\"\n";
 277  $d   .= "SLOT=\"0\"\n";
 278  $d   .= 'LICENSE="|| ( ' . join(' ', sort @{$stat->license}) . " )\"\n";
 279  $d   .= 'KEYWORDS="' . join(' ', sort @{$stat->keywords}) . "\"\n";
 280  $d   .= 'DEPEND="' . join "\n",
 281   'dev-lang/perl',
 282   map {
 283    my $a = $_->[0]->package_name;
 284    $a = $gentooism{$a} || $a;
 285    my $x = '';
 286    if (defined $_->[1]) {
 287     $x  = '>=';
 288     $a .= '-' . $_->[1];
 289    }
 290    '|| ( ' . join(' ', map "$x$_/$a",
 291                            qw/perl-core dev-perl perl-gcpan/, CATEGORY)
 292            . ' )';
 293   } @{$stat->deps};
 294  $d   .= "\"\n";
 295  $d   .= "SRC_TEST=\"do\"\n";
 296  $d   .= $stat->footer;
 297
 298  my $file = $stat->eb_file;
 299  open my $eb, '>', $file or do {
 300   error "open($file): $! -- aborting";
 301   return 0;
 302  };
 303  print $eb $d;
 304  close $eb;
 305
 306  if ($stat->do_manifest) {
 307   unless (copy $stat->fetched_arch, $stat->distdir) {
 308    error "Couldn\'t copy the distribution file to distdir ($!) -- aborting";
 309    1 while unlink $file;
 310    return 0;
 311   }
 312
 313   msg 'Adding Manifest entry for ' . $stat->dist;
 314   unless ($self->_run([ 'ebuild', $file, 'manifest' ], 0)) {
 315    1 while unlink $file;
 316    return 0;
 317   }
 318  }
 319
 320  $stat->created(1);
 321  return 1;
 322 }
 323
 324 sub install {
 325  my $self = shift;
 326  my $stat = $self->status;
 327  my $conf = $self->parent->parent->configure_object;
 328
 329  my $sudo = $conf->get_program('sudo');
 330  my @cmd = ('emerge', '=' . $stat->eb_name . '-' . $stat->eb_version);
 331  unshift @cmd, $sudo if $sudo;
 332
 333  my $success = $self->_run(\@cmd, 1);
 334  $stat->installed($success);
 335
 336  return $success;
 337 }
 338
 339 sub uninstall {
 340  my $self = shift;
 341  my $stat = $self->status;
 342  my $conf = $self->parent->parent->configure_object;
 343
 344  my $sudo = $conf->get_program('sudo');
 345  my @cmd = ('emerge', '-C', '=' . $stat->eb_name . '-' . $stat->eb_version);
 346  unshift @cmd, $sudo if $sudo;
 347
 348  my $success = $self->_run(\@cmd, 1);
 349  $stat->uninstalled($success);
 350
 351  return $success;
 352 }
 353
 354 sub _run {
 355  my ($self, $cmd, $verbose) = @_;
 356  my $stat = $self->status;
 357
 358  my ($success, $errmsg, $output) = do {
 359   local $ENV{PORTDIR_OVERLAY}     = $stat->overlay;
 360   local $ENV{PORTAGE_RO_DISTDIRS} = $stat->distdir;
 361   run command => $cmd, verbose => $verbose;
 362  };
 363
 364  unless ($success) {
 365   error "$errmsg -- aborting";
 366   if (not $verbose and defined $output and $self->status->verbose) {
 367    my $msg = join '', @$output;
 368    1 while chomp $msg;
 369    error $msg;
 370   }
 371  }
 372
 373  return $success;
 374 }
 375
 376 =head1 DEPENDENCIES
 377
 378 Gentoo (L<http://gentoo.org>).
 379
 380 L<CPANPLUS>, L<IPC::Cmd> (core modules since 5.9.5).
 381
 382 L<Cwd> (since perl 5) L<File::Path> (5.001), L<File::Copy> (5.002), L<File::Spec::Functions> (5.00504).
 383
 384 =head1 SEE ALSO
 385
 386 L<cpan2dist>.
 387
 388 L<CPANPLUS::Dist::Base>, L<CPANPLUS::Dist::Deb>, L<CPANPLUS::Dist::Mdv>.
 389
 390 =head1 AUTHOR
 391
 392 Vincent Pit, C<< <perl at profvince.com> >>, L<http://www.profvince.com>.
 393
 394 You can contact me by mail or on C<irc.perl.org> (vincent).
 395
 396 =head1 BUGS
 397
 398 Please report any bugs or feature requests to C<bug-cpanplus-dist-gentoo at rt.cpan.org>, or through the web interface at L<http://rt.cpan.org/NoAuth/ReportBug.html?Queue=CPANPLUS-Dist-Gentoo>.  I will be notified, and then you'll automatically be notified of progress on your bug as I make changes.
 399
 400 =head1 SUPPORT
 401
 402 You can find documentation for this module with the perldoc command.
 403
 404     perldoc CPANPLUS::Dist::Gentoo
 405
 406 =head1 ACKNOWLEDGEMENTS
 407
 408 The module is to some extend cargo-culted from L<CPANPLUS::Dist::Deb> and L<CPANPLUS::Dist::Mdv>.
 409
 410 Kent Fredric, for testing and suggesting improvements.
 411
 412 =head1 COPYRIGHT & LICENSE
 413
 414 Copyright 2008 Vincent Pit, all rights reserved.
 415
 416 This program is free software; you can redistribute it and/or modify it under the same terms as Perl itself.
 417
 418 =cut
 419
 420 1; # End of CPANPLUS::Dist::Gentoo