lib/Test/Valgrind/Tool.pm

   1 package Test::Valgrind::Tool;
   2
   3 use strict;
   4 use warnings;
   5
   6 =head1 NAME
   7
   8 Test::Valgrind::Tool - Base class for Test::Valgrind tools.
   9
  10 =head1 VERSION
  11
  12 Version 1.02
  13
  14 =cut
  15
  16 our $VERSION = '1.02';
  17
  18 =head1 DESCRIPTION
  19
  20 This class is the base for L<Test::Valgrind> tools.
  21
  22 They wrap around C<valgrind> tools by parsing its output and sending reports to the parent session whenever an error occurs.
  23 They are expected to function both in suppressions generation and in analysis mode.
  24
  25 =cut
  26
  27 use base qw/Test::Valgrind::Component Test::Valgrind::Carp/;
  28
  29 =head1 METHODS
  30
  31 =head2 C<requires_version>
  32
  33 The minimum C<valgrind> version needed to run this tool.
  34 Defaults to C<3.1.0>.
  35
  36 =cut
  37
  38 sub requires_version { '3.1.0' }
  39
  40 =head2 C<< new tool => $tool >>
  41
  42 Creates a new tool object of type C<$tool> by requiring and redispatching the method call to the module named C<$tool> if it contains C<'::'> or to C<Test::Valgrind::Tool::$tool> otherwise.
  43 The class represented by C<$tool> must inherit this class.
  44
  45 =cut
  46
  47 sub new {
  48  my $class = shift;
  49  $class = ref($class) || $class;
  50
  51  my %args = @_;
  52
  53  if ($class eq __PACKAGE__) {
  54   my $tool = delete $args{tool} || 'memcheck';
  55   $tool =~ s/[^\w:]//g;
  56   $tool = __PACKAGE__ . "::$tool" if $tool !~ /::/;
  57   $class->_croak("Couldn't load tool $tool: $@") unless eval "require $tool; 1";
  58   return $tool->new(%args);
  59  }
  60
  61  $class->SUPER::new(@_);
  62 }
  63
  64 =head2 C<new_trainer>
  65
  66 Creates a new tool object suitable for generating suppressions.
  67
  68 Defaults to return C<undef>, which skips suppression generation.
  69
  70 =cut
  71
  72 sub new_trainer { }
  73
  74 =head2 C<report_class $session>
  75
  76 Returns the class in which suppression reports generated by this tool will be blessed.
  77
  78 This method must be implemented when subclassing.
  79
  80 =cut
  81
  82 sub report_class;
  83
  84 =head2 C<args $session>
  85
  86 Returns the list of tool-specific arguments that are to be passed to C<valgrind>.
  87 All the suppression arguments are already handled by the session.
  88
  89 Defaults to the empty list.
  90
  91 =cut
  92
  93 sub args { }
  94
  95 =head2 C<suppressions_tag $session>
  96
  97 Returns a identifier that will be used to pick up the right suppressions for running the tool, or C<undef> to indicate that no special suppressions are needed.
  98
  99 This method must be implemented when subclassing.
 100
 101 =cut
 102
 103 sub suppressions_tag;
 104
 105 =head2 C<start $session>
 106
 107 Called when the C<$session> starts.
 108
 109 Defaults to set L<Test::Valgrind::Component/started>.
 110
 111 =head2 C<parse $session, $fh>
 112
 113 Wraps around either L</parse_suppressions> or L</parse_analysis> depending on the running mode of the C<$session>.
 114 Croaks if the tool isn't started.
 115
 116 =cut
 117
 118 sub parse {
 119  my ($self, $sess, $fh) = @_;
 120
 121  $self->_croak('Tool isn\'t started') unless $self->started;
 122
 123  if ($sess->do_suppressions) {
 124   $self->parse_suppressions($sess, $fh);
 125  } else {
 126   $self->parse_analysis($sess, $fh);
 127  }
 128 }
 129
 130 =head2 C<parse_suppressions $sesssion, $fh>
 131
 132 Parse the suppression reports that the C<valgrind> process attached to the session C<$session> send through the filehandle C<$fh>.
 133
 134 This method must be implemented when subclassing.
 135
 136 =cut
 137
 138 sub parse_suppressions;
 139
 140 =head2 C<parse_analysis $sesssion, $fh>
 141
 142 Parse the error reports sent by the C<valgrind> process attached to the session C<$session> through the filehandle C<$fh>.
 143
 144 This method must be implemented when subclassing.
 145
 146 =cut
 147
 148 sub parse_analysis;
 149
 150 =head2 C<finish $session>
 151
 152 Called when the C<$session> finishes.
 153
 154 Defaults to clear L<Test::Valgrind::Component/started>.
 155
 156 =head1 SEE ALSO
 157
 158 L<Test::Valgrind>, L<Test::Valgrind::Component>, L<Test::Valgrind::Session>.
 159
 160 =head1 AUTHOR
 161
 162 Vincent Pit, C<< <perl at profvince.com> >>, L<http://www.profvince.com>.
 163
 164 You can contact me by mail or on C<irc.perl.org> (vincent).
 165
 166 =head1 BUGS
 167
 168 Please report any bugs or feature requests to C<bug-test-valgrind at rt.cpan.org>, or through the web interface at L<http://rt.cpan.org/NoAuth/ReportBug.html?Queue=Test-Valgrind>.
 169 I will be notified, and then you'll automatically be notified of progress on your bug as I make changes.
 170
 171 =head1 SUPPORT
 172
 173 You can find documentation for this module with the perldoc command.
 174
 175     perldoc Test::Valgrind::Tool
 176
 177 =head1 COPYRIGHT & LICENSE
 178
 179 Copyright 2009 Vincent Pit, all rights reserved.
 180
 181 This program is free software; you can redistribute it and/or modify it under the same terms as Perl itself.
 182
 183 =cut
 184
 185 1; # End of Test::Valgrind::Tool