Implement and test is_deeply()

[perl/modules/Test-Leaner.git] / lib / Test / Leaner.pm

diff --git a/lib/Test/Leaner.pm b/lib/Test/Leaner.pm
index 7fe001a248b394eec4daa55d02b9fdbe95432190..d79aef2c9a527bfa3f1e5a4d429bb700b4dc2e83 100644 (file)
--- a/lib/Test/Leaner.pm
+++ b/lib/Test/Leaner.pm
@@ -37,7 +37,7 @@ Its functions behave the same as their L<Test::More> counterparts, except for th
 =item *
 
 Stringification isn't forced on the test operands.
-However, L</ok> honors C<'bool'> overloading, L</is> honors C<'eq'> overloading and L</cmp_ok> honors whichever overloading category corresponds to the specified operator.
+However, L</ok> honors C<'bool'> overloading, L</is> and L</is_deeply> honor C<'eq'> overloading (and just that one) and L</cmp_ok> honors whichever overloading category corresponds to the specified operator.
 
 =item *
 
@@ -52,11 +52,16 @@ It also tests in scalar context, so C<'..'> will be treated as the flip-flop ope
 
 C<use_ok>, C<require_ok>, C<can_ok>, C<isa_ok>, C<new_ok>, C<subtest>, C<explain>, C<TODO> blocks and C<todo_skip> are not implemented.
 
+=item *
+
+L<Test::Leaner> depends on L<Scalar::Util>, while L<Test::More> does not.
+
 =back
 
 =cut
 
-use Exporter ();
+use Exporter     ();
+use Scalar::Util ();
 
 BEGIN {
  if ($] >= 5.008 and $INC{'threads.pm'}) {
@@ -172,9 +177,10 @@ our @EXPORT = qw<
  ok
  is
  isnt
- cmp_ok
  like
  unlike
+ cmp_ok
+ is_deeply
  diag
  note
  BAIL_OUT
@@ -426,6 +432,8 @@ IS_BINOP
 
 =head2 C<like $got, $regexp_expected [, $desc ]>
 
+=cut
+
 =head2 C<unlike $got, $regexp_expected, [, $desc ]>
 
 =cut
@@ -451,6 +459,58 @@ sub cmp_ok ($$$;$) {
  goto $handler;
 }
 
+=head2 C<is_deeply $got, $expected [, $desc ]>
+
+=cut
+
+sub _deep_check {
+ my ($x, $y) = @_;
+
+ no warnings qw<numeric uninitialized>;
+
+ return 0 if defined($x) xor defined($y);
+
+ # Try object identity/eq overloading first. It also covers the case where
+ # $x and $y are both undefined.
+ # If either $x or $y is overloaded but none has eq overloading, the test will
+ # break at that point.
+ return 1 if not(ref($x) xor ref($y)) and $x eq $y;
+
+ # Test::More::is_deeply happily breaks encapsulation if the objects aren't
+ # overloaded.
+ my $ry = Scalar::Util::reftype($y);
+ return 0 if Scalar::Util::reftype($x) ne $ry;
+
+ # Shortcut if $x and $y are both not references and failed the previous
+ # $x eq $y test.
+ return 0 unless $ry;
+
+ if ($ry eq 'ARRAY') {
+  if ($#$x == $#$y) {
+   _deep_check($x->[$_], $y->[$_]) or return 0 for 0 .. $#$y;
+   return 1;
+  }
+ } elsif ($ry eq 'HASH') {
+  if (keys(%$x) == keys(%$y)) {
+   (exists $x->{$_} and _deep_check($x->{$_}, $y->{$_}))
+                                                       or return 0 for keys %$y;
+   return 1;
+  }
+ } elsif ($ry eq 'SCALAR' or $ry eq 'REF') {
+  return _deep_check($$x, $$y);
+ }
+
+ return 0;
+};
+
+sub is_deeply {
+ @_ = (
+  &_deep_check,
+  $_[2],
+ );
+ goto &ok;
+}
+
 sub _diag_fh {
  my $fh = shift;
 
@@ -588,7 +648,7 @@ In that case, it also needs a working L<threads::shared>.
 
 L<perl> 5.6.
 
-L<Exporter>, L<Test::More>
+L<Exporter>, L<Scalar::Util>, L<Test::More>.
 
 =head1 AUTHOR