lib/CPANPLUS/Dist/Gentoo.pm

   1 package CPANPLUS::Dist::Gentoo;
   2
   3 use strict;
   4 use warnings;
   5
   6 use File::Copy qw/copy/;
   7 use File::Path qw/mkpath/;
   8 use File::Spec::Functions qw/catdir catfile/;
   9
  10 use IPC::Cmd qw/run can_run/;
  11
  12 use CPANPLUS::Error;
  13
  14 use base qw/CPANPLUS::Dist::Base/;
  15
  16 =head1 NAME
  17
  18 CPANPLUS::Dist::Gentoo - CPANPLUS backend generating Gentoo ebuilds.
  19
  20 =head1 VERSION
  21
  22 Version 0.02_01
  23
  24 =cut
  25
  26 our $VERSION = '0.02_01';
  27
  28 =head1 SYNOPSIS
  29
  30     cpan2dist --format=CPANPLUS::Dist::Gentoo \
  31               --dist-opts overlay=/usr/local/portage \
  32               --dist-opts distdir=/usr/portage/distfiles \
  33               --dist-opts manifest=yes \
  34               --dist-opts keywords=x86 \
  35               Any::Module You::Like
  36
  37 =head1 DESCRPITON
  38
  39 This module is a CPANPLUS backend that recursively generates Gentoo ebuilds for a given package in the specified overlay (defaults to C</usr/local/portage>), update the manifest, and even emerge it (together with its dependencies) if the user requires it. You need write permissions on the directory where Gentoo fetches its source files (usually C</usr/portage/distfiles>).
  40
  41 The generated ebuilds are placed into the section C<perl-gcpanp>. They favour depending on C<perl-core> or C<dev-perl> rather than C<perl-gcpanp>.
  42
  43 =head1 INSTALLATION
  44
  45 After installing this module, you should append C<perl-gcpanp> to your F</etc/portage/categories> file.
  46
  47 =head1 METHODS
  48
  49 All the methods are inherited from L<CPANPLUS::Dist::Base>. Please refer to its perldoc for precise information on what's done at each step.
  50
  51 =cut
  52
  53 use constant CATEGORY => 'perl-gcpanp';
  54
  55 sub format_available {
  56  for my $prog (qw/emerge ebuild/) {
  57   unless (can_run($prog)) {
  58    error "$prog is required to write ebuilds -- aborting";
  59    return 0;
  60   }
  61  }
  62  return 1;
  63 }
  64
  65 sub init {
  66  my ($self) = @_;
  67  my $stat = $self->status;
  68  my $conf = $self->parent->parent->configure_object;
  69
  70  $stat->mk_accessors(qw/name version dist desc uri src license deps
  71                         eb_name eb_version eb_dir eb_file fetched_arch
  72                         overlay distdir keywords do_manifest
  73                         verbose/);
  74
  75  $stat->verbose($conf->get_conf('verbose'));
  76
  77  return 1;
  78 }
  79
  80 my %gentooism = (
  81  'Digest'            => 'digest-base',
  82  'Locale-Maketext'   => 'locale-maketext',
  83  'Net-Ping'          => 'net-ping',
  84  'PathTools'         => 'File-Spec',
  85  'PodParser'         => 'Pod-Parser',
  86  'Set-Scalar'        => 'set-scalar',
  87  'Tie-EncryptedHash' => 'tie-encryptedhash',
  88 );
  89
  90 sub prepare {
  91  my $self = shift;
  92  my $mod  = $self->parent;
  93  my $stat = $self->status;
  94  my $int  = $mod->parent;
  95  my $conf = $int->configure_object;
  96
  97  my %opts = @_;
  98
  99  my $keywords = delete $opts{'keywords'};
 100  $keywords = 'x86' unless defined $keywords;
 101  $keywords = [ split ' ', $keywords ];
 102  $stat->keywords($keywords);
 103
 104  my $manifest = delete $opts{'manifest'};
 105  $manifest = 1 unless defined $manifest;
 106  $manifest = 0 if $manifest =~ /^\s*no?\s*$/i;
 107  $stat->do_manifest($manifest);
 108
 109  my $overlay = catdir(delete($opts{'overlay'}) || '/usr/local/portage',
 110                       CATEGORY);
 111  $stat->overlay($overlay);
 112
 113  $stat->distdir(delete($opts{'distdir'}) || '/usr/portage/distfiles');
 114  if ($stat->do_manifest && !-w $stat->distdir) {
 115   error 'distdir isn\'t writable -- aborting';
 116   return 0;
 117  }
 118  $stat->fetched_arch($mod->status->fetch);
 119
 120  my $name = $mod->package_name;
 121  $stat->name($name);
 122
 123  my $version = $mod->package_version;
 124  $stat->version($version);
 125  $stat->dist($name . '-' . $version);
 126  my $f = 1;
 127  $version =~ s/_+/$f ? do { $f = 0; '_p' } : ''/ge;
 128  1 while $version =~ s/(_p[^.]*)\.+/$1/;
 129  $stat->eb_version($version);
 130
 131  $stat->eb_name($gentooism{$stat->name} || $stat->name);
 132  $stat->eb_dir(catdir($overlay, $stat->eb_name));
 133  $stat->eb_file(catfile($stat->eb_dir,
 134                         $stat->eb_name . '-' . $stat->eb_version . '.ebuild'));
 135  if (-r $stat->eb_file) {
 136   msg 'Ebuild already generated for ' . $stat->dist . ' -- skipping';
 137   $stat->prepared(1);
 138   $stat->created(1);
 139   return 1;
 140  }
 141
 142  $self->SUPER::prepare(%opts);
 143
 144  my $desc = $mod->description;
 145  ($desc = $name) =~ s/-+/::/g unless $desc;
 146  $stat->desc($desc);
 147  $stat->uri('http://search.cpan.org/dist/' . $name);
 148  unless ($name =~ /^([^-]+)/) {
 149   error 'Wrong distribution name -- aborting';
 150   return 0;
 151  }
 152  $stat->src('mirror://cpan/modules/by-module/' . $1 . '/' . $mod->package);
 153  $stat->license([ qw/Artistic GPL-2/ ]);
 154
 155  my $prereqs = $mod->status->prereqs;
 156  $prereqs = { map { ($gentooism{$_} || $_) => $prereqs->{$_} } keys %$prereqs };
 157  my @depends;
 158  for my $prereq (sort keys %$prereqs) {
 159   next if $prereq =~ /^perl(?:-|\z)/;
 160   my $obj = $int->module_tree($prereq);
 161   unless ($obj) {
 162    error 'Wrong module object -- aborting';
 163    return 0;
 164   }
 165   next if $obj->package_is_perl_core;
 166   {
 167    my $version;
 168    if ($prereqs->{$prereq}) {
 169     if ($obj->installed_version && $obj->installed_version < $obj->version) {
 170      $version = $obj->installed_version;
 171     } else {
 172      $version = $obj->package_version;
 173     }
 174    }
 175    push @depends, [ $obj , $version ];
 176   }
 177  }
 178  $stat->deps(\@depends);
 179
 180  return 1;
 181 }
 182
 183 sub create {
 184  my $self = shift;
 185  my $stat = $self->status;
 186
 187  unless ($stat->prepared) {
 188   error 'Can\'t create ' . $stat->dist . ' since it was never prepared -- aborting';
 189   return 0;
 190  }
 191
 192  if ($stat->created) {
 193   msg $stat->dist . ' was already created -- skipping';
 194   return 1;
 195  }
 196
 197  $self->SUPER::create(@_);
 198
 199  my $dir = $stat->eb_dir;
 200  unless (-d $dir) {
 201   eval { mkpath $dir };
 202   if ($@) {
 203    error "mkpath($dir): $@";
 204    return 0;
 205   }
 206  }
 207
 208  my $d = "# Generated by CPANPLUS::Dist::Gentoo\n\ninherit perl-module\n\n";
 209  $d   .= 'S="${WORKDIR}/' . $stat->dist . "\"\n";
 210  $d   .= 'DESCRIPTION="' . $stat->desc . "\"\n";
 211  $d   .= 'HOMEPAGE="' . $stat->uri . "\"\n";
 212  $d   .= 'SRC_URI="' . $stat->src . "\"\n";
 213  $d   .= "SLOT=\"0\"\n";
 214  $d   .= 'LICENSE="|| ( ' . join(' ', sort @{$stat->license}) . " )\"\n";
 215  $d   .= 'KEYWORDS="' . join(' ', sort @{$stat->keywords}) . "\"\n";
 216  $d   .= 'DEPEND="' . join "\n",
 217   'dev-lang/perl',
 218   map {
 219    my $a = $_->[0]->package_name;
 220    my $x = '';
 221    if (defined $_->[1]) {
 222     $x  = '>=';
 223     $a .= '-' . $_->[1];
 224    }
 225    '|| ( ' . join(' ', map "$x$_/$a",
 226                            qw/perl-core dev-perl perl-gcpan/, CATEGORY)
 227            . ' )';
 228   } @{$stat->deps};
 229  $d   .= "\"\n";
 230
 231  my $file = $stat->eb_file;
 232  open my $eb, '>', $file or do {
 233   error "open($file): $! -- aborting";
 234   return 0;
 235  };
 236  print $eb $d;
 237  close $eb;
 238
 239  if ($stat->do_manifest) {
 240   unless (copy $stat->fetched_arch, $stat->distdir) {
 241    error "Couldn\'t copy the distribution file to distdir ($!) -- aborting";
 242    1 while unlink $file;
 243    return 0;
 244   }
 245
 246   msg 'Adding Manifest entry for ' . $stat->dist;
 247   unless ($self->_run([ 'ebuild', $file, 'manifest' ], 0)) {
 248    1 while unlink $file;
 249    return 0;
 250   }
 251  }
 252
 253  return 1;
 254 }
 255
 256 sub install {
 257  my $self = shift;
 258  my $stat = $self->status;
 259  my $conf = $self->parent->parent->configure_object;
 260
 261  my $sudo = $conf->get_program('sudo');
 262  my @cmd = ('emerge', '=' . $stat->eb_name . '-' . $stat->eb_version);
 263  unshift @cmd, $sudo if $sudo;
 264
 265  return $self->_run(\@cmd, 1);
 266 }
 267
 268 sub uninstall {
 269  my $self = shift;
 270  my $stat = $self->status;
 271  my $conf = $self->parent->parent->configure_object;
 272
 273  my $sudo = $conf->get_program('sudo');
 274  my @cmd = ('emerge', '-C', '=' . $stat->eb_name . '-' . $stat->eb_version);
 275  unshift @cmd, $sudo if $sudo;
 276
 277  return $self->_run(\@cmd, 1);
 278 }
 279
 280 sub _run {
 281  my ($self, $cmd, $verbose) = @_;
 282
 283  my ($success, $errmsg, $output) = run command => $cmd, verbose => $verbose;
 284  unless ($success) {
 285   error "$errmsg -- aborting";
 286   if (not $verbose and defined $output and $self->status->verbose) {
 287    my $msg = join '', @$output;
 288    1 while chomp $msg;
 289    error $msg;
 290   }
 291  }
 292
 293  return $success;
 294 }
 295
 296 =head1 DEPENDENCIES
 297
 298 Gentoo (L<http://gentoo.org>).
 299
 300 L<CPANPLUS>, L<IPC::Cmd> (core modules since 5.9.5).
 301
 302 L<File::Path> (since 5.001), L<File::Copy> (5.002), L<File::Spec::Functions> (5.00504).
 303
 304 =head1 SEE ALSO
 305
 306 L<cpan2dist>.
 307
 308 L<CPANPLUS::Dist::Base>, L<CPANPLUS::Dist::Deb>, L<CPANPLUS::Dist::Mdv>.
 309
 310 =head1 AUTHOR
 311
 312 Vincent Pit, C<< <perl at profvince.com> >>, L<http://www.profvince.com>.
 313
 314 You can contact me by mail or on C<irc.perl.org> (vincent).
 315
 316 =head1 BUGS
 317
 318 Please report any bugs or feature requests to C<bug-cpanplus-dist-gentoo at rt.cpan.org>, or through the web interface at L<http://rt.cpan.org/NoAuth/ReportBug.html?Queue=CPANPLUS-Dist-Gentoo>.  I will be notified, and then you'll automatically be notified of progress on your bug as I make changes.
 319
 320 =head1 SUPPORT
 321
 322 You can find documentation for this module with the perldoc command.
 323
 324     perldoc CPANPLUS::Dist::Gentoo
 325
 326 =head1 ACKNOWLEDGEMENTS
 327
 328 The module is to some extend cargo-culted from L<CPANPLUS::Dist::Deb> and L<CPANPLUS::Dist::Mdv>.
 329
 330 =head1 COPYRIGHT & LICENSE
 331
 332 Copyright 2008 Vincent Pit, all rights reserved.
 333
 334 This program is free software; you can redistribute it and/or modify it under the same terms as Perl itself.
 335
 336 =cut
 337
 338 1; # End of CPANPLUS::Dist::Gentoo