lib/Bit/MorseSignals/Receiver.pm

   1 package Bit::MorseSignals::Receiver;
   2
   3 use strict;
   4 use warnings;
   5
   6 use Carp qw/croak/;
   7 use Encode qw/decode_utf8/;
   8 use Storable qw/thaw/;
   9
  10 use Bit::MorseSignals qw/:consts/;
  11
  12 =head1 NAME
  13
  14 Bit::MorseSignals::Receiver - Base class for Bit::MorseSignals receivers.
  15
  16 =head1 VERSION
  17
  18 Version 0.03
  19
  20 =cut
  21
  22 our $VERSION = '0.03';
  23
  24 =head1 SYNOPSIS
  25
  26     use Bit::MorseSignals::Receiver;
  27
  28     my $pants = new Bit::MorseSignals::Receiver done => sub { print "received $_[1]!\n" };
  29     while (...) {
  30      my $bit = comes_from_somewhere_lets_say_signals();
  31      $pants->push($bit);
  32     }
  33
  34 =head1 DESCRIPTION
  35
  36 Base class for L<Bit::MorseSignals> receivers. Please refer to this module for more general information about the protocol.
  37
  38 Given a sequence of bits coming from the L<Bit::MorseSignals> protocol, the receiver object detects when a packet has been completed and then reconstructs the original message depending of the datatype specified in the header.
  39
  40 =cut
  41
  42 sub _check_self {
  43  croak 'First argument isn\'t a valid ' . __PACKAGE__ . ' object'
  44   unless ref $_[0] and $_[0]->isa(__PACKAGE__);
  45 }
  46
  47 =head1 METHODS
  48
  49 =head2 C<< new [ done => $cb ] >>
  50
  51 L<Bit::MorseSignals::Receiver> object constructor. With the C<'done'> option, you can specify a callback that will be triggered every time a message is completed, and in which C<$_[0]> will be the receiver object and C<$_[1]> the message received.
  52
  53 =cut
  54
  55 sub new {
  56  my $class = shift;
  57  $class = ref $class || $class || return;
  58  croak 'Optional arguments must be passed as key => value pairs' if @_ % 2;
  59  my %opts = @_;
  60  my $self = {
  61   msg    => undef,
  62   done   => $opts{done},
  63  };
  64  bless $self, $class;
  65  $self->reset;
  66  return $self;
  67 }
  68
  69 =head2 C<push $bit>
  70
  71 Tells the receiver that you have received the bit C<$bit>. Returns true while the message isn't completed, and C<undef> as soon as it is.
  72
  73 =cut
  74
  75 sub push {
  76  my ($self, $bit) = @_;
  77  _check_self($self);
  78  if (!defined $bit) {
  79   $bit = $_;
  80   return unless defined $bit;
  81  }
  82  $bit = $bit ? 1 : 0;
  83
  84  if ($self->{state} == 3) { # data
  85
  86   vec($self->{buf}, $self->{len}, 1) = $bit;
  87   ++$self->{len};
  88   if ($self->{len} >= $self->{sig_len}) {
  89    my $res = 1;
  90    for (1 .. $self->{sig_len}) {
  91     if (vec($self->{buf}, $self->{len} - $_, 1) != vec($self->{sig}, $_-1, 1)) {
  92      $res = 0;
  93      last;
  94     }
  95    }
  96    if ($res) {
  97     my $base = int $self->{sig_len} / 8 + $self->{sig_len} % 8 != 0;
  98     substr $self->{buf}, -$base, $base, '';
  99     my @demanglers = (sub { $_[0] }, \&decode_utf8, \&thaw  );
 100     #        BM_DATA_{PLAIN,         UTF8,          STORABLE}
 101     $self->{msg} = defined $demanglers[$self->{type}]
 102                     ? $demanglers[$self->{type}]->($self->{buf})
 103                     : $self->{buf};
 104     $self->reset;
 105     $self->{done}->($self, $self->{msg}) if $self->{done};
 106     return;
 107    }
 108   }
 109
 110  } elsif ($self->{state} == 2) { # header
 111
 112   vec($self->{buf}, $self->{len}++, 1) = $bit;
 113   if ($self->{len} >= 3) {
 114    my $type = 2 * vec($self->{buf}, 0, 1)
 115                 + vec($self->{buf}, 1, 1);
 116    $type = BM_DATA_PLAIN if vec($self->{buf}, 2, 1);
 117    @{$self}{qw/state type buf len/} = (3, $type, '', 0);
 118   }
 119
 120  } elsif ($self->{state} == 1) { # end of signature
 121
 122   if ($self->{sig_bit} != $bit) {
 123    $self->{state} = 2;
 124   }
 125   vec($self->{sig}, $self->{sig_len}++, 1) = $bit;
 126
 127  } else { # first bit
 128
 129   @{$self}{qw/state sig sig_bit sig_len buf len/}
 130            = (1,    '', $bit,   1,      '', 0  );
 131   vec($self->{sig}, 0, 1) = $bit;
 132
 133  }
 134
 135  return $self;
 136 }
 137
 138 =head2 C<reset>
 139
 140 Resets the current receiver state, obliterating any current message being received.
 141
 142 =cut
 143
 144 sub reset {
 145  my ($self) = @_;
 146  _check_self($self);
 147  $self->{state} = 0;
 148  @{$self}{qw/sig sig_bit sig_len type buf len/} = ();
 149  return $self;
 150 }
 151
 152 =head2 C<busy>
 153
 154 True when the receiver is in the middle of assembling a message.
 155
 156 =cut
 157
 158 sub busy {
 159  my ($self) = @_;
 160  _check_self($self);
 161  return $self->{state} > 0;
 162 }
 163
 164 =head2 C<msg>
 165
 166 The last message completed, or C<undef> when no message has been assembled yet.
 167
 168 =cut
 169
 170 sub msg {
 171  my ($self) = @_;
 172  _check_self($self);
 173  return $self->{msg};
 174 }
 175
 176 =head1 EXPORT
 177
 178 An object module shouldn't export any function, and so does this one.
 179
 180 =head1 DEPENDENCIES
 181
 182 L<Carp> (standard since perl 5), L<Encode> (since perl 5.007003), L<Storable> (idem).
 183
 184 =head1 SEE ALSO
 185
 186 L<Bit::MorseSignals>, L<Bit::MorseSignals::Emitter>.
 187
 188 =head1 AUTHOR
 189
 190 Vincent Pit, C<< <perl at profvince.com> >>, L<http://www.profvince.com>.
 191
 192 You can contact me by mail or on #perl @ FreeNode (vincent or Prof_Vince).
 193
 194 =head1 BUGS
 195
 196 Please report any bugs or feature requests to C<bug-bit-morsesignals-receiver at rt.cpan.org>, or through the web interface at L<http://rt.cpan.org/NoAuth/ReportBug.html?Queue=Bit-MorseSignals>.  I will be notified, and then you'll automatically be notified of progress on your bug as I make changes.
 197
 198 =head1 SUPPORT
 199
 200 You can find documentation for this module with the perldoc command.
 201
 202     perldoc Bit::MorseSignals::Receiver
 203
 204 =head1 COPYRIGHT & LICENSE
 205
 206 Copyright 2008 Vincent Pit, all rights reserved.
 207
 208 This program is free software; you can redistribute it and/or modify it
 209 under the same terms as Perl itself.
 210
 211 =cut
 212
 213 1; # End of Bit::MorseSignals::Receiver