lib/CPANPLUS/Dist/Gentoo.pm

   1 package CPANPLUS::Dist::Gentoo;
   2
   3 use strict;
   4 use warnings;
   5
   6 use File::Copy qw/copy/;
   7 use File::Path qw/mkpath/;
   8 use File::Spec::Functions qw/catdir catfile/;
   9
  10 use IPC::Cmd qw/run can_run/;
  11
  12 use CPANPLUS::Error;
  13
  14 use base qw/CPANPLUS::Dist::Base/;
  15
  16 =head1 NAME
  17
  18 CPANPLUS::Dist::Gentoo - CPANPLUS backend generating Gentoo ebuilds.
  19
  20 =head1 VERSION
  21
  22 Version 0.02_01
  23
  24 =cut
  25
  26 our $VERSION = '0.02_01';
  27
  28 =head1 SYNOPSIS
  29
  30     cpan2dist --format=CPANPLUS::Dist::Gentoo \
  31               --dist-opts overlay=/usr/local/portage \
  32               --dist-opts distdir=/usr/portage/distfiles \
  33               --dist-opts manifest=yes \
  34               --dist-opts keywords=x86 \
  35               Any::Module You::Like
  36
  37 =head1 DESCRPITON
  38
  39 This module is a CPANPLUS backend that recursively generates Gentoo ebuilds for a given package in the specified overlay (defaults to C</usr/local/portage>), update the manifest, and even emerge it (together with its dependencies) if the user requires it. You need write permissions on the directory where Gentoo fetches its source files (usually C</usr/portage/distfiles>).
  40
  41 The generated ebuilds are placed into the section C<perl-gcpanp>. They favour depending on C<perl-core> or C<dev-perl> rather than C<perl-gcpanp>.
  42
  43 =head1 INSTALLATION
  44
  45 After installing this module, you should append C<perl-gcpanp> to your F</etc/portage/categories> file.
  46
  47 =head1 METHODS
  48
  49 All the methods are inherited from L<CPANPLUS::Dist::Base>. Please refer to its perldoc for precise information on what's done at each step.
  50
  51 =cut
  52
  53 use constant CATEGORY => 'perl-gcpanp';
  54
  55 sub format_available {
  56  for my $prog (qw/emerge ebuild/) {
  57   unless (can_run($prog)) {
  58    error "$prog is required to write ebuilds -- aborting";
  59    return 0;
  60   }
  61  }
  62  return 1;
  63 }
  64
  65 sub init {
  66  my ($self) = @_;
  67  my $stat = $self->status;
  68  my $conf = $self->parent->parent->configure_object;
  69
  70  $stat->mk_accessors(qw/name version dist desc uri src license deps
  71                         eb_name eb_version eb_dir eb_file fetched_arch
  72                         overlay distdir keywords do_manifest
  73                         force verbose/);
  74
  75  $stat->force($conf->get_conf('force'));
  76  $stat->verbose($conf->get_conf('verbose'));
  77
  78  return 1;
  79 }
  80
  81 my %gentooism = (
  82  'Digest'            => 'digest-base',
  83  'Locale-Maketext'   => 'locale-maketext',
  84  'Net-Ping'          => 'net-ping',
  85  'PathTools'         => 'File-Spec',
  86  'PodParser'         => 'Pod-Parser',
  87  'Set-Scalar'        => 'set-scalar',
  88  'Tie-EncryptedHash' => 'tie-encryptedhash',
  89 );
  90
  91 sub prepare {
  92  my $self = shift;
  93  my $mod  = $self->parent;
  94  my $stat = $self->status;
  95  my $int  = $mod->parent;
  96  my $conf = $int->configure_object;
  97
  98  my %opts = @_;
  99
 100  my $keywords = delete $opts{'keywords'};
 101  $keywords = 'x86' unless defined $keywords;
 102  $keywords = [ split ' ', $keywords ];
 103  $stat->keywords($keywords);
 104
 105  my $manifest = delete $opts{'manifest'};
 106  $manifest = 1 unless defined $manifest;
 107  $manifest = 0 if $manifest =~ /^\s*no?\s*$/i;
 108  $stat->do_manifest($manifest);
 109
 110  my $overlay = catdir(delete($opts{'overlay'}) || '/usr/local/portage',
 111                       CATEGORY);
 112  $stat->overlay($overlay);
 113
 114  $stat->distdir(delete($opts{'distdir'}) || '/usr/portage/distfiles');
 115  if ($stat->do_manifest && !-w $stat->distdir) {
 116   error 'distdir isn\'t writable -- aborting';
 117   return 0;
 118  }
 119  $stat->fetched_arch($mod->status->fetch);
 120
 121  my $name = $mod->package_name;
 122  $stat->name($name);
 123
 124  my $version = $mod->package_version;
 125  $stat->version($version);
 126  $stat->dist($name . '-' . $version);
 127  my $f = 1;
 128  $version =~ s/_+/$f ? do { $f = 0; '_p' } : ''/ge;
 129  1 while $version =~ s/(_p[^.]*)\.+/$1/;
 130  $stat->eb_version($version);
 131
 132  $stat->eb_name($gentooism{$stat->name} || $stat->name);
 133  $stat->eb_dir(catdir($overlay, $stat->eb_name));
 134
 135  my $file = catfile($stat->eb_dir,
 136                     $stat->eb_name . '-' . $stat->eb_version . '.ebuild');
 137  $stat->eb_file($file);
 138
 139  if (-e $file) {
 140   my $skip = 1;
 141   if ($stat->force) {
 142    if (-w $file) {
 143     1 while unlink $file;
 144     $skip = 0;
 145    } else {
 146     error "Can't force rewriting of $file -- skipping";
 147    }
 148   } else {
 149    msg 'Ebuild already generated for ' . $stat->dist . ' -- skipping';
 150   }
 151   if ($skip) {
 152    $stat->prepared(1);
 153    $stat->created(1);
 154    return 1;
 155   }
 156  }
 157
 158  $self->SUPER::prepare(%opts);
 159
 160  my $desc = $mod->description;
 161  ($desc = $name) =~ s/-+/::/g unless $desc;
 162  $stat->desc($desc);
 163  $stat->uri('http://search.cpan.org/dist/' . $name);
 164  unless ($name =~ /^([^-]+)/) {
 165   error 'Wrong distribution name -- aborting';
 166   return 0;
 167  }
 168  $stat->src('mirror://cpan/modules/by-module/' . $1 . '/' . $mod->package);
 169  $stat->license([ qw/Artistic GPL-2/ ]);
 170
 171  my $prereqs = $mod->status->prereqs;
 172  $prereqs = { map { ($gentooism{$_} || $_) => $prereqs->{$_} } keys %$prereqs };
 173  my @depends;
 174  for my $prereq (sort keys %$prereqs) {
 175   next if $prereq =~ /^perl(?:-|\z)/;
 176   my $obj = $int->module_tree($prereq);
 177   unless ($obj) {
 178    error 'Wrong module object -- aborting';
 179    return 0;
 180   }
 181   next if $obj->package_is_perl_core;
 182   {
 183    my $version;
 184    if ($prereqs->{$prereq}) {
 185     if ($obj->installed_version && $obj->installed_version < $obj->version) {
 186      $version = $obj->installed_version;
 187     } else {
 188      $version = $obj->package_version;
 189     }
 190    }
 191    push @depends, [ $obj , $version ];
 192   }
 193  }
 194  $stat->deps(\@depends);
 195
 196  return 1;
 197 }
 198
 199 sub create {
 200  my $self = shift;
 201  my $stat = $self->status;
 202
 203  unless ($stat->prepared) {
 204   error 'Can\'t create ' . $stat->dist . ' since it was never prepared -- aborting';
 205   return 0;
 206  }
 207
 208  if ($stat->created) {
 209   msg $stat->dist . ' was already created -- skipping';
 210   return 1;
 211  }
 212
 213  $self->SUPER::create(@_);
 214
 215  my $dir = $stat->eb_dir;
 216  unless (-d $dir) {
 217   eval { mkpath $dir };
 218   if ($@) {
 219    error "mkpath($dir): $@";
 220    return 0;
 221   }
 222  }
 223
 224  my $d = "# Generated by CPANPLUS::Dist::Gentoo\n\ninherit perl-module\n\n";
 225  $d   .= 'S="${WORKDIR}/' . $stat->dist . "\"\n";
 226  $d   .= 'DESCRIPTION="' . $stat->desc . "\"\n";
 227  $d   .= 'HOMEPAGE="' . $stat->uri . "\"\n";
 228  $d   .= 'SRC_URI="' . $stat->src . "\"\n";
 229  $d   .= "SLOT=\"0\"\n";
 230  $d   .= 'LICENSE="|| ( ' . join(' ', sort @{$stat->license}) . " )\"\n";
 231  $d   .= 'KEYWORDS="' . join(' ', sort @{$stat->keywords}) . "\"\n";
 232  $d   .= 'DEPEND="' . join "\n",
 233   'dev-lang/perl',
 234   map {
 235    my $a = $_->[0]->package_name;
 236    my $x = '';
 237    if (defined $_->[1]) {
 238     $x  = '>=';
 239     $a .= '-' . $_->[1];
 240    }
 241    '|| ( ' . join(' ', map "$x$_/$a",
 242                            qw/perl-core dev-perl perl-gcpan/, CATEGORY)
 243            . ' )';
 244   } @{$stat->deps};
 245  $d   .= "\"\n";
 246
 247  my $file = $stat->eb_file;
 248  open my $eb, '>', $file or do {
 249   error "open($file): $! -- aborting";
 250   return 0;
 251  };
 252  print $eb $d;
 253  close $eb;
 254
 255  if ($stat->do_manifest) {
 256   unless (copy $stat->fetched_arch, $stat->distdir) {
 257    error "Couldn\'t copy the distribution file to distdir ($!) -- aborting";
 258    1 while unlink $file;
 259    return 0;
 260   }
 261
 262   msg 'Adding Manifest entry for ' . $stat->dist;
 263   unless ($self->_run([ 'ebuild', $file, 'manifest' ], 0)) {
 264    1 while unlink $file;
 265    return 0;
 266   }
 267  }
 268
 269  return 1;
 270 }
 271
 272 sub install {
 273  my $self = shift;
 274  my $stat = $self->status;
 275  my $conf = $self->parent->parent->configure_object;
 276
 277  my $sudo = $conf->get_program('sudo');
 278  my @cmd = ('emerge', '=' . $stat->eb_name . '-' . $stat->eb_version);
 279  unshift @cmd, $sudo if $sudo;
 280
 281  return $self->_run(\@cmd, 1);
 282 }
 283
 284 sub uninstall {
 285  my $self = shift;
 286  my $stat = $self->status;
 287  my $conf = $self->parent->parent->configure_object;
 288
 289  my $sudo = $conf->get_program('sudo');
 290  my @cmd = ('emerge', '-C', '=' . $stat->eb_name . '-' . $stat->eb_version);
 291  unshift @cmd, $sudo if $sudo;
 292
 293  return $self->_run(\@cmd, 1);
 294 }
 295
 296 sub _run {
 297  my ($self, $cmd, $verbose) = @_;
 298  my $stat = $self->status;
 299
 300  my ($success, $errmsg, $output) = do {
 301   local $ENV{PORTDIR_OVERLAY}     = $stat->overlay;
 302   local $ENV{PORTAGE_RO_DISTDIRS} = $stat->distdir;
 303   run command => $cmd, verbose => $verbose;
 304  };
 305
 306  unless ($success) {
 307   error "$errmsg -- aborting";
 308   if (not $verbose and defined $output and $self->status->verbose) {
 309    my $msg = join '', @$output;
 310    1 while chomp $msg;
 311    error $msg;
 312   }
 313  }
 314
 315  return $success;
 316 }
 317
 318 =head1 DEPENDENCIES
 319
 320 Gentoo (L<http://gentoo.org>).
 321
 322 L<CPANPLUS>, L<IPC::Cmd> (core modules since 5.9.5).
 323
 324 L<File::Path> (since 5.001), L<File::Copy> (5.002), L<File::Spec::Functions> (5.00504).
 325
 326 =head1 SEE ALSO
 327
 328 L<cpan2dist>.
 329
 330 L<CPANPLUS::Dist::Base>, L<CPANPLUS::Dist::Deb>, L<CPANPLUS::Dist::Mdv>.
 331
 332 =head1 AUTHOR
 333
 334 Vincent Pit, C<< <perl at profvince.com> >>, L<http://www.profvince.com>.
 335
 336 You can contact me by mail or on C<irc.perl.org> (vincent).
 337
 338 =head1 BUGS
 339
 340 Please report any bugs or feature requests to C<bug-cpanplus-dist-gentoo at rt.cpan.org>, or through the web interface at L<http://rt.cpan.org/NoAuth/ReportBug.html?Queue=CPANPLUS-Dist-Gentoo>.  I will be notified, and then you'll automatically be notified of progress on your bug as I make changes.
 341
 342 =head1 SUPPORT
 343
 344 You can find documentation for this module with the perldoc command.
 345
 346     perldoc CPANPLUS::Dist::Gentoo
 347
 348 =head1 ACKNOWLEDGEMENTS
 349
 350 The module is to some extend cargo-culted from L<CPANPLUS::Dist::Deb> and L<CPANPLUS::Dist::Mdv>.
 351
 352 =head1 COPYRIGHT & LICENSE
 353
 354 Copyright 2008 Vincent Pit, all rights reserved.
 355
 356 This program is free software; you can redistribute it and/or modify it under the same terms as Perl itself.
 357
 358 =cut
 359
 360 1; # End of CPANPLUS::Dist::Gentoo