lib/Variable/Magic.pm

   1 package Variable::Magic;
   2
   3 use 5.007003;
   4
   5 use strict;
   6 use warnings;
   7
   8 use Carp qw/croak/;
   9
  10 =head1 NAME
  11
  12 Variable::Magic - Associate user-defined magic to variables from Perl.
  13
  14 =head1 VERSION
  15
  16 Version 0.09
  17
  18 =cut
  19
  20 our $VERSION;
  21 BEGIN {
  22  $VERSION = '0.09';
  23 }
  24
  25 =head1 SYNOPSIS
  26
  27     use Variable::Magic qw/wizard cast dispell/;
  28
  29     my $wiz = wizard set => sub { print STDERR "now set to ${$_[0]}!\n" };
  30     my $a = 1;
  31     cast $a, $wiz;
  32     $a = 2;          # "now set to 2!"
  33     dispell $a, $wiz;
  34     $a = 3           # (nothing)
  35
  36 =head1 DESCRIPTION
  37
  38 Magic is Perl way of enhancing objects. This mechanism let the user add extra data to any variable and overload syntaxical operations (such as access, assignation or destruction) that can be applied to it. With this module, you can add your own magic to any variable without the pain of the C API.
  39
  40 The operations that can be overloaded are :
  41
  42 =over 4
  43
  44 =item C<get>
  45
  46 This magic is invoked when the variable is evaluated (does not include array/hash subscripts and slices).
  47
  48 =item C<set>
  49
  50 This one is triggered each time the value of the variable changes (includes array/hash subscripts and slices).
  51
  52 =item C<len>
  53
  54 This magic is a little special : it is called when the 'size' or the 'length' of the variable has to be known by Perl. Typically, it's the magic involved when an array is evaluated in scalar context, but also on array assignation and loops (C<for>, C<map> or C<grep>). The callback has then to return the length as an integer.
  55
  56 =item C<clear>
  57
  58 This magic is invoked when the variable is reset, such as when an array is emptied. Please note that this is different from undefining the variable, even though the magic is called when the clearing is a result of the undefine (e.g. for an array, but actually a bug prevent it to work before perl 5.9.5 - see the L<history|/PERL MAGIC HISTORY>).
  59
  60 =item C<free>
  61
  62 This one can be considered as an object destructor. It happens when the variable goes out of scope (with the exception of global scope), but not when it is undefined.
  63
  64 =item C<copy>
  65
  66 This magic only applies to tied arrays and hashes. It fires when you try to access or change their elements. It is available on your perl iff C<MGf_COPY> is true.
  67
  68 =item C<dup>
  69
  70 Invoked when the variable is cloned across threads. Currently not available.
  71
  72 =item C<local>
  73
  74 When this magic is set on a variable, all subsequent localizations of the variable will trigger the callback. It is available on your perl iff C<MGf_LOCAL> is true.
  75
  76 =back
  77
  78 The following actions only apply to hashes and are available iff C<VMG_UVAR> is true. They are referred to as C<uvar> magics.
  79
  80 =over 4
  81
  82 =item C<fetch>
  83
  84 This magic happens each time an element is fetched from the hash.
  85
  86 =item C<store>
  87
  88 This one is called when an element is stored into the hash.
  89
  90 =item C<exists>
  91
  92 This magic fires when a key is tested for existence in the hash.
  93
  94 =item C<delete>
  95
  96 This last one triggers when a key is deleted in the hash, regardless of whether the key actually exists in it.
  97
  98 =back
  99
 100 You can refer to the tests to have more insight of where the different magics are invoked.
 101
 102 To prevent any clash between different magics defined with this module, an unique numerical signature is attached to each kind of magic (i.e. each set of callbacks for magic operations).
 103
 104 =head1 PERL MAGIC HISTORY
 105
 106 The places where magic is invoked have changed a bit through perl history. Here's a little list of the most recent ones.
 107
 108 =head2 B<5.6.x>
 109
 110 =over 4
 111
 112 =item I<p14416> : 'copy' and 'dup' magic.
 113
 114 =back
 115
 116 =head2 B<5.9.3>
 117
 118 =over 4
 119
 120 =item 'len' magic is no longer called when pushing an element into a magic array.
 121
 122 =item I<p26569> : 'local' magic.
 123
 124 =back
 125
 126 =head2 B<5.9.5>
 127
 128 =over 4
 129
 130 =item I<p31064> : Meaningful 'uvar' magic.
 131
 132 =item I<p31473> : 'clear' magic wasn't invoked when undefining an array. The bug is fixed as of this version.
 133
 134 =back
 135
 136 =head1 CONSTANTS
 137
 138 =head2 C<SIG_MIN>
 139
 140 The minimum integer used as a signature for user-defined magic.
 141
 142 =head2 C<SIG_MAX>
 143
 144 The maximum integer used as a signature for user-defined magic.
 145
 146 =head2 C<SIG_NBR>
 147
 148     SIG_NBR = SIG_MAX - SIG_MIN + 1
 149
 150 =head2 C<MGf_COPY>
 151
 152 Evaluates to true iff the 'copy' magic is available.
 153
 154 =head2 C<MGf_DUP>
 155
 156 Evaluates to true iff the 'dup' magic is available.
 157
 158 =head2 C<MGf_LOCAL>
 159
 160 Evaluates to true iff the 'local' magic is available.
 161
 162 =head2 C<VMG_UVAR>
 163
 164 When this constant is true, you can use the C<fetch,store,exists,delete> callbacks on hashes.
 165
 166 =head1 FUNCTIONS
 167
 168 =cut
 169
 170 BEGIN {
 171  require XSLoader;
 172  XSLoader::load(__PACKAGE__, $VERSION);
 173 }
 174
 175 =head2 C<wizard>
 176
 177     wizard sig    => ...,
 178            data   => sub { ... },
 179            get    => sub { my ($ref, $data) = @_; ... },
 180            set    => sub { my ($ref, $data) = @_; ... },
 181            len    => sub { my ($ref, $data, $len) = @_; ... ; return $newlen; },
 182            clear  => sub { my ($ref, $data) = @_; ... },
 183            free   => sub { my ($ref, $data) = @_, ... },
 184            copy   => sub { my ($ref, $data, $elt) = @_; ... },
 185            local  => sub { my ($ref, $data) = @_; ... },
 186            fetch  => sub { my ($ref, $data, $key) = @_; ... },
 187            store  => sub { my ($ref, $data, $key) = @_; ... },
 188            exists => sub { my ($ref, $data, $key) = @_; ... },
 189            delete => sub { my ($ref, $data, $key) = @_; ... }
 190
 191 This function creates a 'wizard', an opaque type that holds the magic information. It takes a list of keys / values as argument, whose keys can be :
 192
 193 =over 4
 194
 195 =item C<sig>
 196
 197 The numerical signature. If not specified or undefined, a random signature is generated. If the signature matches an already defined magic, then the existant magic object is returned.
 198
 199 =item C<data>
 200
 201 A code reference to a private data constructor. It is called each time this magic is cast on a variable, and the scalar returned is used as private data storage for it. C<$_[0]> is a reference to the magic object and C<@_[1 .. @_-1]> are all extra arguments that were passed to L</cast>.
 202
 203 =item C<get>, C<set>, C<len>, C<clear>, C<free>, C<copy>, C<local>, C<fetch>, C<store>, C<exists> and C<delete>
 204
 205 Code references to corresponding magic callbacks. You don't have to specify all of them : the magic associated with undefined entries simply won't be hooked. In those callbacks, C<$_[0]> is always a reference to the magic object and C<$_[1]> is always the private data (or C<undef> when no private data constructor was supplied). In the special case of C<len> magic and when the variable is an array, C<$_[2]> contains its normal length. C<copy> magic receives the current element (i.e. the value) in C<$_[2]>. C<$_[2]> is also the current key in C<fetch>, C<store>, C<exists> and C<delete> callbacks.
 206
 207 =back
 208
 209     # A simple scalar tracer
 210     my $wiz = wizard get  => sub { print STDERR "got ${$_[0]}\n" },
 211                      set  => sub { print STDERR "set to ${$_[0]}\n" },
 212                      free => sub { print STDERR "${$_[0]} was deleted\n" }
 213
 214 =cut
 215
 216 sub wizard {
 217  croak 'Wrong number of arguments for wizard()' if @_ % 2;
 218  my %opts = @_;
 219  my @cbs  = qw/sig data get set len clear free/;
 220  push @cbs, 'copy'  if MGf_COPY;
 221  push @cbs, 'dup'   if MGf_DUP;
 222  push @cbs, 'local' if MGf_LOCAL;
 223  push @cbs, qw/fetch store exists delete/ if VMG_UVAR;
 224  return _wizard(map $opts{$_}, @cbs);
 225 }
 226
 227 =head2 C<gensig>
 228
 229 With this tool, you can manually generate random magic signature between SIG_MIN and SIG_MAX inclusive. That's the way L</wizard> creates them when no signature is supplied.
 230
 231     # Generate a signature
 232     my $sig = gensig;
 233
 234 =head2 C<getsig>
 235
 236     getsig $wiz
 237
 238 This accessor returns the magic signature of this wizard.
 239
 240     # Get $wiz signature
 241     my $sig = getsig $wiz;
 242
 243 =head2 C<cast>
 244
 245     cast [$@%&*]var, [$wiz|$sig], ...
 246
 247 This function associates C<$wiz> magic to the variable supplied, without overwriting any other kind of magic. You can also supply the numeric signature C<$sig> instead of C<$wiz>. It returns true on success or when C<$wiz> magic is already present, C<0> on error, and C<undef> when no magic corresponds to the given signature (in case C<$sig> was supplied). All extra arguments specified after C<$wiz> are passed to the private data constructor. If the variable isn't a hash, any C<uvar> callback of the wizard is safely ignored.
 248
 249     # Casts $wiz onto $x. If $wiz isn't a signature, undef can't be returned.
 250     my $x;
 251     die 'error' unless cast $x, $wiz;
 252
 253 =head2 C<getdata>
 254
 255     getdata [$@%&*]var, [$wiz|$sig]
 256
 257 This accessor fetches the private data associated with the magic C<$wiz> (or the signature C<$sig>) in the variable. C<undef> is returned when no such magic or data is found, or when C<$sig> does not represent a current valid magic object.
 258
 259     # Get the attached data.
 260     my $data = getdata $x, $wiz or die 'no such magic or magic has no data';
 261
 262 =head2 C<dispell>
 263
 264     dispell [$@%&*]variable, [$wiz|$sig]
 265
 266 The exact opposite of L</cast> : it dissociates C<$wiz> magic from the variable. You can also pass the magic signature C<$sig> as the second argument. True is returned on success, C<0> on error or when no magic represented by C<$wiz> could be found in the variable, and C<undef> when no magic corresponds to the given signature (in case C<$sig> was supplied).
 267
 268     # Dispell now. If $wiz isn't a signature, undef can't be returned.
 269     die 'no such magic or error' unless dispell $x, $wiz;
 270
 271 =head1 EXPORT
 272
 273 The functions L</wizard>, L</gensig>, L</getsig>, L</cast>, L</getdata> and L</dispell> are only exported on request. All of them are exported by the tags C<':funcs'> and C<':all'>.
 274
 275 The constants L</SIG_MIN>, L</SIG_MAX>, L</SIG_NBR>, L</MGf_COPY>, L</MGf_DUP>, L</MGf_LOCAL> and L</VMG_UVAR> are also only exported on request. They are all exported by the tags C<':consts'> and C<':all'>.
 276
 277 =cut
 278
 279 use base qw/Exporter/;
 280
 281 our @EXPORT         = ();
 282 our %EXPORT_TAGS    = (
 283  'funcs' =>  [ qw/wizard gensig getsig cast getdata dispell/ ],
 284  'consts' => [ qw/SIG_MIN SIG_MAX SIG_NBR MGf_COPY MGf_DUP MGf_LOCAL VMG_UVAR/ ]
 285 );
 286 our @EXPORT_OK      = map { @$_ } values %EXPORT_TAGS;
 287 $EXPORT_TAGS{'all'} = [ @EXPORT_OK ];
 288
 289 =head1 CAVEATS
 290
 291 If you store a magic object in the private data slot, the magic won't be accessible by L</getdata> since it's not copied by assignation. The only way to address this would be to return a reference.
 292
 293 If you define a wizard with a C<free> callback and cast it on itself, this destructor won't be called because the wizard will be destroyed first.
 294
 295 =head1 DEPENDENCIES
 296
 297 L<perl> 5.7.3.
 298
 299 L<Carp> (standard since perl 5), L<XSLoader> (standard since perl 5.006).
 300
 301 Copy tests need L<Tie::Array> (standard since perl 5.005) and L<Tie::Hash> (since 5.002).
 302
 303 Some uvar tests need L<Hash::Util::FieldHash> (standard since perl 5.009004).
 304
 305 Glob tests need L<Symbol> (standard since perl 5.002).
 306
 307 =head1 SEE ALSO
 308
 309 L<perlguts> and L<perlapi> for internal information about magic.
 310
 311 L<perltie> and L<overload> for other ways of enhancing objects.
 312
 313 =head1 AUTHOR
 314
 315 Vincent Pit, C<< <perl at profvince.com> >>
 316
 317 You can contact me by mail or on #perl @ FreeNode (Prof_Vince).
 318
 319 =head1 BUGS
 320
 321 Please report any bugs or feature requests to
 322 C<bug-variable-magic at rt.cpan.org>, or through the web interface at
 323 L<http://rt.cpan.org/NoAuth/ReportBug.html?Queue=Variable-Magic>.
 324 I will be notified, and then you'll automatically be notified of progress on
 325 your bug as I make changes.
 326
 327 =head1 SUPPORT
 328
 329 You can find documentation for this module with the perldoc command.
 330
 331     perldoc Variable::Magic
 332
 333 =head1 COPYRIGHT & LICENSE
 334
 335 Copyright 2007-2008 Vincent Pit, all rights reserved.
 336
 337 This program is free software; you can redistribute it and/or modify it
 338 under the same terms as Perl itself.
 339
 340 =cut
 341
 342 1; # End of Variable::Magic