lib/Variable/Magic.pm

   1 package Variable::Magic;
   2
   3 use 5.007003;
   4
   5 use strict;
   6 use warnings;
   7
   8 use Carp qw/croak/;
   9
  10 =head1 NAME
  11
  12 Variable::Magic - Associate user-defined magic to variables from Perl.
  13
  14 =head1 VERSION
  15
  16 Version 0.20
  17
  18 =cut
  19
  20 our $VERSION;
  21 BEGIN {
  22  $VERSION = '0.20';
  23 }
  24
  25 =head1 SYNOPSIS
  26
  27     use Variable::Magic qw/wizard cast dispell/;
  28
  29     my $wiz = wizard set => sub { print STDERR "now set to ${$_[0]}!\n" };
  30     my $a = 1;
  31     cast $a, $wiz;
  32     $a = 2;          # "now set to 2!"
  33     dispell $a, $wiz;
  34     $a = 3           # (nothing)
  35
  36 =head1 DESCRIPTION
  37
  38 Magic is Perl way of enhancing objects. This mechanism let the user add extra data to any variable and overload syntaxical operations (such as access, assignation or destruction) that can be applied to it. With this module, you can add your own magic to any variable without the pain of the C API.
  39
  40 The operations that can be overloaded are :
  41
  42 =over 4
  43
  44 =item *
  45
  46 C<get>
  47
  48 This magic is invoked when the variable is evaluated (does not include array/hash subscripts and slices).
  49
  50 =item *
  51
  52 C<set>
  53
  54 This one is triggered each time the value of the variable changes (includes array/hash subscripts and slices).
  55
  56 =item *
  57
  58 C<len>
  59
  60 This magic is a little special : it is called when the 'size' or the 'length' of the variable has to be known by Perl. Typically, it's the magic involved when an array is evaluated in scalar context, but also on array assignation and loops (C<for>, C<map> or C<grep>). The callback has then to return the length as an integer.
  61
  62 =item *
  63
  64 C<clear>
  65
  66 This magic is invoked when the variable is reset, such as when an array is emptied. Please note that this is different from undefining the variable, even though the magic is called when the clearing is a result of the undefine (e.g. for an array, but actually a bug prevent it to work before perl 5.9.5 - see the L<history|/PERL MAGIC HISTORY>).
  67
  68 =item *
  69
  70 C<free>
  71
  72 This one can be considered as an object destructor. It happens when the variable goes out of scope (with the exception of global scope), but not when it is undefined.
  73
  74 =item *
  75
  76 C<copy>
  77
  78 This magic only applies to tied arrays and hashes. It fires when you try to access or change their elements. It is available on your perl iff C<MGf_COPY> is true.
  79
  80 =item *
  81
  82 C<dup>
  83
  84 Invoked when the variable is cloned across threads. Currently not available.
  85
  86 =item *
  87
  88 C<local>
  89
  90 When this magic is set on a variable, all subsequent localizations of the variable will trigger the callback. It is available on your perl iff C<MGf_LOCAL> is true.
  91
  92 =back
  93
  94 The following actions only apply to hashes and are available iff C<VMG_UVAR> is true. They are referred to as C<uvar> magics.
  95
  96 =over 4
  97
  98 =item *
  99
 100 C<fetch>
 101
 102 This magic happens each time an element is fetched from the hash.
 103
 104 =item *
 105
 106 C<store>
 107
 108 This one is called when an element is stored into the hash.
 109
 110 =item *
 111
 112 C<exists>
 113
 114 This magic fires when a key is tested for existence in the hash.
 115
 116 =item *
 117
 118 C<delete>
 119
 120 This last one triggers when a key is deleted in the hash, regardless of whether the key actually exists in it.
 121
 122 =back
 123
 124 You can refer to the tests to have more insight of where the different magics are invoked.
 125
 126 To prevent any clash between different magics defined with this module, an unique numerical signature is attached to each kind of magic (i.e. each set of callbacks for magic operations).
 127
 128 =head1 PERL MAGIC HISTORY
 129
 130 The places where magic is invoked have changed a bit through perl history. Here's a little list of the most recent ones.
 131
 132 =over 4
 133
 134 =item *
 135
 136 B<5.6.x>
 137
 138 I<p14416> : 'copy' and 'dup' magic.
 139
 140 =item *
 141
 142 B<5.9.3>
 143
 144 I<p25854> : 'len' magic is no longer called when pushing an element into a magic array.
 145
 146 I<p26569> : 'local' magic.
 147
 148 =item *
 149
 150 B<5.9.5>
 151
 152 I<p31064> : Meaningful 'uvar' magic.
 153
 154 I<p31473> : 'clear' magic wasn't invoked when undefining an array. The bug is fixed as of this version.
 155
 156 =item *
 157
 158 B<5.10.0>
 159
 160 Since C<PERL_MAGIC_uvar> is uppercased, C<hv_magic_check()> triggers 'copy' magic on hash stores for (non-tied) hashes that also have 'uvar' magic.
 161
 162 =item *
 163
 164 B<5.11.x>
 165
 166 I<p32969> : 'len' magic is no longer invoked when calling C<length> with a magical scalar.
 167
 168 =back
 169
 170 =head1 CONSTANTS
 171
 172 =head2 C<SIG_MIN>
 173
 174 The minimum integer used as a signature for user-defined magic.
 175
 176 =head2 C<SIG_MAX>
 177
 178 The maximum integer used as a signature for user-defined magic.
 179
 180 =head2 C<SIG_NBR>
 181
 182     SIG_NBR = SIG_MAX - SIG_MIN + 1
 183
 184 =head2 C<MGf_COPY>
 185
 186 Evaluates to true iff the 'copy' magic is available.
 187
 188 =head2 C<MGf_DUP>
 189
 190 Evaluates to true iff the 'dup' magic is available.
 191
 192 =head2 C<MGf_LOCAL>
 193
 194 Evaluates to true iff the 'local' magic is available.
 195
 196 =head2 C<VMG_UVAR>
 197
 198 When this constant is true, you can use the C<fetch,store,exists,delete> callbacks on hashes.
 199
 200 =head2 C<VMG_COMPAT_ARRAY_PUSH_NOLEN>
 201
 202 True for perls that don't call 'len' magic when you push an element in a magical array.
 203
 204 =head2 C<VMG_COMPAT_ARRAY_UNDEF_CLEAR>
 205
 206 True for perls that call 'clear' magic when undefining magical arrays.
 207
 208 =head2 C<VMG_COMPAT_SCALAR_LENGTH_NOLEN>
 209
 210 True for perls that don't call 'len' magic when taking the C<length> of a magical scalar.
 211
 212 =head2 C<VMG_PERL_PATCHLEVEL>
 213
 214 The perl patchlevel this module was built with, or C<0> for non-debugging perls.
 215
 216 =head2 C<VMG_THREADSAFE>
 217
 218 True iff this module could have been built with thread-safety features enabled.
 219
 220 =head1 FUNCTIONS
 221
 222 =cut
 223
 224 BEGIN {
 225  require XSLoader;
 226  XSLoader::load(__PACKAGE__, $VERSION);
 227 }
 228
 229 =head2 C<wizard>
 230
 231     wizard sig    => ...,
 232            data   => sub { ... },
 233            get    => sub { my ($ref, $data) = @_; ... },
 234            set    => sub { my ($ref, $data) = @_; ... },
 235            len    => sub { my ($ref, $data, $len) = @_; ... ; return $newlen; },
 236            clear  => sub { my ($ref, $data) = @_; ... },
 237            free   => sub { my ($ref, $data) = @_, ... },
 238            copy   => sub { my ($ref, $data, $key, $elt) = @_; ... },
 239            local  => sub { my ($ref, $data) = @_; ... },
 240            fetch  => sub { my ($ref, $data, $key) = @_; ... },
 241            store  => sub { my ($ref, $data, $key) = @_; ... },
 242            exists => sub { my ($ref, $data, $key) = @_; ... },
 243            delete => sub { my ($ref, $data, $key) = @_; ... }
 244
 245 This function creates a 'wizard', an opaque type that holds the magic information. It takes a list of keys / values as argument, whose keys can be :
 246
 247 =over 4
 248
 249 =item *
 250
 251 C<sig>
 252
 253 The numerical signature. If not specified or undefined, a random signature is generated. If the signature matches an already defined magic, then the existant magic object is returned.
 254
 255 =item *
 256
 257 C<data>
 258
 259 A code reference to a private data constructor. It is called each time this magic is cast on a variable, and the scalar returned is used as private data storage for it. C<$_[0]> is a reference to the magic object and C<@_[1 .. @_-1]> are all extra arguments that were passed to L</cast>.
 260
 261 =item *
 262
 263 C<get>, C<set>, C<len>, C<clear>, C<free>, C<copy>, C<local>, C<fetch>, C<store>, C<exists> and C<delete>
 264
 265 Code references to corresponding magic callbacks. You don't have to specify all of them : the magic associated with undefined entries simply won't be hooked. In those callbacks, C<$_[0]> is always a reference to the magic object and C<$_[1]> is always the private data (or C<undef> when no private data constructor was supplied). In the special case of C<len> magic and when the variable is an array, C<$_[2]> contains its normal length. C<$_[2]> is the current key in C<copy>, C<fetch>, C<store>, C<exists> and C<delete> callbacks, although for C<copy> it may just be a copy of the actual key so it's useless to (for example) cast magic on it. C<copy> magic also receives the current element (i.e. the value) in C<$_[3]>.
 266
 267 =back
 268
 269     # A simple scalar tracer
 270     my $wiz = wizard get  => sub { print STDERR "got ${$_[0]}\n" },
 271                      set  => sub { print STDERR "set to ${$_[0]}\n" },
 272                      free => sub { print STDERR "${$_[0]} was deleted\n" }
 273
 274 =cut
 275
 276 sub wizard {
 277  croak 'Wrong number of arguments for wizard()' if @_ % 2;
 278  my %opts = @_;
 279  my @cbs  = qw/sig data get set len clear free/;
 280  push @cbs, 'copy'  if MGf_COPY;
 281  push @cbs, 'dup'   if MGf_DUP;
 282  push @cbs, 'local' if MGf_LOCAL;
 283  push @cbs, qw/fetch store exists delete/ if VMG_UVAR;
 284  my $ret = eval { _wizard(map $opts{$_}, @cbs) };
 285  if (my $err = $@) {
 286   $err =~ s/\sat\s+.*?\n//;
 287   croak $err;
 288  }
 289  return $ret;
 290 }
 291
 292 =head2 C<gensig>
 293
 294 With this tool, you can manually generate random magic signature between SIG_MIN and SIG_MAX inclusive. That's the way L</wizard> creates them when no signature is supplied.
 295
 296     # Generate a signature
 297     my $sig = gensig;
 298
 299 =head2 C<getsig>
 300
 301     getsig $wiz
 302
 303 This accessor returns the magic signature of this wizard.
 304
 305     # Get $wiz signature
 306     my $sig = getsig $wiz;
 307
 308 =head2 C<cast>
 309
 310     cast [$@%&*]var, [$wiz|$sig], ...
 311
 312 This function associates C<$wiz> magic to the variable supplied, without overwriting any other kind of magic. You can also supply the numeric signature C<$sig> instead of C<$wiz>. It returns true on success or when C<$wiz> magic is already present, C<0> on error, and C<undef> when no magic corresponds to the given signature (in case C<$sig> was supplied). All extra arguments specified after C<$wiz> are passed to the private data constructor. If the variable isn't a hash, any C<uvar> callback of the wizard is safely ignored.
 313
 314     # Casts $wiz onto $x. If $wiz isn't a signature, undef can't be returned.
 315     my $x;
 316     die 'error' unless cast $x, $wiz;
 317
 318 =head2 C<getdata>
 319
 320     getdata [$@%&*]var, [$wiz|$sig]
 321
 322 This accessor fetches the private data associated with the magic C<$wiz> (or the signature C<$sig>) in the variable. C<undef> is returned when no such magic or data is found, or when C<$sig> does not represent a current valid magic object.
 323
 324     # Get the attached data.
 325     my $data = getdata $x, $wiz or die 'no such magic or magic has no data';
 326
 327 =head2 C<dispell>
 328
 329     dispell [$@%&*]variable, [$wiz|$sig]
 330
 331 The exact opposite of L</cast> : it dissociates C<$wiz> magic from the variable. You can also pass the magic signature C<$sig> as the second argument. True is returned on success, C<0> on error or when no magic represented by C<$wiz> could be found in the variable, and C<undef> when no magic corresponds to the given signature (in case C<$sig> was supplied).
 332
 333     # Dispell now. If $wiz isn't a signature, undef can't be returned.
 334     die 'no such magic or error' unless dispell $x, $wiz;
 335
 336 =head1 EXPORT
 337
 338 The functions L</wizard>, L</gensig>, L</getsig>, L</cast>, L</getdata> and L</dispell> are only exported on request. All of them are exported by the tags C<':funcs'> and C<':all'>.
 339
 340 The constants L</SIG_MIN>, L</SIG_MAX>, L</SIG_NBR>, L</MGf_COPY>, L</MGf_DUP>, L</MGf_LOCAL> and L</VMG_UVAR> are also only exported on request. They are all exported by the tags C<':consts'> and C<':all'>.
 341
 342 =cut
 343
 344 use base qw/Exporter/;
 345
 346 our @EXPORT         = ();
 347 our %EXPORT_TAGS    = (
 348  'funcs' =>  [ qw/wizard gensig getsig cast getdata dispell/ ],
 349  'consts' => [ qw/SIG_MIN SIG_MAX SIG_NBR MGf_COPY MGf_DUP MGf_LOCAL VMG_UVAR/,
 350                qw/VMG_COMPAT_ARRAY_PUSH_NOLEN VMG_COMPAT_ARRAY_UNDEF_CLEAR/,
 351                qw/VMG_COMPAT_SCALAR_LENGTH_NOLEN/,
 352                qw/VMG_PERL_PATCHLEVEL/,
 353                qw/VMG_THREADSAFE/ ]
 354 );
 355 our @EXPORT_OK      = map { @$_ } values %EXPORT_TAGS;
 356 $EXPORT_TAGS{'all'} = [ @EXPORT_OK ];
 357
 358 =head1 CAVEATS
 359
 360 If you store a magic object in the private data slot, the magic won't be accessible by L</getdata> since it's not copied by assignation. The only way to address this would be to return a reference.
 361
 362 If you define a wizard with a C<free> callback and cast it on itself, this destructor won't be called because the wizard will be destroyed first.
 363
 364 =head1 DEPENDENCIES
 365
 366 L<perl> 5.7.3.
 367
 368 L<Carp> (standard since perl 5), L<XSLoader> (standard since perl 5.006).
 369
 370 Copy tests need L<Tie::Array> (standard since perl 5.005) and L<Tie::Hash> (since 5.002).
 371
 372 Some uvar tests need L<Hash::Util::FieldHash> (standard since perl 5.009004).
 373
 374 Glob tests need L<Symbol> (standard since perl 5.002).
 375
 376 Threads tests need L<threads> and L<threads::shared>.
 377
 378 =head1 SEE ALSO
 379
 380 L<perlguts> and L<perlapi> for internal information about magic.
 381
 382 L<perltie> and L<overload> for other ways of enhancing objects.
 383
 384 =head1 AUTHOR
 385
 386 Vincent Pit, C<< <perl at profvince.com> >>, L<http://www.profvince.com>.
 387
 388 You can contact me by mail or on #perl @ FreeNode (vincent or Prof_Vince).
 389
 390 =head1 BUGS
 391
 392 Please report any bugs or feature requests to C<bug-variable-magic at rt.cpan.org>, or through the web interface at L<http://rt.cpan.org/NoAuth/ReportBug.html?Queue=Variable-Magic>. I will be notified, and then you'll automatically be notified of progress on your bug as I make changes.
 393
 394 =head1 SUPPORT
 395
 396 You can find documentation for this module with the perldoc command.
 397
 398     perldoc Variable::Magic
 399
 400 Tests code coverage report is available at L<http://www.profvince.com/perl/cover/Variable-Magic>.
 401
 402 =head1 COPYRIGHT & LICENSE
 403
 404 Copyright 2007-2008 Vincent Pit, all rights reserved.
 405
 406 This program is free software; you can redistribute it and/or modify it
 407 under the same terms as Perl itself.
 408
 409 =cut
 410
 411 1; # End of Variable::Magic