t/33-compilation-errors.t

   1 #!perl
   2
   3 use strict;
   4 use warnings;
   5
   6 use Test::More tests => 5;
   7
   8 use lib 't/lib';
   9 use VPIT::TestHelpers 'capture';
  10
  11 BEGIN { delete $ENV{PERL_INDIRECT_PM_DISABLE} }
  12
  13 sub compile_err_code {
  14  my ($fatal) = @_;
  15
  16  if ($fatal) {
  17   $fatal = 'no indirect q[fatal]; sub foo { \$bar }';
  18  } else {
  19   $fatal = 'no indirect;';
  20  }
  21
  22  return "use strict; use warnings; $fatal; baz \$_; sub qux { \$ook }";
  23 }
  24
  25 my $indirect_msg = qr/Indirect call of method "baz" on object "\$_"/;
  26 my $core_err1    = qr/Global symbol "\$bar"/;
  27 my $core_err2    = qr/Global symbol "\$ook"/;
  28 my $aborted      = qr/Execution of -e aborted due to compilation errors\./;
  29 my $failed_req   = qr/Compilation failed in require/;
  30 my $line_end     = qr/[^\n]*\n/;
  31 my $compile_err_warn_exp  = qr/$indirect_msg$line_end$core_err2$line_end/o;
  32 my $compile_err_fatal_exp = qr/$core_err1$line_end$indirect_msg$line_end/o;
  33
  34 SKIP: {
  35  my ($stat, $out, $err) = capture_perl compile_err_code(0);
  36  skip CAPTURE_PERL_FAILED($out) => 1 unless defined $stat;
  37  like $err, qr/\A$compile_err_warn_exp$aborted$line_end\z/o,
  38             'no indirect warn does not hide compilation errors outside of eval';
  39 }
  40
  41 SKIP: {
  42  my $code = compile_err_code(0);
  43  my ($stat, $out, $err) = capture_perl "eval q[$code]; die \$@ if \$@";
  44  skip CAPTURE_PERL_FAILED($out) => 1 unless defined $stat;
  45  like $err, qr/\A$compile_err_warn_exp\z/o,
  46              'no indirect warn does not hide compilation errors inside of eval';
  47 }
  48
  49 SKIP: {
  50  my ($stat, $out, $err) = capture_perl compile_err_code(1);
  51  skip CAPTURE_PERL_FAILED($out) => 1 unless defined $stat;
  52  like $err, qr/\A$compile_err_fatal_exp\z/o,
  53            'no indirect fatal does not hide compilation errors outside of eval';
  54 }
  55
  56 {
  57  local $@;
  58  eval compile_err_code(1);
  59  like $@, qr/\A$compile_err_fatal_exp\z/o,
  60             'no indirect fatal does not hide compilation errors inside of eval';
  61 }
  62
  63 {
  64  local $@;
  65  eval { require indirect::TestCompilationError };
  66  like $@, qr/\A$compile_err_fatal_exp$failed_req$line_end\z/o,
  67          'no indirect fatal does not hide compilation errors inside of require';
  68 }