lib/CPANPLUS/Dist/Gentoo.pm

   1 package CPANPLUS::Dist::Gentoo;
   2
   3 use strict;
   4 use warnings;
   5
   6 use File::Copy qw/copy/;
   7 use File::Path qw/mkpath/;
   8 use File::Spec::Functions qw/catdir catfile/;
   9
  10 use IPC::Cmd qw/run can_run/;
  11
  12 use CPANPLUS::Error;
  13
  14 use base qw/CPANPLUS::Dist::Base/;
  15
  16 =head1 NAME
  17
  18 CPANPLUS::Dist::Gentoo - CPANPLUS backend generating Gentoo ebuilds.
  19
  20 =head1 VERSION
  21
  22 Version 0.02_01
  23
  24 =cut
  25
  26 our $VERSION = '0.02_01';
  27
  28 =head1 SYNOPSIS
  29
  30     cpan2dist --format=CPANPLUS::Dist::Gentoo \
  31               --dist-opts overlay=/usr/local/portage \
  32               --dist-opts distdir=/usr/portage/distfiles \
  33               --dist-opts manifest=yes \
  34               --dist-opts keywords=x86 \
  35               Any::Module You::Like
  36
  37 =head1 DESCRPITON
  38
  39 This module is a CPANPLUS backend that recursively generates Gentoo ebuilds for a given package in the specified overlay (defaults to C</usr/local/portage>), update the manifest, and even emerge it (together with its dependencies) if the user requires it. You need write permissions on the directory where Gentoo fetches its source files (usually C</usr/portage/distfiles>).
  40
  41 The generated ebuilds are placed into the section C<perl-gcpanp>. They favour depending on C<perl-core> or C<dev-perl> rather than C<perl-gcpanp>.
  42
  43 =head1 INSTALLATION
  44
  45 After installing this module, you should append C<perl-gcpanp> to your F</etc/portage/categories> file.
  46
  47 =head1 METHODS
  48
  49 All the methods are inherited from L<CPANPLUS::Dist::Base>. Please refer to its perldoc for precise information on what's done at each step.
  50
  51 =cut
  52
  53 use constant CATEGORY => 'perl-gcpanp';
  54
  55 sub format_available {
  56  for my $prog (qw/emerge ebuild/) {
  57   unless (can_run($prog)) {
  58    error "$prog is required to write ebuilds -- aborting";
  59    return 0;
  60   }
  61  }
  62  return 1;
  63 }
  64
  65 sub init {
  66  my ($self) = @_;
  67  my $stat = $self->status;
  68  my $conf = $self->parent->parent->configure_object;
  69
  70  $stat->mk_accessors(qw/name version dist desc uri src license deps
  71                         eb_name eb_version eb_dir eb_file fetched_arch
  72                         overlay distdir keywords do_manifest
  73                         force verbose/);
  74
  75  $stat->force($conf->get_conf('force'));
  76  $stat->verbose($conf->get_conf('verbose'));
  77
  78  return 1;
  79 }
  80
  81 my %gentooism = (
  82  'Digest'            => 'digest-base',
  83  'Locale-Maketext'   => 'locale-maketext',
  84  'Net-Ping'          => 'net-ping',
  85  'PathTools'         => 'File-Spec',
  86  'PodParser'         => 'Pod-Parser',
  87  'Set-Scalar'        => 'set-scalar',
  88  'Tie-EncryptedHash' => 'tie-encryptedhash',
  89 );
  90
  91 sub prepare {
  92  my $self = shift;
  93  my $mod  = $self->parent;
  94  my $stat = $self->status;
  95  my $int  = $mod->parent;
  96  my $conf = $int->configure_object;
  97
  98  my %opts = @_;
  99
 100  my $keywords = delete $opts{'keywords'};
 101  $keywords = 'x86' unless defined $keywords;
 102  $keywords = [ split ' ', $keywords ];
 103  $stat->keywords($keywords);
 104
 105  my $manifest = delete $opts{'manifest'};
 106  $manifest = 1 unless defined $manifest;
 107  $manifest = 0 if $manifest =~ /^\s*no?\s*$/i;
 108  $stat->do_manifest($manifest);
 109
 110  $stat->overlay(delete($opts{'overlay'}) || '/usr/local/portage');
 111
 112  $stat->distdir(delete($opts{'distdir'}) || '/usr/portage/distfiles');
 113
 114  if ($stat->do_manifest && !-w $stat->distdir) {
 115   error 'distdir isn\'t writable -- aborting';
 116   return 0;
 117  }
 118  $stat->fetched_arch($mod->status->fetch);
 119
 120  my $name = $mod->package_name;
 121  $stat->name($name);
 122
 123  my $version = $mod->package_version;
 124  $stat->version($version);
 125
 126  $stat->dist($name . '-' . $version);
 127
 128  my $f = 1;
 129  $version =~ s/_+/$f ? do { $f = 0; '_p' } : ''/ge;
 130  1 while $version =~ s/(_p[^.]*)\.+/$1/;
 131  $stat->eb_version($version);
 132
 133  $stat->eb_name($gentooism{$name} || $name);
 134
 135  $stat->eb_dir(catdir($stat->overlay, CATEGORY, $stat->eb_name));
 136
 137  my $file = catfile($stat->eb_dir,
 138                     $stat->eb_name . '-' . $stat->eb_version . '.ebuild');
 139  if (-e $file) {
 140   my $skip = 1;
 141   if ($stat->force) {
 142    if (-w $file) {
 143     1 while unlink $file;
 144     $skip = 0;
 145    } else {
 146     error "Can't force rewriting of $file -- skipping";
 147    }
 148   } else {
 149    msg 'Ebuild already generated for ' . $stat->dist . ' -- skipping';
 150   }
 151   if ($skip) {
 152    $stat->prepared(1);
 153    $stat->created(1);
 154    return 1;
 155   }
 156  }
 157  $stat->eb_file($file);
 158
 159  $self->SUPER::prepare(%opts);
 160
 161  my $desc = $mod->description;
 162  ($desc = $name) =~ s/-+/::/g unless $desc;
 163  $stat->desc($desc);
 164
 165  $stat->uri('http://search.cpan.org/dist/' . $name);
 166
 167  unless ($name =~ /^([^-]+)/) {
 168   error 'Wrong distribution name -- aborting';
 169   return 0;
 170  }
 171  $stat->src('mirror://cpan/modules/by-module/' . $1 . '/' . $mod->package);
 172
 173  $stat->license([ qw/Artistic GPL-2/ ]);
 174
 175  my $prereqs = $mod->status->prereqs;
 176  $prereqs = { map { ($gentooism{$_} || $_) => $prereqs->{$_} } keys %$prereqs };
 177  my @depends;
 178  for my $prereq (sort keys %$prereqs) {
 179   next if $prereq =~ /^perl(?:-|\z)/;
 180   my $obj = $int->module_tree($prereq);
 181   unless ($obj) {
 182    error 'Wrong module object -- aborting';
 183    return 0;
 184   }
 185   next if $obj->package_is_perl_core;
 186   {
 187    my $version;
 188    if ($prereqs->{$prereq}) {
 189     if ($obj->installed_version && $obj->installed_version < $obj->version) {
 190      $version = $obj->installed_version;
 191     } else {
 192      $version = $obj->package_version;
 193     }
 194    }
 195    push @depends, [ $obj , $version ];
 196   }
 197  }
 198  $stat->deps(\@depends);
 199
 200  return 1;
 201 }
 202
 203 sub create {
 204  my $self = shift;
 205  my $stat = $self->status;
 206
 207  unless ($stat->prepared) {
 208   error 'Can\'t create ' . $stat->dist . ' since it was never prepared -- aborting';
 209   return 0;
 210  }
 211
 212  if ($stat->created) {
 213   msg $stat->dist . ' was already created -- skipping';
 214   return 1;
 215  }
 216
 217  $self->SUPER::create(@_);
 218
 219  my $dir = $stat->eb_dir;
 220  unless (-d $dir) {
 221   eval { mkpath $dir };
 222   if ($@) {
 223    error "mkpath($dir): $@";
 224    return 0;
 225   }
 226  }
 227
 228  my $d = "# Generated by CPANPLUS::Dist::Gentoo\n\ninherit perl-module\n\n";
 229  $d   .= 'S="${WORKDIR}/' . $stat->dist . "\"\n";
 230  $d   .= 'DESCRIPTION="' . $stat->desc . "\"\n";
 231  $d   .= 'HOMEPAGE="' . $stat->uri . "\"\n";
 232  $d   .= 'SRC_URI="' . $stat->src . "\"\n";
 233  $d   .= "SLOT=\"0\"\n";
 234  $d   .= 'LICENSE="|| ( ' . join(' ', sort @{$stat->license}) . " )\"\n";
 235  $d   .= 'KEYWORDS="' . join(' ', sort @{$stat->keywords}) . "\"\n";
 236  $d   .= 'DEPEND="' . join "\n",
 237   'dev-lang/perl',
 238   map {
 239    my $a = $_->[0]->package_name;
 240    my $x = '';
 241    if (defined $_->[1]) {
 242     $x  = '>=';
 243     $a .= '-' . $_->[1];
 244    }
 245    '|| ( ' . join(' ', map "$x$_/$a",
 246                            qw/perl-core dev-perl perl-gcpan/, CATEGORY)
 247            . ' )';
 248   } @{$stat->deps};
 249  $d   .= "\"\n";
 250
 251  my $file = $stat->eb_file;
 252  open my $eb, '>', $file or do {
 253   error "open($file): $! -- aborting";
 254   return 0;
 255  };
 256  print $eb $d;
 257  close $eb;
 258
 259  if ($stat->do_manifest) {
 260   unless (copy $stat->fetched_arch, $stat->distdir) {
 261    error "Couldn\'t copy the distribution file to distdir ($!) -- aborting";
 262    1 while unlink $file;
 263    return 0;
 264   }
 265
 266   msg 'Adding Manifest entry for ' . $stat->dist;
 267   unless ($self->_run([ 'ebuild', $file, 'manifest' ], 0)) {
 268    1 while unlink $file;
 269    return 0;
 270   }
 271  }
 272
 273  return 1;
 274 }
 275
 276 sub install {
 277  my $self = shift;
 278  my $stat = $self->status;
 279  my $conf = $self->parent->parent->configure_object;
 280
 281  my $sudo = $conf->get_program('sudo');
 282  my @cmd = ('emerge', '=' . $stat->eb_name . '-' . $stat->eb_version);
 283  unshift @cmd, $sudo if $sudo;
 284
 285  return $self->_run(\@cmd, 1);
 286 }
 287
 288 sub uninstall {
 289  my $self = shift;
 290  my $stat = $self->status;
 291  my $conf = $self->parent->parent->configure_object;
 292
 293  my $sudo = $conf->get_program('sudo');
 294  my @cmd = ('emerge', '-C', '=' . $stat->eb_name . '-' . $stat->eb_version);
 295  unshift @cmd, $sudo if $sudo;
 296
 297  return $self->_run(\@cmd, 1);
 298 }
 299
 300 sub _run {
 301  my ($self, $cmd, $verbose) = @_;
 302  my $stat = $self->status;
 303
 304  my ($success, $errmsg, $output) = do {
 305   local $ENV{PORTDIR_OVERLAY}     = $stat->overlay;
 306   local $ENV{PORTAGE_RO_DISTDIRS} = $stat->distdir;
 307   run command => $cmd, verbose => $verbose;
 308  };
 309
 310  unless ($success) {
 311   error "$errmsg -- aborting";
 312   if (not $verbose and defined $output and $self->status->verbose) {
 313    my $msg = join '', @$output;
 314    1 while chomp $msg;
 315    error $msg;
 316   }
 317  }
 318
 319  return $success;
 320 }
 321
 322 =head1 DEPENDENCIES
 323
 324 Gentoo (L<http://gentoo.org>).
 325
 326 L<CPANPLUS>, L<IPC::Cmd> (core modules since 5.9.5).
 327
 328 L<File::Path> (since 5.001), L<File::Copy> (5.002), L<File::Spec::Functions> (5.00504).
 329
 330 =head1 SEE ALSO
 331
 332 L<cpan2dist>.
 333
 334 L<CPANPLUS::Dist::Base>, L<CPANPLUS::Dist::Deb>, L<CPANPLUS::Dist::Mdv>.
 335
 336 =head1 AUTHOR
 337
 338 Vincent Pit, C<< <perl at profvince.com> >>, L<http://www.profvince.com>.
 339
 340 You can contact me by mail or on C<irc.perl.org> (vincent).
 341
 342 =head1 BUGS
 343
 344 Please report any bugs or feature requests to C<bug-cpanplus-dist-gentoo at rt.cpan.org>, or through the web interface at L<http://rt.cpan.org/NoAuth/ReportBug.html?Queue=CPANPLUS-Dist-Gentoo>.  I will be notified, and then you'll automatically be notified of progress on your bug as I make changes.
 345
 346 =head1 SUPPORT
 347
 348 You can find documentation for this module with the perldoc command.
 349
 350     perldoc CPANPLUS::Dist::Gentoo
 351
 352 =head1 ACKNOWLEDGEMENTS
 353
 354 The module is to some extend cargo-culted from L<CPANPLUS::Dist::Deb> and L<CPANPLUS::Dist::Mdv>.
 355
 356 =head1 COPYRIGHT & LICENSE
 357
 358 Copyright 2008 Vincent Pit, all rights reserved.
 359
 360 This program is free software; you can redistribute it and/or modify it under the same terms as Perl itself.
 361
 362 =cut
 363
 364 1; # End of CPANPLUS::Dist::Gentoo