lib/Test/Leaner.pm

   1 package Test::Leaner;
   2
   3 use 5.006;
   4 use strict;
   5 use warnings;
   6
   7 =head1 NAME
   8
   9 Test::Leaner - A slimmer Test::More for when you favor performance over completeness.
  10
  11 =head1 VERSION
  12
  13 Version 0.03
  14
  15 =cut
  16
  17 our $VERSION = '0.03';
  18
  19 =head1 SYNOPSIS
  20
  21     use Test::Leaner tests => 10_000;
  22     for (1 .. 10_000) {
  23      ...
  24      is $one, 1, "checking situation $_";
  25     }
  26
  27
  28 =head1 DESCRIPTION
  29
  30 When profiling some L<Test::More>-based test script that contained about 10 000 unit tests, I realized that 60% of the time was spent in L<Test::Builder> itself, even though every single test actually involved a costly C<eval STRING>.
  31
  32 This module aims to be a partial replacement to L<Test::More> in those situations where you want to run a large number of simple tests.
  33 Its functions behave the same as their L<Test::More> counterparts, except for the following differences :
  34
  35 =over 4
  36
  37 =item *
  38
  39 Stringification isn't forced on the test operands.
  40 However, L</ok> honors C<'bool'> overloading, L</is> and L</is_deeply> honor C<'eq'> overloading (and just that one), L</isnt> honors C<'ne'> overloading, and L</cmp_ok> honors whichever overloading category corresponds to the specified operator.
  41
  42 =item *
  43
  44 L</pass>, L</fail>, L</ok>, L</is>, L</isnt>, L</like>, L</unlike>, L</cmp_ok> and L</is_deeply> are all guaranteed to return the truth value of the test.
  45
  46 =item *
  47
  48 C<isn't> (the sub C<t> in package C<isn>) is not aliased to L</isnt>.
  49
  50 =item *
  51
  52 L</like> and L</unlike> don't special case regular expressions that are passed as C<'/.../'> strings.
  53 A string regexp argument is always treated as the source of the regexp, making C<like $text, $rx> and C<like $text, qr[$rx]> equivalent to each other and to C<cmp_ok $text, '=~', $rx> (and likewise for C<unlike>).
  54
  55 =item *
  56
  57 L</cmp_ok> throws an exception if the given operator isn't a valid Perl binary operator (except C<'='> and variants).
  58 It also tests in scalar context, so C<'..'> will be treated as the flip-flop operator and not the range operator.
  59
  60 =item *
  61
  62 L</is_deeply> doesn't guard for memory cycles.
  63 If the two first arguments present parallel memory cycles, the test may result in an infinite loop.
  64
  65 =item *
  66
  67 The tests don't output any kind of default diagnostic in case of failure ; the rationale being that if you have a large number of tests and a lot of them are failing, then you don't want to be flooded by diagnostics.
  68 Moreover, this allows a much faster variant of L</is_deeply>.
  69
  70 =item *
  71
  72 C<use_ok>, C<require_ok>, C<can_ok>, C<isa_ok>, C<new_ok>, C<subtest>, C<explain>, C<TODO> blocks and C<todo_skip> are not implemented.
  73
  74 =back
  75
  76 =cut
  77
  78 use Exporter ();
  79
  80 my $main_process;
  81
  82 BEGIN {
  83  $main_process = $$;
  84
  85  if ($] >= 5.008 and $INC{'threads.pm'}) {
  86   my $use_ithreads = do {
  87    require Config;
  88    no warnings 'once';
  89    $Config::Config{useithreads};
  90   };
  91   if ($use_ithreads) {
  92    require threads::shared;
  93    *THREADSAFE = sub () { 1 };
  94   }
  95  }
  96  unless (defined &Test::Leaner::THREADSAFE) {
  97   *THREADSAFE = sub () { 0 }
  98  }
  99 }
 100
 101 my ($TAP_STREAM, $DIAG_STREAM);
 102
 103 my ($plan, $test, $failed, $no_diag, $done_testing);
 104
 105 our @EXPORT = qw<
 106  plan
 107  skip
 108  done_testing
 109  pass
 110  fail
 111  ok
 112  is
 113  isnt
 114  like
 115  unlike
 116  cmp_ok
 117  is_deeply
 118  diag
 119  note
 120  BAIL_OUT
 121 >;
 122
 123 =head1 ENVIRONMENT
 124
 125 =head2 C<PERL_TEST_LEANER_USES_TEST_MORE>
 126
 127 If this environment variable is set, L<Test::Leaner> will replace its functions by those from L<Test::More>.
 128 Moreover, the symbols that are imported when you C<use Test::Leaner> will be those from L<Test::More>, but you can still only import the symbols originally defined in L<Test::Leaner> (hence the functions from L<Test::More> that are not implemented in L<Test::Leaner> will not be imported).
 129 If your version of L<Test::More> is too old and doesn't have some symbols (like L</note> or L</done_testing>), they will be replaced in L<Test::Leaner> by croaking stubs.
 130
 131 This may be useful if your L<Test::Leaner>-based test script fails and you want extra diagnostics.
 132
 133 =cut
 134
 135 sub _handle_import_args {
 136  my @imports;
 137
 138  my $i = 0;
 139  while ($i <= $#_) {
 140   my $item = $_[$i];
 141   my $splice;
 142   if (defined $item) {
 143    if ($item eq 'import') {
 144     push @imports, @{ $_[$i+1] };
 145     $splice  = 2;
 146    } elsif ($item eq 'no_diag') {
 147     lock $plan if THREADSAFE;
 148     $no_diag = 1;
 149     $splice  = 1;
 150    }
 151   }
 152   if ($splice) {
 153    splice @_, $i, $splice;
 154   } else {
 155    ++$i;
 156   }
 157  }
 158
 159  return @imports;
 160 }
 161
 162 if ($ENV{PERL_TEST_LEANER_USES_TEST_MORE}) {
 163  require Test::More;
 164
 165  my $leaner_stash = \%Test::Leaner::;
 166  my $more_stash   = \%Test::More::;
 167
 168  my %stubbed;
 169
 170  for (@EXPORT) {
 171   my $replacement = exists $more_stash->{$_} ? *{$more_stash->{$_}}{CODE}
 172                                              : undef;
 173   unless (defined $replacement) {
 174    $stubbed{$_}++;
 175    $replacement = sub {
 176     @_ = ("$_ is not implemented in this version of Test::More");
 177     goto &croak;
 178    };
 179   }
 180   no warnings 'redefine';
 181   $leaner_stash->{$_} = $replacement;
 182  }
 183
 184  my $import = sub {
 185   my $class = shift;
 186
 187   my @imports = &_handle_import_args;
 188   if (@imports == grep /^!/, @imports) {
 189    # All imports are negated, or @imports is empty
 190    my %negated;
 191    /^!(.*)/ and ++$negated{$1} for @imports;
 192    push @imports, grep !$negated{$_}, @EXPORT;
 193   }
 194
 195   my @test_more_imports;
 196   for (@imports) {
 197    if ($stubbed{$_}) {
 198     my $pkg = caller;
 199     no strict 'refs';
 200     *{$pkg."::$_"} = $leaner_stash->{$_};
 201    } elsif (/^!/ or !exists $more_stash->{$_} or exists $leaner_stash->{$_}) {
 202     push @test_more_imports, $_;
 203    } else {
 204     # Croak for symbols in Test::More but not in Test::Leaner
 205     Exporter::import($class, $_);
 206    }
 207   }
 208
 209   my $test_more_import = 'Test::More'->can('import');
 210   return unless $test_more_import;
 211
 212   @_ = (
 213    'Test::More',
 214    @_,
 215    import => \@test_more_imports,
 216   );
 217   {
 218    lock $plan if THREADSAFE;
 219    push @_, 'no_diag' if $no_diag;
 220   }
 221
 222   goto $test_more_import;
 223  };
 224
 225  no warnings 'redefine';
 226  *import = $import;
 227
 228  return 1;
 229 }
 230
 231 sub NO_PLAN  () { -1 }
 232 sub SKIP_ALL () { -2 }
 233
 234 BEGIN {
 235  if (THREADSAFE) {
 236   threads::shared::share($_) for $plan, $test, $failed, $no_diag, $done_testing;
 237  }
 238
 239  lock $plan if THREADSAFE;
 240
 241  $plan   = undef;
 242  $test   = 0;
 243  $failed = 0;
 244 }
 245
 246 sub carp {
 247  my $level = 1 + ($Test::Builder::Level || 0);
 248  my @caller;
 249  do {
 250   @caller = caller $level--;
 251  } while (!@caller and $level >= 0);
 252  my ($file, $line) = @caller[1, 2];
 253  warn @_, " at $file line $line.\n";
 254 }
 255
 256 sub croak {
 257  my $level = 1 + ($Test::Builder::Level || 0);
 258  my @caller;
 259  do {
 260   @caller = caller $level--;
 261  } while (!@caller and $level >= 0);
 262  my ($file, $line) = @caller[1, 2];
 263  die @_, " at $file line $line.\n";
 264 }
 265
 266 sub _sanitize_comment {
 267  $_[0] =~ s/\n+\z//;
 268  $_[0] =~ s/#/\\#/g;
 269  $_[0] =~ s/\n/\n# /g;
 270 }
 271
 272 =head1 FUNCTIONS
 273
 274 The following functions from L<Test::More> are implemented and exported by default.
 275
 276 =head2 C<< plan [ tests => $count | 'no_plan' | skip_all => $reason ] >>
 277
 278 See L<Test::More/plan>.
 279
 280 =cut
 281
 282 sub plan {
 283  my ($key, $value) = @_;
 284
 285  return unless $key;
 286
 287  lock $plan if THREADSAFE;
 288
 289  croak("You tried to plan twice") if defined $plan;
 290
 291  my $plan_str;
 292
 293  if ($key eq 'no_plan') {
 294   croak("no_plan takes no arguments") if $value;
 295   $plan       = NO_PLAN;
 296  } elsif ($key eq 'tests') {
 297   croak("Got an undefined number of tests") unless defined $value;
 298   croak("You said to run 0 tests")          unless $value;
 299   croak("Number of tests must be a positive integer.  You gave it '$value'")
 300                                             unless $value =~ /^\+?[0-9]+$/;
 301   $plan       = $value;
 302   $plan_str   = "1..$value";
 303  } elsif ($key eq 'skip_all') {
 304   $plan       = SKIP_ALL;
 305   $plan_str   = '1..0 # SKIP';
 306   if (defined $value) {
 307    _sanitize_comment($value);
 308    $plan_str .= " $value" if length $value;
 309   }
 310  } else {
 311   my @args = grep defined, $key, $value;
 312   croak("plan() doesn't understand @args");
 313  }
 314
 315  if (defined $plan_str) {
 316   local $\;
 317   print $TAP_STREAM "$plan_str\n";
 318  }
 319
 320  exit 0 if $plan == SKIP_ALL;
 321
 322  return 1;
 323 }
 324
 325 sub import {
 326  my $class = shift;
 327
 328  my @imports = &_handle_import_args;
 329
 330  if (@_) {
 331   local $Test::Builder::Level = ($Test::Builder::Level || 0) + 1;
 332   &plan;
 333  }
 334
 335  @_ = ($class, @imports);
 336  goto &Exporter::import;
 337 }
 338
 339 =head2 C<< skip $reason => $count >>
 340
 341 See L<Test::More/skip>.
 342
 343 =cut
 344
 345 sub skip {
 346  my ($reason, $count) = @_;
 347
 348  lock $plan if THREADSAFE;
 349
 350  if (not defined $count) {
 351   carp("skip() needs to know \$how_many tests are in the block")
 352                                       unless defined $plan and $plan == NO_PLAN;
 353   $count = 1;
 354  } elsif ($count =~ /[^0-9]/) {
 355   carp('skip() was passed a non-numeric number of tests.  Did you get the arguments backwards?');
 356   $count = 1;
 357  }
 358
 359  for (1 .. $count) {
 360   ++$test;
 361
 362   my $skip_str = "ok $test # skip";
 363   if (defined $reason) {
 364    _sanitize_comment($reason);
 365    $skip_str  .= " $reason" if length $reason;
 366   }
 367
 368   local $\;
 369   print $TAP_STREAM "$skip_str\n";
 370  }
 371
 372  no warnings 'exiting';
 373  last SKIP;
 374 }
 375
 376 =head2 C<done_testing [ $count ]>
 377
 378 See L<Test::More/done_testing>.
 379
 380 =cut
 381
 382 sub done_testing {
 383  my ($count) = @_;
 384
 385  lock $plan if THREADSAFE;
 386
 387  $count = $test unless defined $count;
 388  croak("Number of tests must be a positive integer.  You gave it '$count'")
 389                                                  unless $count =~ /^\+?[0-9]+$/;
 390
 391  if (not defined $plan or $plan == NO_PLAN) {
 392   $plan         = $count; # $plan can't be NO_PLAN anymore
 393   $done_testing = 1;
 394   local $\;
 395   print $TAP_STREAM "1..$plan\n";
 396  } else {
 397   if ($done_testing) {
 398    @_ = ('done_testing() was already called');
 399    goto &fail;
 400   } elsif ($plan != $count) {
 401    @_ = ("planned to run $plan tests but done_testing() expects $count");
 402    goto &fail;
 403   }
 404  }
 405
 406  return 1;
 407 }
 408
 409 =head2 C<ok $ok [, $desc ]>
 410
 411 See L<Test::More/ok>.
 412
 413 =cut
 414
 415 sub ok ($;$) {
 416  my ($ok, $desc) = @_;
 417
 418  lock $plan if THREADSAFE;
 419
 420  ++$test;
 421
 422  my $test_str = "ok $test";
 423  $ok or do {
 424   $test_str   = "not $test_str";
 425   ++$failed;
 426  };
 427  if (defined $desc) {
 428   _sanitize_comment($desc);
 429   $test_str .= " - $desc" if length $desc;
 430  }
 431
 432  local $\;
 433  print $TAP_STREAM "$test_str\n";
 434
 435  return $ok;
 436 }
 437
 438 =head2 C<pass [ $desc ]>
 439
 440 See L<Test::More/pass>.
 441
 442 =cut
 443
 444 sub pass (;$) {
 445  unshift @_, 1;
 446  goto &ok;
 447 }
 448
 449 =head2 C<fail [ $desc ]>
 450
 451 See L<Test::More/fail>.
 452
 453 =cut
 454
 455 sub fail (;$) {
 456  unshift @_, 0;
 457  goto &ok;
 458 }
 459
 460 =head2 C<is $got, $expected [, $desc ]>
 461
 462 See L<Test::More/is>.
 463
 464 =cut
 465
 466 sub is ($$;$) {
 467  my ($got, $expected, $desc) = @_;
 468  no warnings 'uninitialized';
 469  @_ = (
 470   (not(defined $got xor defined $expected) and $got eq $expected),
 471   $desc,
 472  );
 473  goto &ok;
 474 }
 475
 476 =head2 C<isnt $got, $expected [, $desc ]>
 477
 478 See L<Test::More/isnt>.
 479
 480 =cut
 481
 482 sub isnt ($$;$) {
 483  my ($got, $expected, $desc) = @_;
 484  no warnings 'uninitialized';
 485  @_ = (
 486   ((defined $got xor defined $expected) or $got ne $expected),
 487   $desc,
 488  );
 489  goto &ok;
 490 }
 491
 492 my %binops = (
 493  'or'  => 'or',
 494  'xor' => 'xor',
 495  'and' => 'and',
 496
 497  '||'  => 'hor',
 498  ('//' => 'dor') x ($] >= 5.010),
 499  '&&'  => 'hand',
 500
 501  '|'   => 'bor',
 502  '^'   => 'bxor',
 503  '&'   => 'band',
 504
 505  'lt'  => 'lt',
 506  'le'  => 'le',
 507  'gt'  => 'gt',
 508  'ge'  => 'ge',
 509  'eq'  => 'eq',
 510  'ne'  => 'ne',
 511  'cmp' => 'cmp',
 512
 513  '<'   => 'nlt',
 514  '<='  => 'nle',
 515  '>'   => 'ngt',
 516  '>='  => 'nge',
 517  '=='  => 'neq',
 518  '!='  => 'nne',
 519  '<=>' => 'ncmp',
 520
 521  '=~'  => 'like',
 522  '!~'  => 'unlike',
 523  ('~~' => 'smartmatch') x ($] >= 5.010),
 524
 525  '+'   => 'add',
 526  '-'   => 'substract',
 527  '*'   => 'multiply',
 528  '/'   => 'divide',
 529  '%'   => 'modulo',
 530  '<<'  => 'lshift',
 531  '>>'  => 'rshift',
 532
 533  '.'   => 'concat',
 534  '..'  => 'flipflop',
 535  '...' => 'altflipflop',
 536  ','   => 'comma',
 537  '=>'  => 'fatcomma',
 538 );
 539
 540 my %binop_handlers;
 541
 542 sub _create_binop_handler {
 543  my ($op) = @_;
 544  my $name = $binops{$op};
 545  croak("Operator $op not supported") unless defined $name;
 546  {
 547   local $@;
 548   eval <<"IS_BINOP";
 549 sub is_$name (\$\$;\$) {
 550  my (\$got, \$expected, \$desc) = \@_;
 551  \@_ = (scalar(\$got $op \$expected), \$desc);
 552  goto &ok;
 553 }
 554 IS_BINOP
 555   die $@ if $@;
 556  }
 557  $binop_handlers{$op} = do {
 558   no strict 'refs';
 559   \&{__PACKAGE__."::is_$name"};
 560  }
 561 }
 562
 563 =head2 C<like $got, $regexp_expected [, $desc ]>
 564
 565 See L<Test::More/like>.
 566
 567 =head2 C<unlike $got, $regexp_expected, [, $desc ]>
 568
 569 See L<Test::More/unlike>.
 570
 571 =cut
 572
 573 {
 574  no warnings 'once';
 575  *like   = _create_binop_handler('=~');
 576  *unlike = _create_binop_handler('!~');
 577 }
 578
 579 =head2 C<cmp_ok $got, $op, $expected [, $desc ]>
 580
 581 See L<Test::More/cmp_ok>.
 582
 583 =cut
 584
 585 sub cmp_ok ($$$;$) {
 586  my ($got, $op, $expected, $desc) = @_;
 587  my $handler = $binop_handlers{$op};
 588  unless ($handler) {
 589   local $Test::More::Level = ($Test::More::Level || 0) + 1;
 590   $handler = _create_binop_handler($op);
 591  }
 592  @_ = ($got, $expected, $desc);
 593  goto $handler;
 594 }
 595
 596 =head2 C<is_deeply $got, $expected [, $desc ]>
 597
 598 See L<Test::More/is_deeply>.
 599
 600 =cut
 601
 602 BEGIN {
 603  local $@;
 604  if (eval { require Scalar::Util; 1 }) {
 605   *_reftype = \&Scalar::Util::reftype;
 606  } else {
 607   # Stolen from Scalar::Util::PP
 608   require B;
 609   my %tmap = qw<
 610    B::NULL   SCALAR
 611
 612    B::HV     HASH
 613    B::AV     ARRAY
 614    B::CV     CODE
 615    B::IO     IO
 616    B::GV     GLOB
 617    B::REGEXP REGEXP
 618   >;
 619   *_reftype = sub ($) {
 620    my $r = shift;
 621
 622    return undef unless length ref $r;
 623
 624    my $t = ref B::svref_2object($r);
 625
 626    return exists $tmap{$t} ? $tmap{$t}
 627                            : length ref $$r ? 'REF'
 628                                             : 'SCALAR'
 629   }
 630  }
 631 }
 632
 633 sub _deep_ref_check {
 634  my ($x, $y, $ry) = @_;
 635
 636  no warnings qw<numeric uninitialized>;
 637
 638  if ($ry eq 'ARRAY') {
 639   return 0 unless $#$x == $#$y;
 640
 641   my ($ex, $ey);
 642   for (0 .. $#$y) {
 643    $ex = $x->[$_];
 644    $ey = $y->[$_];
 645
 646    # Inline the beginning of _deep_check
 647    return 0 if defined $ex xor defined $ey;
 648
 649    next if not(ref $ex xor ref $ey) and $ex eq $ey;
 650
 651    $ry = _reftype($ey);
 652    return 0 if _reftype($ex) ne $ry;
 653
 654    return 0 unless $ry and _deep_ref_check($ex, $ey, $ry);
 655   }
 656
 657   return 1;
 658  } elsif ($ry eq 'HASH') {
 659   return 0 unless keys(%$x) == keys(%$y);
 660
 661   my ($ex, $ey);
 662   for (keys %$y) {
 663    return 0 unless exists $x->{$_};
 664    $ex = $x->{$_};
 665    $ey = $y->{$_};
 666
 667    # Inline the beginning of _deep_check
 668    return 0 if defined $ex xor defined $ey;
 669
 670    next if not(ref $ex xor ref $ey) and $ex eq $ey;
 671
 672    $ry = _reftype($ey);
 673    return 0 if _reftype($ex) ne $ry;
 674
 675    return 0 unless $ry and _deep_ref_check($ex, $ey, $ry);
 676   }
 677
 678   return 1;
 679  } elsif ($ry eq 'SCALAR' or $ry eq 'REF') {
 680   return _deep_check($$x, $$y);
 681  }
 682
 683  return 0;
 684 }
 685
 686 sub _deep_check {
 687  my ($x, $y) = @_;
 688
 689  no warnings qw<numeric uninitialized>;
 690
 691  return 0 if defined $x xor defined $y;
 692
 693  # Try object identity/eq overloading first. It also covers the case where
 694  # $x and $y are both undefined.
 695  # If either $x or $y is overloaded but none has eq overloading, the test will
 696  # break at that point.
 697  return 1 if not(ref $x xor ref $y) and $x eq $y;
 698
 699  # Test::More::is_deeply happily breaks encapsulation if the objects aren't
 700  # overloaded.
 701  my $ry = _reftype($y);
 702  return 0 if _reftype($x) ne $ry;
 703
 704  # Shortcut if $x and $y are both not references and failed the previous
 705  # $x eq $y test.
 706  return 0 unless $ry;
 707
 708  # We know that $x and $y are both references of type $ry, without overloading.
 709  _deep_ref_check($x, $y, $ry);
 710 }
 711
 712 sub is_deeply {
 713  @_ = (
 714   &_deep_check,
 715   $_[2],
 716  );
 717  goto &ok;
 718 }
 719
 720 sub _diag_fh {
 721  my $fh = shift;
 722
 723  return unless @_;
 724
 725  lock $plan if THREADSAFE;
 726  return if $no_diag;
 727
 728  my $msg = join '', map { defined($_) ? $_ : 'undef' } @_;
 729  _sanitize_comment($msg);
 730  return unless length $msg;
 731
 732  local $\;
 733  print $fh "# $msg\n";
 734
 735  return 0;
 736 };
 737
 738 =head2 C<diag @text>
 739
 740 See L<Test::More/diag>.
 741
 742 =cut
 743
 744 sub diag {
 745  unshift @_, $DIAG_STREAM;
 746  goto &_diag_fh;
 747 }
 748
 749 =head2 C<note @text>
 750
 751 See L<Test::More/note>.
 752
 753 =cut
 754
 755 sub note {
 756  unshift @_, $TAP_STREAM;
 757  goto &_diag_fh;
 758 }
 759
 760 =head2 C<BAIL_OUT [ $desc ]>
 761
 762 See L<Test::More/BAIL_OUT>.
 763
 764 =cut
 765
 766 sub BAIL_OUT {
 767  my ($desc) = @_;
 768
 769  lock $plan if THREADSAFE;
 770
 771  my $bail_out_str = 'Bail out!';
 772  if (defined $desc) {
 773   _sanitize_comment($desc);
 774   $bail_out_str  .= "  $desc" if length $desc; # Two spaces
 775  }
 776
 777  local $\;
 778  print $TAP_STREAM "$bail_out_str\n";
 779
 780  exit 255;
 781 }
 782
 783 END {
 784  if ($main_process == $$ and not $?) {
 785   lock $plan if THREADSAFE;
 786
 787   if (defined $plan) {
 788    if ($failed) {
 789     $? = $failed <= 254 ? $failed : 254;
 790    } elsif ($plan >= 0) {
 791     $? = $test == $plan ? 0 : 255;
 792    }
 793    if ($plan == NO_PLAN) {
 794     local $\;
 795     print $TAP_STREAM "1..$test\n";
 796    }
 797   }
 798  }
 799 }
 800
 801 =pod
 802
 803 L<Test::Leaner> also provides some functions of its own, which are never exported.
 804
 805 =head2 C<tap_stream [ $fh ]>
 806
 807 Read/write accessor for the filehandle to which the tests are outputted.
 808 On write, it also turns autoflush on onto C<$fh>.
 809
 810 Note that it can only be used as a write accessor before you start any thread, as L<threads::shared> cannot reliably share filehandles.
 811
 812 Defaults to C<STDOUT>.
 813
 814 =cut
 815
 816 sub tap_stream (;*) {
 817  if (@_) {
 818   $TAP_STREAM = $_[0];
 819
 820   my $fh = select $TAP_STREAM;
 821   $|++;
 822   select $fh;
 823  }
 824
 825  return $TAP_STREAM;
 826 }
 827
 828 tap_stream *STDOUT;
 829
 830 =head2 C<diag_stream [ $fh ]>
 831
 832 Read/write accessor for the filehandle to which the diagnostics are printed.
 833 On write, it also turns autoflush on onto C<$fh>.
 834
 835 Just like L</tap_stream>, it can only be used as a write accessor before you start any thread, as L<threads::shared> cannot reliably share filehandles.
 836
 837 Defaults to C<STDERR>.
 838
 839 =cut
 840
 841 sub diag_stream (;*) {
 842  if (@_) {
 843   $DIAG_STREAM = $_[0];
 844
 845   my $fh = select $DIAG_STREAM;
 846   $|++;
 847   select $fh;
 848  }
 849
 850  return $DIAG_STREAM;
 851 }
 852
 853 diag_stream *STDERR;
 854
 855 =head2 C<THREADSAFE>
 856
 857 This constant evaluates to true if and only if L<Test::Leaner> is thread-safe, i.e. when this version of C<perl> is at least 5.8, has been compiled with C<useithreads> defined, and L<threads> has been loaded B<before> L<Test::Leaner>.
 858 In that case, it also needs a working L<threads::shared>.
 859
 860 =head1 DEPENDENCIES
 861
 862 L<perl> 5.6.
 863
 864 L<Exporter>, L<Test::More>.
 865
 866 =head1 AUTHOR
 867
 868 Vincent Pit, C<< <perl at profvince.com> >>, L<http://www.profvince.com>.
 869
 870 You can contact me by mail or on C<irc.perl.org> (vincent).
 871
 872 =head1 BUGS
 873
 874 Please report any bugs or feature requests to C<bug-test-leaner at rt.cpan.org>, or through the web interface at L<http://rt.cpan.org/NoAuth/ReportBug.html?Queue=Test-Leaner>.
 875 I will be notified, and then you'll automatically be notified of progress on your bug as I make changes.
 876
 877 =head1 SUPPORT
 878
 879 You can find documentation for this module with the perldoc command.
 880
 881     perldoc Test::Leaner
 882
 883 =head1 COPYRIGHT & LICENSE
 884
 885 Copyright 2010,2011 Vincent Pit, all rights reserved.
 886
 887 This program is free software; you can redistribute it and/or modify it under the same terms as Perl itself.
 888
 889 =cut
 890
 891 1; # End of Test::Leaner