lib/CPANPLUS/Dist/Gentoo.pm

   1 package CPANPLUS::Dist::Gentoo;
   2
   3 use strict;
   4 use warnings;
   5
   6 use File::Copy qw/copy/;
   7 use File::Path qw/mkpath/;
   8 use File::Spec::Functions qw/catdir catfile/;
   9
  10 use IPC::Cmd qw/run can_run/;
  11
  12 use CPANPLUS::Error;
  13
  14 use base qw/CPANPLUS::Dist::Base/;
  15
  16 =head1 NAME
  17
  18 CPANPLUS::Dist::Gentoo - CPANPLUS backend generating Gentoo ebuilds.
  19
  20 =head1 VERSION
  21
  22 Version 0.03
  23
  24 =cut
  25
  26 our $VERSION = '0.03';
  27
  28 =head1 SYNOPSIS
  29
  30     cpan2dist --format=CPANPLUS::Dist::Gentoo \
  31               --dist-opts overlay=/usr/local/portage \
  32               --dist-opts distdir=/usr/portage/distfiles \
  33               --dist-opts manifest=yes \
  34               --dist-opts keywords=x86 \
  35               Any::Module You::Like
  36
  37 =head1 DESCRPITON
  38
  39 This module is a CPANPLUS backend that recursively generates Gentoo ebuilds for a given package in the specified overlay (defaults to F</usr/local/portage>), updates the manifest, and even emerges it (together with its dependencies) if the user requires it. You need write permissions on the directory where Gentoo fetches its source files (usually F</usr/portage/distfiles>). You also need to specify the correct keyword for your architecture if it differs from the default C<x86>.
  40
  41 The generated ebuilds are placed into the C<perl-gcpanp> category. They favour depending on C<perl-core>, C<dev-perl> or C<perl-gcpan> (in that order) rather than C<perl-gcpanp>.
  42
  43 =head1 INSTALLATION
  44
  45 After installing this module, you should append C<perl-gcpanp> to your F</etc/portage/categories> file.
  46
  47 =head1 METHODS
  48
  49 All the methods are inherited from L<CPANPLUS::Dist::Base>. Please refer to its documentation for precise information on what's done at each step.
  50
  51 =cut
  52
  53 use constant CATEGORY => 'perl-gcpanp';
  54
  55 sub format_available {
  56  for my $prog (qw/emerge ebuild/) {
  57   unless (can_run($prog)) {
  58    error "$prog is required to write ebuilds -- aborting";
  59    return 0;
  60   }
  61  }
  62  return 1;
  63 }
  64
  65 sub init {
  66  my ($self) = @_;
  67  my $stat = $self->status;
  68  my $conf = $self->parent->parent->configure_object;
  69
  70  $stat->mk_accessors(qw/name version dist desc uri src license deps
  71                         eb_name eb_version eb_dir eb_file fetched_arch
  72                         overlay distdir keywords do_manifest
  73                         force verbose/);
  74
  75  $stat->force($conf->get_conf('force'));
  76  $stat->verbose($conf->get_conf('verbose'));
  77
  78  return 1;
  79 }
  80
  81 my %gentooism = (
  82  'Digest'            => 'digest-base',
  83  'Locale-Maketext'   => 'locale-maketext',
  84  'Net-Ping'          => 'net-ping',
  85  'PathTools'         => 'File-Spec',
  86  'PodParser'         => 'Pod-Parser',
  87  'Set-Scalar'        => 'set-scalar',
  88  'Tie-EncryptedHash' => 'tie-encryptedhash',
  89 );
  90
  91 sub prepare {
  92  my $self = shift;
  93  my $mod  = $self->parent;
  94  my $stat = $self->status;
  95  my $int  = $mod->parent;
  96  my $conf = $int->configure_object;
  97
  98  my %opts = @_;
  99
 100  my $keywords = delete $opts{'keywords'};
 101  $keywords = 'x86' unless defined $keywords;
 102  $keywords = [ split ' ', $keywords ];
 103  $stat->keywords($keywords);
 104
 105  my $manifest = delete $opts{'manifest'};
 106  $manifest = 1 unless defined $manifest;
 107  $manifest = 0 if $manifest =~ /^\s*no?\s*$/i;
 108  $stat->do_manifest($manifest);
 109
 110  $stat->overlay(delete($opts{'overlay'}) || '/usr/local/portage');
 111
 112  $stat->distdir(delete($opts{'distdir'}) || '/usr/portage/distfiles');
 113
 114  if ($stat->do_manifest && !-w $stat->distdir) {
 115   error 'distdir isn\'t writable -- aborting';
 116   return 0;
 117  }
 118  $stat->fetched_arch($mod->status->fetch);
 119
 120  my $name = $mod->package_name;
 121  $stat->name($name);
 122
 123  my $version = $mod->package_version;
 124  $stat->version($version);
 125
 126  $stat->dist($name . '-' . $version);
 127
 128  $version =~ s/[^\d._]+//g;
 129  $version =~ s/^[._]*//;
 130  $version =~ s/[._]*$//;
 131  $version =~ s/[._]*_[._]*/_/g;
 132  {
 133   ($version, my $patch, my @rest) = split /_/, $version;
 134   $version .= '_p' . $patch if defined $patch;
 135   $version .= join('.', '', @rest) if @rest;
 136  }
 137  $stat->eb_version($version);
 138
 139  $stat->eb_name($gentooism{$name} || $name);
 140
 141  $stat->eb_dir(catdir($stat->overlay, CATEGORY, $stat->eb_name));
 142
 143  my $file = catfile($stat->eb_dir,
 144                     $stat->eb_name . '-' . $stat->eb_version . '.ebuild');
 145  if (-e $file) {
 146   my $skip = 1;
 147   if ($stat->force) {
 148    if (-w $file) {
 149     1 while unlink $file;
 150     $skip = 0;
 151    } else {
 152     error "Can't force rewriting of $file -- skipping";
 153    }
 154   } else {
 155    msg 'Ebuild already generated for ' . $stat->dist . ' -- skipping';
 156   }
 157   if ($skip) {
 158    $stat->prepared(1);
 159    $stat->created(1);
 160    return 1;
 161   }
 162  }
 163  $stat->eb_file($file);
 164
 165  $self->SUPER::prepare(%opts);
 166
 167  my $desc = $mod->description;
 168  ($desc = $name) =~ s/-+/::/g unless $desc;
 169  $stat->desc($desc);
 170
 171  $stat->uri('http://search.cpan.org/dist/' . $name);
 172
 173  unless ($name =~ /^([^-]+)/) {
 174   error 'Wrong distribution name -- aborting';
 175   return 0;
 176  }
 177  $stat->src('mirror://cpan/modules/by-module/' . $1 . '/' . $mod->package);
 178
 179  $stat->license([ qw/Artistic GPL-2/ ]);
 180
 181  my $prereqs = $mod->status->prereqs;
 182  $prereqs = { map { ($gentooism{$_} || $_) => $prereqs->{$_} } keys %$prereqs };
 183  my @depends;
 184  for my $prereq (sort keys %$prereqs) {
 185   next if $prereq =~ /^perl(?:-|\z)/;
 186   my $obj = $int->module_tree($prereq);
 187   unless ($obj) {
 188    error 'Wrong module object -- aborting';
 189    return 0;
 190   }
 191   next if $obj->package_is_perl_core;
 192   {
 193    my $version;
 194    if ($prereqs->{$prereq}) {
 195     if ($obj->installed_version && $obj->installed_version < $obj->version) {
 196      $version = $obj->installed_version;
 197     } else {
 198      $version = $obj->package_version;
 199     }
 200    }
 201    push @depends, [ $obj , $version ];
 202   }
 203  }
 204  $stat->deps(\@depends);
 205
 206  return 1;
 207 }
 208
 209 sub create {
 210  my $self = shift;
 211  my $stat = $self->status;
 212
 213  unless ($stat->prepared) {
 214   error 'Can\'t create ' . $stat->dist . ' since it was never prepared -- aborting';
 215   return 0;
 216  }
 217
 218  if ($stat->created) {
 219   msg $stat->dist . ' was already created -- skipping';
 220   return 1;
 221  }
 222
 223  $self->SUPER::create(@_);
 224
 225  my $dir = $stat->eb_dir;
 226  unless (-d $dir) {
 227   eval { mkpath $dir };
 228   if ($@) {
 229    error "mkpath($dir): $@";
 230    return 0;
 231   }
 232  }
 233
 234  my $d = "# Generated by CPANPLUS::Dist::Gentoo\n\ninherit perl-module\n\n";
 235  $d   .= 'S="${WORKDIR}/' . $stat->dist . "\"\n";
 236  $d   .= 'DESCRIPTION="' . $stat->desc . "\"\n";
 237  $d   .= 'HOMEPAGE="' . $stat->uri . "\"\n";
 238  $d   .= 'SRC_URI="' . $stat->src . "\"\n";
 239  $d   .= "SLOT=\"0\"\n";
 240  $d   .= 'LICENSE="|| ( ' . join(' ', sort @{$stat->license}) . " )\"\n";
 241  $d   .= 'KEYWORDS="' . join(' ', sort @{$stat->keywords}) . "\"\n";
 242  $d   .= 'DEPEND="' . join "\n",
 243   'dev-lang/perl',
 244   map {
 245    my $a = $_->[0]->package_name;
 246    my $x = '';
 247    if (defined $_->[1]) {
 248     $x  = '>=';
 249     $a .= '-' . $_->[1];
 250    }
 251    '|| ( ' . join(' ', map "$x$_/$a",
 252                            qw/perl-core dev-perl perl-gcpan/, CATEGORY)
 253            . ' )';
 254   } @{$stat->deps};
 255  $d   .= "\"\n";
 256
 257  my $file = $stat->eb_file;
 258  open my $eb, '>', $file or do {
 259   error "open($file): $! -- aborting";
 260   return 0;
 261  };
 262  print $eb $d;
 263  close $eb;
 264
 265  if ($stat->do_manifest) {
 266   unless (copy $stat->fetched_arch, $stat->distdir) {
 267    error "Couldn\'t copy the distribution file to distdir ($!) -- aborting";
 268    1 while unlink $file;
 269    return 0;
 270   }
 271
 272   msg 'Adding Manifest entry for ' . $stat->dist;
 273   unless ($self->_run([ 'ebuild', $file, 'manifest' ], 0)) {
 274    1 while unlink $file;
 275    return 0;
 276   }
 277  }
 278
 279  return 1;
 280 }
 281
 282 sub install {
 283  my $self = shift;
 284  my $stat = $self->status;
 285  my $conf = $self->parent->parent->configure_object;
 286
 287  my $sudo = $conf->get_program('sudo');
 288  my @cmd = ('emerge', '=' . $stat->eb_name . '-' . $stat->eb_version);
 289  unshift @cmd, $sudo if $sudo;
 290
 291  return $self->_run(\@cmd, 1);
 292 }
 293
 294 sub uninstall {
 295  my $self = shift;
 296  my $stat = $self->status;
 297  my $conf = $self->parent->parent->configure_object;
 298
 299  my $sudo = $conf->get_program('sudo');
 300  my @cmd = ('emerge', '-C', '=' . $stat->eb_name . '-' . $stat->eb_version);
 301  unshift @cmd, $sudo if $sudo;
 302
 303  return $self->_run(\@cmd, 1);
 304 }
 305
 306 sub _run {
 307  my ($self, $cmd, $verbose) = @_;
 308  my $stat = $self->status;
 309
 310  my ($success, $errmsg, $output) = do {
 311   local $ENV{PORTDIR_OVERLAY}     = $stat->overlay;
 312   local $ENV{PORTAGE_RO_DISTDIRS} = $stat->distdir;
 313   run command => $cmd, verbose => $verbose;
 314  };
 315
 316  unless ($success) {
 317   error "$errmsg -- aborting";
 318   if (not $verbose and defined $output and $self->status->verbose) {
 319    my $msg = join '', @$output;
 320    1 while chomp $msg;
 321    error $msg;
 322   }
 323  }
 324
 325  return $success;
 326 }
 327
 328 =head1 DEPENDENCIES
 329
 330 Gentoo (L<http://gentoo.org>).
 331
 332 L<CPANPLUS>, L<IPC::Cmd> (core modules since 5.9.5).
 333
 334 L<File::Path> (since 5.001), L<File::Copy> (5.002), L<File::Spec::Functions> (5.00504).
 335
 336 =head1 SEE ALSO
 337
 338 L<cpan2dist>.
 339
 340 L<CPANPLUS::Dist::Base>, L<CPANPLUS::Dist::Deb>, L<CPANPLUS::Dist::Mdv>.
 341
 342 =head1 AUTHOR
 343
 344 Vincent Pit, C<< <perl at profvince.com> >>, L<http://www.profvince.com>.
 345
 346 You can contact me by mail or on C<irc.perl.org> (vincent).
 347
 348 =head1 BUGS
 349
 350 Please report any bugs or feature requests to C<bug-cpanplus-dist-gentoo at rt.cpan.org>, or through the web interface at L<http://rt.cpan.org/NoAuth/ReportBug.html?Queue=CPANPLUS-Dist-Gentoo>.  I will be notified, and then you'll automatically be notified of progress on your bug as I make changes.
 351
 352 =head1 SUPPORT
 353
 354 You can find documentation for this module with the perldoc command.
 355
 356     perldoc CPANPLUS::Dist::Gentoo
 357
 358 =head1 ACKNOWLEDGEMENTS
 359
 360 The module is to some extend cargo-culted from L<CPANPLUS::Dist::Deb> and L<CPANPLUS::Dist::Mdv>.
 361
 362 =head1 COPYRIGHT & LICENSE
 363
 364 Copyright 2008 Vincent Pit, all rights reserved.
 365
 366 This program is free software; you can redistribute it and/or modify it under the same terms as Perl itself.
 367
 368 =cut
 369
 370 1; # End of CPANPLUS::Dist::Gentoo