lib/B/RecDeparse.pm

   1 package B::RecDeparse;
   2
   3 use 5.008;
   4
   5 use strict;
   6 use warnings;
   7
   8 use Config;
   9
  10 use base qw/B::Deparse/;
  11
  12 =head1 NAME
  13
  14 B::RecDeparse - Deparse recursively into subroutines.
  15
  16 =head1 VERSION
  17
  18 Version 0.04
  19
  20 =cut
  21
  22 our $VERSION = '0.04';
  23
  24 =head1 SYNOPSIS
  25
  26     perl -MO=RecDeparse,deparse,[@B__Deparse_opts],level,-1 [ -e '...' | bleh.pl ]
  27
  28     # Or as a module :
  29     use B::RecDeparse;
  30
  31     my $brd = B::RecDeparse->new(deparse => [ @b__deparse_opts ], level => $level);
  32     my $code = $brd->coderef2text(sub { ... });
  33
  34 =head1 DESCRIPTION
  35
  36 This module extends L<B::Deparse> by making it recursively replace subroutine calls encountered when deparsing.
  37
  38 Please refer to L<B::Deparse> documentation for what to do and how to do it. Besides the constructor syntax, everything should work the same for the two modules.
  39
  40 =head1 METHODS
  41
  42 =head2 C<< new < deparse => [ @B__Deparse_opts ], level => $level > >>
  43
  44 The L<B::RecDeparse> object constructor. You can specify the underlying L<B::Deparse> constructor arguments by passing a string or an array reference as the value of the C<deparse> key. The C<level> option expects an integer that specifies how many levels of recursions are allowed : C<-1> means infinite while C<0> means none and match L<B::Deparse> behaviour.
  45
  46 =cut
  47
  48 use constant {
  49  # p31268 made pp_entersub call single_delim
  50  FOOL_SINGLE_DELIM =>
  51      ($^V ge v5.9.5)
  52   || ($^V lt v5.9.0 and $^V ge v5.8.9)
  53   || ($Config{perl_patchlevel} && $Config{perl_patchlevel} >= 31268)
  54 };
  55
  56 sub _parse_args {
  57  if (@_ % 2) {
  58   require Carp;
  59   Carp::croak('Optional arguments must be passed as key/value pairs');
  60  }
  61  my %args = @_;
  62
  63  my $deparse = $args{deparse};
  64  if (defined $deparse) {
  65   if (!ref $deparse) {
  66    $deparse = [ $deparse ];
  67   } elsif (ref $deparse ne 'ARRAY') {
  68    $deparse = [ ];
  69   }
  70  } else {
  71   $deparse = [ ];
  72  }
  73
  74  my $level = $args{level};
  75  $level    = -1  unless defined $level;
  76  $level    = int $level;
  77
  78  return $deparse, $level;
  79 }
  80
  81 sub new {
  82  my $class = shift;
  83  $class = ref($class) || $class || __PACKAGE__;
  84  my ($deparse, $level) = _parse_args(@_);
  85  my $self = bless $class->SUPER::new(@$deparse), $class;
  86  $self->{brd_level} = $level;
  87  return $self;
  88 }
  89
  90 sub _recurse {
  91  return $_[0]->{brd_level} < 0 || $_[0]->{brd_cur} < $_[0]->{brd_level}
  92 }
  93
  94 sub compile {
  95  my $bd = B::Deparse->new();
  96  my @args = @_;
  97  my ($deparse, $level) = _parse_args(@args);
  98  my $compiler = $bd->coderef2text(B::Deparse::compile(@$deparse));
  99  $compiler =~ s/
 100   ['"]? B::Deparse ['"]? \s* -> \s* (new) \s* \( ([^\)]*) \)
 101  /B::RecDeparse->$1(deparse => [ $2 ], level => $level)/gx;
 102  $compiler = eval 'sub ' . $compiler;
 103  die if $@;
 104  return $compiler;
 105 }
 106
 107 sub init {
 108  my $self = shift;
 109  $self->{brd_cur} = 0;
 110  $self->{brd_sub} = 0;
 111  $self->SUPER::init(@_);
 112 }
 113
 114 my $key = $; . __PACKAGE__ . $;;
 115
 116 if (FOOL_SINGLE_DELIM) {
 117  my $oldsd = *B::Deparse::single_delim{CODE};
 118  no warnings 'redefine';
 119  *B::Deparse::single_delim = sub {
 120   my $body = $_[2];
 121   if ((caller 1)[0] eq __PACKAGE__ and $body =~ s/^$key//) {
 122    return $body;
 123   } else {
 124    $oldsd->(@_);
 125   }
 126  }
 127 }
 128
 129 sub pp_entersub {
 130  my $self = shift;
 131  my $body = do {
 132   local $self->{brd_sub} = 1;
 133   $self->SUPER::pp_entersub(@_);
 134  };
 135  $body =~ s/^&\s*(\w)/$1/ if $self->_recurse;
 136  return $body;
 137 }
 138
 139 sub pp_refgen {
 140  my $self = shift;
 141  return do {
 142   local $self->{brd_sub} = 0;
 143   $self->SUPER::pp_refgen(@_);
 144  }
 145 }
 146
 147 sub pp_gv {
 148  my $self = shift;
 149  my $body;
 150  if ($self->{brd_sub} <= 0 || !$self->_recurse) {
 151   $body = $self->SUPER::pp_gv(@_);
 152  } else {
 153   my $gv = $self->gv_or_padgv($_[0]);
 154   $body = do {
 155    local @{$self}{qw/brd_sub brd_cur/} = (0, $self->{brd_cur} + 1);
 156    'sub ' . $self->indent($self->deparse_sub($gv->CV));
 157   };
 158   if (FOOL_SINGLE_DELIM) {
 159    $body = $key . $body;
 160   } else {
 161    $body .= '->';
 162   }
 163  }
 164  return $body;
 165 }
 166
 167 =head2 C<compile>
 168
 169 =head2 C<init>
 170
 171 =head2 C<pp_entersub>
 172
 173 =head2 C<pp_refgen>
 174
 175 =head2 C<pp_gv>
 176
 177 Functions and methods from L<B::Deparse> reimplemented by this module. Never call them directly.
 178
 179 Otherwise, L<B::RecDeparse> inherits all methods from L<B::Deparse>.
 180
 181 =head1 EXPORT
 182
 183 An object-oriented module shouldn't export any function, and so does this one.
 184
 185 =head1 DEPENDENCIES
 186
 187 L<Carp> (standard since perl 5), L<Config> (since perl 5.00307) and L<B::Deparse> (since perl 5.005).
 188
 189 =head1 AUTHOR
 190
 191 Vincent Pit, C<< <perl at profvince.com> >>, L<http://www.profvince.com>.
 192
 193 You can contact me by mail or on C<irc.perl.org> (vincent).
 194
 195 =head1 BUGS
 196
 197 Please report any bugs or feature requests to C<bug-b-recdeparse at rt.cpan.org>, or through the web interface at L<http://rt.cpan.org/NoAuth/ReportBug.html?Queue=B-RecDeparse>.  I will be notified, and then you'll automatically be notified of progress on your bug as I make changes.
 198
 199 =head1 SUPPORT
 200
 201 You can find documentation for this module with the perldoc command.
 202
 203     perldoc B::RecDeparse
 204
 205 Tests code coverage report is available at L<http://www.profvince.com/perl/cover/B-RecDeparse>.
 206
 207 =head1 COPYRIGHT & LICENSE
 208
 209 Copyright 2008 Vincent Pit, all rights reserved.
 210
 211 This program is free software; you can redistribute it and/or modify it under the same terms as Perl itself.
 212
 213 =cut
 214
 215 1; # End of B::RecDeparse