lib/Test/Valgrind/Session.pm

   1 package Test::Valgrind::Session;
   2
   3 use strict;
   4 use warnings;
   5
   6 =head1 NAME
   7
   8 Test::Valgrind::Session - Test::Valgrind session object.
   9
  10 =head1 VERSION
  11
  12 Version 1.13
  13
  14 =cut
  15
  16 our $VERSION = '1.13';
  17
  18 =head1 DESCRIPTION
  19
  20 This class supervises the execution of the C<valgrind> process.
  21 It also acts as a dispatcher between the different components.
  22
  23 =cut
  24
  25 use File::Spec   ();
  26 use Scalar::Util ();
  27
  28 use Fcntl (); # F_SETFD
  29 use POSIX (); # SIGKILL
  30
  31 use version ();
  32
  33 use base qw<Test::Valgrind::Carp>;
  34
  35 =head1 METHODS
  36
  37 =head2 C<< new search_dirs => \@search_dirs, valgrind => [ $valgrind | \@valgrind ], min_version => $min_version, no_def_supp => $no_def_supp, extra_supps => \@extra_supps >>
  38
  39 The package constructor, which takes several options :
  40
  41 =over 4
  42
  43 =item *
  44
  45 All the directories from C<@search_dirs> will have F<valgrind> appended to create a list of candidates for the C<valgrind> executable.
  46
  47 Defaults to the current C<PATH> environment variable.
  48
  49 =item *
  50
  51 If a simple scalar C<$valgrind> is passed as the value to C<'valgrind'>, it will be the only candidate.
  52 C<@search_dirs> will then be ignored.
  53
  54 If an array refernce C<\@valgrind> is passed, its values will be I<prepended> to the list of the candidates resulting from C<@search_dirs>.
  55
  56 =item *
  57
  58 C<$min_version> specifies the minimal C<valgrind> version required.
  59 The constructor will croak if it's not able to find an adequate C<valgrind> from the supplied candidates list and search path.
  60
  61 Defaults to none.
  62
  63 =item *
  64
  65 If C<$no_def_supp> is false, C<valgrind> won't read the default suppression file associated with the tool and the command.
  66
  67 Defaults to false.
  68
  69 =item *
  70
  71 C<$extra_supps> is a reference to an array of optional suppression files that will be passed to C<valgrind>.
  72
  73 Defaults to none.
  74
  75 =back
  76
  77 =cut
  78
  79 sub new {
  80  my $class = shift;
  81  $class = ref($class) || $class;
  82
  83  my %args = @_;
  84
  85  my @paths;
  86  my $vg = delete $args{valgrind};
  87  if (defined $vg and not ref $vg) {
  88   @paths = ($vg);
  89  } else {
  90   push @paths, @$vg if $vg and ref $vg eq 'ARRAY';
  91   my $dirs = delete $args{search_dirs};
  92   $dirs = [ File::Spec->path ] unless $dirs;
  93   push @paths, map File::Spec->catfile($_, 'valgrind'), @$dirs
  94                                                         if ref $dirs eq 'ARRAY';
  95  }
  96  $class->_croak('Empty valgrind candidates list') unless @paths;
  97
  98  my $min_version = delete $args{min_version};
  99  defined and not ref and $_ = version->new($_) for $min_version;
 100
 101  my ($valgrind, $version);
 102  for (@paths) {
 103   next unless -x;
 104   my $ver = qx/$_ --version/;
 105   if ($ver =~ /^valgrind-(\d+(\.\d+)*)/) {
 106    if ($min_version) {
 107     $version = version->new($1);
 108     next if $version < $min_version;
 109    } else {
 110     $version = $1;
 111    }
 112    $valgrind = $_;
 113    last;
 114   }
 115  }
 116  $class->_croak('No appropriate valgrind executable could be found')
 117                                                        unless defined $valgrind;
 118
 119  my $extra_supps = delete $args{extra_supps};
 120  $extra_supps    = [ ] unless $extra_supps and ref $extra_supps eq 'ARRAY';
 121  @$extra_supps   = grep { defined && -f $_ && -r _ } @$extra_supps;
 122
 123  bless {
 124   valgrind    => $valgrind,
 125   version     => $version,
 126   no_def_supp => delete($args{no_def_supp}),
 127   extra_supps => $extra_supps,
 128  }, $class;
 129 }
 130
 131 =head2 C<valgrind>
 132
 133 The path to the selected C<valgrind> executable.
 134
 135 =head2 C<version>
 136
 137 The L<version> object associated to the selected C<valgrind>.
 138
 139 =cut
 140
 141 sub version {
 142  my ($self) = @_;
 143
 144  my $version = $self->{version};
 145  $self->{version} = $version = version->new($version) unless ref $version;
 146
 147  return $version;
 148 }
 149
 150 =head2 C<no_def_supp>
 151
 152 Read-only accessor for the C<no_def_supp> option.
 153
 154 =cut
 155
 156 eval "sub $_ { \$_[0]->{$_} }" for qw<valgrind no_def_supp>;
 157
 158 =head2 C<extra_supps>
 159
 160 Read-only accessor for the C<extra_supps> option.
 161
 162 =cut
 163
 164 sub extra_supps { @{$_[0]->{extra_supps} || []} }
 165
 166 =head2 C<< run action => $action, tool => $tool, command => $command >>
 167
 168 Runs the command C<$command> through C<valgrind> with the tool C<$tool>, which will report to the action C<$action>.
 169
 170 If the command is a L<Test::Valgrind::Command::Aggregate> object, the action and the tool will be initialized once before running all the aggregated commands.
 171
 172 =cut
 173
 174 sub run {
 175  my $self = shift;
 176
 177  my %args = @_;
 178
 179  $self->start(%args);
 180  my $guard = Test::Valgrind::Session::Guard->new(sub { $self->finish });
 181
 182  $self->_run($args{command});
 183 }
 184
 185 sub _run {
 186  my ($self, $cmd) = @_;
 187
 188  if ($cmd->isa('Test::Valgrind::Command::Aggregate')) {
 189   $self->_run($_) for $cmd->commands;
 190   return;
 191  }
 192
 193  $self->command($cmd);
 194
 195  $self->report($self->report_class->new_diag(
 196   'Using valgrind ' . $self->version . ' located at ' . $self->valgrind
 197  ));
 198
 199  my $env = $self->command->env($self);
 200
 201  my @supp_args;
 202  if ($self->do_suppressions) {
 203   push @supp_args, '--gen-suppressions=all';
 204  } elsif (not $self->no_def_supp) {
 205   my $def_supp = $self->def_supp_file;
 206   if (defined $def_supp and not -e $def_supp) {
 207    $self->report($self->report_class->new_diag(
 208     "Generating suppressions..."
 209    ));
 210    require Test::Valgrind::Suppressions;
 211    Test::Valgrind::Suppressions->generate(
 212     tool    => $self->tool,
 213     command => $self->command,
 214     target  => $def_supp,
 215    );
 216    $self->_croak('Couldn\'t generate suppressions') unless -e $def_supp;
 217    $self->report($self->report_class->new_diag(
 218     "Suppressions for this perl stored in $def_supp"
 219    ));
 220   }
 221   for ($self->suppressions) {
 222    next unless -e $_;
 223    $self->report($self->report_class->new_diag("Using suppression file $_"));
 224    push @supp_args, "--suppressions=$_";
 225   }
 226  }
 227
 228  pipe my $vrdr, my $vwtr or $self->_croak("pipe(\$vrdr, \$vwtr): $!");
 229  {
 230   my $oldfh = select $vrdr;
 231   $|++;
 232   select $oldfh;
 233  }
 234
 235  my $pid = fork;
 236  $self->_croak("fork(): $!") unless defined $pid;
 237
 238  if ($pid == 0) {
 239   eval 'setpgrp 0, 0';
 240   close $vrdr or $self->_croak("close(\$vrdr): $!");
 241   fcntl $vwtr, Fcntl::F_SETFD(), 0
 242                               or $self->_croak("fcntl(\$vwtr, F_SETFD, 0): $!");
 243
 244   my @args = (
 245    $self->valgrind,
 246    $self->tool->args($self),
 247    @supp_args,
 248    $self->parser->args($self, $vwtr),
 249    $self->command->args($self),
 250   );
 251
 252 #  $self->report($self->report_class->new_diag("@args"));
 253
 254   exec { $args[0] } @args or $self->_croak("exec @args: $!");
 255  }
 256
 257  local $SIG{INT} = sub {
 258   kill -(POSIX::SIGKILL()) => $pid;
 259   waitpid $pid, 0;
 260   die 'interrupted';
 261  };
 262
 263  close $vwtr or $self->_croak("close(\$vwtr): $!");
 264
 265  $self->parser->parse($self, $vrdr);
 266
 267  $self->{exit_code} = (waitpid($pid, 0) == $pid) ? $? >> 8 : 255;
 268
 269  close $vrdr or $self->_croak("close(\$vrdr): $!");
 270
 271  return;
 272 }
 273
 274 sub Test::Valgrind::Session::Guard::new     { bless \($_[1]), $_[0] }
 275
 276 sub Test::Valgrind::Session::Guard::DESTROY { ${$_[0]}->() }
 277
 278 =head2 C<action>
 279
 280 Read-only accessor for the C<action> associated to the current run.
 281
 282 =head2 C<tool>
 283
 284 Read-only accessor for the C<tool> associated to the current run.
 285
 286 =head2 C<parser>
 287
 288 Read-only accessor for the C<parser> associated to the current tool.
 289
 290 =head2 C<command>
 291
 292 Read-only accessor for the C<command> associated to the current run.
 293
 294 =cut
 295
 296 my @members;
 297 BEGIN {
 298  @members = qw<action tool command parser>;
 299  for (@members) {
 300   eval "sub $_ { \@_ <= 1 ? \$_[0]->{$_} : (\$_[0]->{$_} = \$_[1]) }";
 301   die if $@;
 302  }
 303 }
 304
 305 =head2 C<do_suppressions>
 306
 307 Forwards to C<< ->action->do_suppressions >>.
 308
 309 =cut
 310
 311 sub do_suppressions { $_[0]->action->do_suppressions }
 312
 313 =head2 C<parser_class>
 314
 315 Calls C<< ->tool->parser_class >> with the current session object as the unique argument.
 316
 317 =cut
 318
 319 sub parser_class { $_[0]->tool->parser_class($_[0]) }
 320
 321 =head2 C<report_class>
 322
 323 Calls C<< ->tool->report_class >> with the current session object as the unique argument.
 324
 325 =cut
 326
 327 sub report_class { $_[0]->tool->report_class($_[0]) }
 328
 329 =head2 C<def_supp_file>
 330
 331 Returns an absolute path to the default suppression file associated to the current session.
 332
 333 C<undef> will be returned as soon as any of C<< ->command->suppressions_tag >> or C<< ->tool->suppressions_tag >> are also C<undef>.
 334 Otherwise, the file part of the name is builded by joining those two together, and the directory part is roughly F<< File::HomeDir->my_home / .perl / Test-Valgrind / suppressions / $VERSION >>.
 335
 336 =cut
 337
 338 sub def_supp_file {
 339  my ($self) = @_;
 340
 341  my $tool_tag = $self->tool->suppressions_tag($self);
 342  return unless defined $tool_tag;
 343
 344  my $cmd_tag = $self->command->suppressions_tag($self);
 345  return unless defined $cmd_tag;
 346
 347  require File::HomeDir; # So that it's not needed at configure time.
 348
 349  return File::Spec->catfile(
 350   File::HomeDir->my_home,
 351   '.perl',
 352   'Test-Valgrind',
 353   'suppressions',
 354   $VERSION,
 355   "$tool_tag-$cmd_tag.supp",
 356  );
 357 }
 358
 359 =head2 C<suppressions>
 360
 361 Returns the list of all the suppressions that will be passed to C<valgrind>.
 362 Honors L</no_def_supp> and L</extra_supps>.
 363
 364 =cut
 365
 366 sub suppressions {
 367  my ($self) = @_;
 368
 369  my @supps;
 370  unless ($self->no_def_supp) {
 371   my $def_supp = $self->def_supp_file;
 372   push @supps, $def_supp if defined $def_supp;
 373  }
 374  push @supps, $self->extra_supps;
 375
 376  return @supps;
 377 }
 378
 379 =head2 C<start>
 380
 381 Starts the action and tool associated to the current run.
 382 It's automatically called at the beginning of L</run>.
 383
 384 =cut
 385
 386 sub start {
 387  my $self = shift;
 388
 389  my %args = @_;
 390
 391  for (qw<action tool command>) {
 392   my $base = 'Test::Valgrind::' . ucfirst;
 393   my $value = $args{$_};
 394   $self->_croak("Invalid $_") unless Scalar::Util::blessed($value)
 395                                                          and $value->isa($base);
 396   $self->$_($args{$_})
 397  }
 398
 399  delete @{$self}{qw<last_status exit_code>};
 400
 401  $self->tool->start($self);
 402  $self->parser($self->parser_class->new)->start($self);
 403  $self->action->start($self);
 404
 405  return;
 406 }
 407
 408 =head2 C<abort $msg>
 409
 410 Forwards to C<< ->action->abort >> after unshifting the session object to the argument list.
 411
 412 =cut
 413
 414 sub abort {
 415  my $self = shift;
 416
 417  $self->action->abort($self, @_);
 418 }
 419
 420 =head2 C<report $report>
 421
 422 Forwards to C<< ->action->report >> after unshifting the session object to the argument list.
 423
 424 =cut
 425
 426 sub report {
 427  my ($self, $report) = @_;
 428
 429  return unless defined $report;
 430
 431  for my $handler (qw<tool command>) {
 432   $report = $self->$handler->filter($self, $report);
 433   return unless defined $report;
 434  }
 435
 436  $self->action->report($self, $report);
 437 }
 438
 439 =head2 C<finish>
 440
 441 Finishes the action and tool associated to the current run.
 442 It's automatically called at the end of L</run>.
 443
 444 =cut
 445
 446 sub finish {
 447  my ($self) = @_;
 448
 449  my $action = $self->action;
 450
 451  $action->finish($self);
 452  $self->parser->finish($self);
 453  $self->tool->finish($self);
 454
 455  my $status = $action->status($self);
 456  $self->{last_status} = defined $status ? $status : $self->{exit_code};
 457
 458  $self->$_(undef) for @members;
 459
 460  return;
 461 }
 462
 463 =head2 C<status>
 464
 465 Returns the status code of the last run of the session.
 466
 467 =cut
 468
 469 sub status { $_[0]->{last_status} }
 470
 471 =head1 SEE ALSO
 472
 473 L<Test::Valgrind>, L<Test::Valgrind::Action>, L<Test::Valgrind::Command>, L<Test::Valgrind::Tool>, L<Test::Valgrind::Parser>.
 474
 475 L<version>, L<File::HomeDir>.
 476
 477 =head1 AUTHOR
 478
 479 Vincent Pit, C<< <perl at profvince.com> >>, L<http://www.profvince.com>.
 480
 481 You can contact me by mail or on C<irc.perl.org> (vincent).
 482
 483 =head1 BUGS
 484
 485 Please report any bugs or feature requests to C<bug-test-valgrind at rt.cpan.org>, or through the web interface at L<http://rt.cpan.org/NoAuth/ReportBug.html?Queue=Test-Valgrind>.
 486 I will be notified, and then you'll automatically be notified of progress on your bug as I make changes.
 487
 488 =head1 SUPPORT
 489
 490 You can find documentation for this module with the perldoc command.
 491
 492     perldoc Test::Valgrind::Session
 493
 494 =head1 COPYRIGHT & LICENSE
 495
 496 Copyright 2009,2010,2011 Vincent Pit, all rights reserved.
 497
 498 This program is free software; you can redistribute it and/or modify it under the same terms as Perl itself.
 499
 500 =cut
 501
 502 1; # End of Test::Valgrind::Session