lib/App/Rgit/Command.pm

   1 package App::Rgit::Command;
   2
   3 use strict;
   4 use warnings;
   5
   6 use Carp qw/croak/;
   7
   8 use Object::Tiny qw/cmd cwd_as_repo args repos/;
   9
  10 use App::Rgit::Utils qw/validate/;
  11 use App::Rgit::Repository;
  12
  13 =head1 NAME
  14
  15 App::Rgit::Command - Base class for App::Rgit commands.
  16
  17 =head1 VERSION
  18
  19 Version 0.01
  20
  21 =cut
  22
  23 our $VERSION = '0.01';
  24
  25 =head1 DESCRIPTION
  26
  27 Base class for L<App::Rgit> commands.
  28
  29 This is an internal class to L<rgit>.
  30
  31 =head1 METHODS
  32
  33 =head2 C<< new cmd => $cmd, args => \@args, repos => \@repos >>
  34
  35 Creates a new command object for C<$cmd> that will called for all repositories C<@repos> with arguments C<@args>.
  36
  37 =cut
  38
  39 my %commands;
  40 __PACKAGE__->action($_ => 'Once') for qw/version help daemon init/, ' ';
  41
  42 sub new {
  43  my ($class, %args) = &validate;
  44  my $cmd = $args{cmd};
  45  $cmd = ' ' unless defined $cmd;
  46  my $action = $class->action($cmd);
  47  croak "Command $cmd shouldn't be executed as an $action"
  48                            unless $class eq __PACKAGE__ or $class->isa($action);
  49  my @repos = grep $_->isa('App::Rgit::Repository'),
  50               ref $args{repos} eq 'ARRAY' ? @{$args{repos}} : $args{repos};
  51  eval "require $action; 1" or croak "Couldn't load $action: $@";
  52  my $r = App::Rgit::Repository->new(fake => 1);
  53  return unless defined $r;
  54  $action->SUPER::new(
  55   cmd         => $cmd,
  56   args        => $args{args} || [ ],
  57   repos       => \@repos,
  58   cwd_as_repo => $r,
  59  );
  60 }
  61
  62 =head2 C<< action $cmd [ => $pkg ] >>
  63
  64 If C<$pkg> is supplied, handles command C<$cmd> with C<$pkg> objects.
  65 Otherwise, returns the current class for C<$cmd>.
  66
  67 =cut
  68
  69 sub action {
  70  my ($self, $cmd, $pkg) = @_;
  71  $cmd = $self->cmd if !defined $cmd
  72                    and defined $self and $self->isa(__PACKAGE__);
  73  return unless defined $cmd;
  74  unless (defined $pkg) {
  75   return __PACKAGE__ . '::Each' unless defined $commands{$cmd};
  76   return $commands{$cmd}
  77  }
  78  $pkg = __PACKAGE__ . '::' . $pkg unless $pkg =~ /:/;
  79  $commands{$cmd} = $pkg;
  80 }
  81
  82 =head2 C<cmd>
  83
  84 =head2 C<cwd_as_repo>
  85
  86 =head2 C<args>
  87
  88 =head2 C<repos>
  89
  90 Accessors.
  91
  92 =head2 C<run $conf>
  93
  94 Runs the command with a L<App::Rgit::Config> configuration object.
  95 Stops as soon as one of the executed commands fails, and returns the corresponding exit code.
  96 Returns zero when all went fine.
  97 Implemented in subclasses.
  98
  99 =head1 SEE ALSO
 100
 101 L<rgit>.
 102
 103 =head1 AUTHOR
 104
 105 Vincent Pit, C<< <perl at profvince.com> >>, L<http://profvince.com>.
 106
 107 You can contact me by mail or on C<irc.perl.org> (vincent).
 108
 109 =head1 BUGS
 110
 111 Please report any bugs or feature requests to C<bug-rgit at rt.cpan.org>, or through the web interface at L<http://rt.cpan.org/NoAuth/ReportBug.html?Queue=rgit>.  I will be notified, and then you'll automatically be notified of progress on your bug as I make changes.
 112
 113 =head1 SUPPORT
 114
 115 You can find documentation for this module with the perldoc command.
 116
 117     perldoc App::Rgit::Command
 118
 119 =head1 COPYRIGHT & LICENSE
 120
 121 Copyright 2008 Vincent Pit, all rights reserved.
 122
 123 This program is free software; you can redistribute it and/or modify it under the same terms as Perl itself.
 124
 125 =cut
 126
 127 1; # End of App::Rgit::Command