lib/Sub/Nary.pm

   1 package Sub::Nary;
   2
   3 use 5.008001;
   4
   5 use strict;
   6 use warnings;
   7
   8 use Carp qw/croak/;
   9 use List::Util qw/reduce/;
  10
  11 use B qw/class ppname svref_2object OPf_KIDS/;
  12
  13 use Test::More; use Data::Dumper;
  14
  15 =head1 NAME
  16
  17 Sub::Nary - Try to count how many elements a subroutine can return in list context.
  18
  19 =head1 VERSION
  20
  21 Version 0.02
  22
  23 =cut
  24
  25 our $VERSION;
  26 BEGIN {
  27  $VERSION  = '0.02';
  28 }
  29
  30 our $DEBUG = 0;
  31
  32 =head1 SYNOPSIS
  33
  34     use Sub::Nary;
  35
  36     my $sn = Sub::Nary->new();
  37     my $r  = $sn->nary(\&hlagh);
  38
  39 =head1 DESCRIPTION
  40
  41 This module uses the L<B> framework to walk into subroutines and try to guess how many scalars are likely to be returned in list context. It's not always possible to give a definitive answer to this question at compile time, so the results are given in terms of "probability of return" (to be understood in a sense described below).
  42
  43 =head1 METHODS
  44
  45 =head2 C<new>
  46
  47 The usual constructor. Currently takes no argument.
  48
  49 =head2 C<nary $coderef>
  50
  51 Takes a code reference to a named or anonymous subroutine, and returns a hash reference whose keys are the possible numbers of returning scalars, and the corresponding values the "probability" to get them. The special key C<'list'> is used to denote a possibly infinite number of returned arguments. The return value hence would look at
  52
  53     { 1 => 0.2, 2 => 0.4, 4 => 0.3, list => 0.1 }
  54
  55 that is, we should get C<1> scalar C<1> time over C<5> and so on. The sum of all values is C<1>. The returned result, and all the results obtained from intermediate subs, are cached into the object.
  56
  57 =head2 C<flush>
  58
  59 Flushes the L<Sub::Nary> object cache. Returns the object itself.
  60
  61 =head1 PROBABILITY OF RETURN
  62
  63 The probability is computed as such :
  64
  65 =over 4
  66
  67 =item * When branching, each branch is considered equally possible.
  68
  69 For example, the subroutine
  70
  71     sub simple {
  72      if (rand < 0.1) {
  73       return 1;
  74      } else {
  75       return 2, 3;
  76      }
  77     }
  78
  79 is seen returning one or two arguments each with probability C<1/2>.
  80 As for
  81
  82     sub hlagh {
  83      my $x = rand;
  84      if ($x < 0.1) {
  85       return 1, 2, 3;
  86      } elsif ($x > 0.9) {
  87       return 4, 5;
  88      }
  89     }
  90
  91 it is considered to return C<3> scalars with probability C<1/2>, C<2> with probability C<1/2 * 1/2 = 1/4> and C<1> (when the two tests fail, the last computed value is returned, which here is C<< $x > 0.9 >> evaluated in the scalar context of the test) with remaining probability C<1/4>.
  92
  93 =item * The total probability law for a given returning point is the convolution product of the probabilities of its list elements.
  94
  95 As such,
  96
  97     sub notsosimple {
  98      return 1, simple(), 2
  99     }
 100
 101 returns C<3> or C<4> arguments with probability C<1/2> ; and
 102
 103     sub double {
 104      return simple(), simple()
 105     }
 106
 107 never returns C<1> argument but returns C<2> with probability C<1/2 * 1/2 = 1/4>, C<3> with probability C<1/2 * 1/2 + 1/2 * 1/2 = 1/2> and C<4> with probability C<1/4> too.
 108
 109 =item * If a core function may return different numbers of scalars, each kind is considered equally possible.
 110
 111 For example, C<stat> returns C<13> elements on success and C<0> on error. The according probability will then be C<< { 0 => 0.5, 13 => 0.5 } >>.
 112
 113 =item * The C<list> state is absorbing in regard of all the other ones.
 114
 115 This is just a pedantic way to say that "list + fixed length = list".
 116 That's why
 117
 118     sub listy {
 119      return 1, simple(), @_
 120     }
 121
 122 is considered as always returning an unbounded list.
 123
 124 Also, the convolution law does not behave the same when C<list> elements are involved : in the following example,
 125
 126     sub oneorlist {
 127      if (rand < 0.1) {
 128       return 1
 129      } else {
 130       return @_
 131      }
 132     }
 133
 134     sub composed {
 135      return oneorlist(), oneorlist()
 136     }
 137
 138 C<composed> returns C<2> scalars with probability C<1/2 * 1/2 = 1/4> and a C<list> with probability C<3/4>.
 139
 140 =back
 141
 142 =cut
 143
 144 BEGIN {
 145  require XSLoader;
 146  XSLoader::load(__PACKAGE__, $VERSION);
 147 }
 148
 149 sub _check_self {
 150  croak 'First argument isn\'t a valid ' . __PACKAGE__ . ' object'
 151   unless ref $_[0] and $_[0]->isa(__PACKAGE__);
 152 }
 153
 154 sub new {
 155  my $class = shift;
 156  $class = ref($class) || $class || __PACKAGE__;
 157  bless { cache => { } }, $class;
 158 }
 159
 160 sub flush {
 161  my $self = shift;
 162  _check_self($self);
 163  $self->{cache} = { };
 164  $self;
 165 }
 166
 167 sub nary {
 168  my $self = shift;
 169  my $sub  = shift;
 170
 171  $self->{cv} = [ ];
 172  return ($self->enter(svref_2object($sub)))[1];
 173 }
 174
 175 sub name ($) {
 176  local $SIG{__DIE__} = \&Carp::confess;
 177  my $n = $_[0]->name;
 178  $n eq 'null' ? substr(ppname($_[0]->targ), 3) : $n
 179 }
 180
 181 sub scale {
 182  my ($c, $r) = @_;
 183  return unless defined $r;
 184  return (ref $r) ? { map { $_ => $r->{$_} * $c } keys %$r } : { $r => $c };
 185 }
 186
 187 sub power {
 188  my ($p, $n, $c) = @_;
 189  return unless defined $p;
 190  return { 0 => $c } unless $n;
 191  if ($n eq 'list') {
 192   my $z = delete $p->{0};
 193   return { 'list' => $c } unless $z;
 194   return { 0      => $c } if $z == 1;
 195   return { 0 => $c * $z, list => $c * (1 - $z) };
 196  }
 197  my $r = combine map { { %$p } } 1 .. $n;
 198  $r->{$_} *= $c for keys %$r;
 199  return $r;
 200 }
 201
 202 sub add {
 203  reduce {
 204   $a->{$_} += $b->{$_} for keys %$b;
 205   $a
 206  } map { (ref) ? $_ : { $_ => 1 } } grep defined, @_;
 207 }
 208
 209 my %ops;
 210
 211 $ops{$_} = 1      for scalops;
 212 $ops{$_} = 0      for qw/stub nextstate pushmark iter unstack/;
 213 $ops{$_} = 1      for qw/padsv/;
 214 $ops{$_} = 'list' for qw/padav/;
 215 $ops{$_} = 'list' for qw/padhv rv2hv/;
 216 $ops{$_} = 'list' for qw/padany/;
 217 $ops{$_} = 'list' for qw/match entereval readline/;
 218
 219 $ops{each}      = { 0 => 0.5, 2 => 0.5 };
 220 $ops{stat}      = { 0 => 0.5, 13 => 0.5 };
 221
 222 $ops{caller}    = sub { my @a = caller 0; scalar @a }->();
 223 $ops{localtime} = do { my @a = localtime; scalar @a };
 224 $ops{gmtime}    = do { my @a = gmtime; scalar @a };
 225
 226 $ops{$_} = { 0 => 0.5, 10 => 0.5 } for map "gpw$_", qw/nam uid ent/;
 227 $ops{$_} = { 0 => 0.5, 4 => 0.5 }  for map "ggr$_", qw/nam gid ent/;
 228 $ops{$_} = 'list'                  for qw/ghbyname ghbyaddr ghostent/;
 229 $ops{$_} = { 0 => 0.5, 4 => 0.5 }  for qw/gnbyname gnbyaddr gnetent/;
 230 $ops{$_} = { 0 => 0.5, 3 => 0.5 }  for qw/gpbyname gpbynumber gprotoent/;
 231 $ops{$_} = { 0 => 0.5, 4 => 0.5 }  for qw/gsbyname gsbyport gservent/;
 232
 233 sub enter {
 234  my ($self, $cv) = @_;
 235
 236  return undef, 'list' if class($cv) ne 'CV';
 237  my $op  = $cv->ROOT;
 238  my $tag = tag($op);
 239
 240  return undef, { %{$self->{cache}->{$tag}} } if exists $self->{cache}->{$tag};
 241
 242  # Anything can happen with recursion
 243  for (@{$self->{cv}}) {
 244   return undef, 'list' if $tag == tag($_->ROOT);
 245  }
 246
 247  unshift @{$self->{cv}}, $cv;
 248  my $r = add $self->inspect($op->first);
 249  shift @{$self->{cv}};
 250
 251  $r = { $r => 1 } unless ref $r;
 252  $self->{cache}->{$tag} = { %$r };
 253  return undef, $r;
 254 }
 255
 256 sub inspect {
 257  my ($self, $op) = @_;
 258
 259  my $n = name($op);
 260  diag "@ $n" if $DEBUG;
 261  return add($self->inspect_kids($op)), undef if $n eq 'return';
 262
 263  my $meth = $self->can('pp_' . $n);
 264  return $self->$meth($op) if $meth;
 265
 266  if (exists $ops{$n}) {
 267   my $l = $ops{$n};
 268   $l = { %$l } if ref $l;
 269   return undef, $l;
 270  }
 271
 272  if (class($op) eq 'LOGOP' and not null $op->first) {
 273   my @res;
 274
 275   diag "? logop\n" if $DEBUG;
 276
 277   my $op = $op->first;
 278   my ($r1, $l1) = $self->inspect($op);
 279   return $r1, $l1 if $r1 and zero $l1;
 280   my $c = count $l1;
 281
 282   $op = $op->sibling;
 283   my ($r2, $l2) = $self->inspect($op);
 284
 285   $op = $op->sibling;
 286   my ($r3, $l3);
 287   if (null $op) {
 288    # If the logop has no else branch, it can also return the *scalar* result of
 289    # the conditional
 290    $l3 = { 1 => $c };
 291   } else {
 292    ($r3, $l3) = $self->inspect($op);
 293   }
 294
 295   my $r = add $r1, scale $c / 2, add $r2, $r3;
 296   my $l = scale $c / 2, add $l2, $l3;
 297   return $r, $l
 298  }
 299
 300  return $self->inspect_kids($op);
 301 }
 302
 303 sub inspect_kids {
 304  my ($self, $op) = @_;
 305
 306  return undef, 0 unless $op->flags & OPf_KIDS;
 307
 308  $op = $op->first;
 309  return undef, 0 if null $op;
 310  if (name($op) eq 'pushmark') {
 311   $op = $op->sibling;
 312   return undef, 0 if null $op;
 313  }
 314
 315  my ($r, @l);
 316  my $c = 1;
 317  for (; not null $op; $op = $op->sibling) {
 318   my $n = name($op);
 319   if ($n eq 'nextstate') {
 320    @l  = ();
 321    next;
 322   }
 323   if ($n eq 'lineseq') {
 324    @l  = ();
 325    $op = $op->first;
 326    redo;
 327   }
 328   diag "> $n ($c)" if $DEBUG;
 329   my ($rc, $lc) = $self->inspect($op);
 330   $r = add $r, scale $c, $rc if defined $rc;
 331   if ($rc and not defined $lc) {
 332    @l = ();
 333    last;
 334   }
 335   push @l, scale $c, $lc;
 336   $c *= count $lc if defined $lc;
 337  }
 338
 339  my $l = combine @l;
 340
 341  return $r, $l;
 342 }
 343
 344 # Stolen from B::Deparse
 345
 346 sub padval { $_[0]->{cv}->[0]->PADLIST->ARRAYelt(1)->ARRAYelt($_[1]) }
 347
 348 sub gv_or_padgv {
 349  my ($self, $op) = @_;
 350  if (class($op) eq 'PADOP') {
 351   return $self->padval($op->padix)
 352  } else { # class($op) eq "SVOP"
 353   return $op->gv;
 354  }
 355 }
 356
 357 sub const_sv {
 358  my ($self, $op) = @_;
 359  my $sv = $op->sv;
 360  # the constant could be in the pad (under useithreads)
 361  $sv = $self->padval($op->targ) unless $$sv;
 362  return $sv;
 363 }
 364
 365 sub pp_entersub {
 366  my ($self, $op) = @_;
 367
 368  $op = $op->first while $op->flags & OPf_KIDS;
 369  return undef, 0 if null $op;
 370  if (name($op) eq 'pushmark') {
 371   $op = $op->sibling;
 372   return undef, 0 if null $op;
 373  }
 374
 375  my $r;
 376  my $c = 1;
 377  for (; not null $op->sibling; $op = $op->sibling) {
 378   my $n = name($op);
 379   next if $n eq 'nextstate';
 380   diag "* $n" if $DEBUG;
 381   my ($rc, $lc) = $self->inspect($op);
 382   $r = add $r, scale $c, $rc if defined $rc;
 383   if (zero $lc) {
 384    $c = 1 - count $r;
 385    return $r, $c ? { 0 => $c } : undef
 386   }
 387   $c *= count $lc;
 388  }
 389
 390  if (name($op) eq 'rv2cv') {
 391   my $n;
 392   do {
 393    $op = $op->first;
 394    my $next = $op->sibling;
 395    while (not null $next) {
 396     $op   = $next;
 397     $next = $next->sibling;
 398    }
 399    $n  = name($op)
 400   } while ($op->flags & OPf_KIDS and { map { $_ => 1 } qw/null leave/ }->{$n});
 401   return 'list', undef unless { map { $_ => 1 } qw/gv refgen/ }->{$n};
 402   local $self->{sub} = 1;
 403   my ($rc, $lc) = $self->inspect($op);
 404   return $r, scale $c, $lc;
 405  } else {
 406   # Method call ?
 407   return $r, { 'list' => $c };
 408  }
 409 }
 410
 411 sub pp_gv {
 412  my ($self, $op) = @_;
 413
 414  return $self->{sub} ? $self->enter($self->gv_or_padgv($op)->CV) : (undef, 1)
 415 }
 416
 417 sub pp_anoncode {
 418  my ($self, $op) = @_;
 419
 420  return $self->{sub} ? $self->enter($self->const_sv($op)) : (undef, 1)
 421 }
 422
 423 sub pp_goto {
 424  my ($self, $op) = @_;
 425
 426  my $n = name($op);
 427  while ($op->flags & OPf_KIDS) {
 428   my $nop = $op->first;
 429   my $nn  = name($nop);
 430   if ($nn eq 'pushmark') {
 431    $nop = $nop->sibling;
 432    $nn  = name($nop);
 433   }
 434   if ($n eq 'rv2cv' and $nn eq 'gv') {
 435    return $self->enter($self->gv_or_padgv($nop)->CV);
 436   }
 437   $op = $nop;
 438   $n  = $nn;
 439  }
 440
 441  return undef, 'list';
 442 }
 443
 444 sub pp_const {
 445  my ($self, $op) = @_;
 446
 447  return undef, 0 unless $op->isa('B::SVOP');
 448
 449  my $sv = $self->const_sv($op);
 450  my $n  = 1;
 451  my $c  = class($sv);
 452  if ($c eq 'AV') {
 453   $n = $sv->FILL + 1
 454  } elsif ($c eq 'HV') {
 455   $n = 2 * $sv->FILL
 456  }
 457
 458  return undef, $n
 459 }
 460
 461 sub pp_aslice { $_[0]->inspect($_[1]->first->sibling) }
 462
 463 sub pp_hslice;
 464 *pp_hslice = *pp_aslice{CODE};
 465
 466 sub pp_lslice { $_[0]->inspect($_[1]->first) }
 467
 468 sub pp_rv2av {
 469  my ($self, $op) = @_;
 470  $op = $op->first;
 471
 472  my ($r, $l) = $self->inspect($op);
 473  if (name($op) ne 'const') {
 474   my $c = 1 - count $r;
 475   $l = $c ? { list => $c } : 0;
 476  }
 477  return $r, $l;
 478 }
 479
 480 sub pp_aassign {
 481  my ($self, $op) = @_;
 482
 483  $op = $op->first;
 484
 485  # Can't assign to return
 486  my $l = ($self->inspect($op->sibling))[1];
 487  return undef, $l if not exists $l->{list};
 488
 489  $self->inspect($op);
 490 }
 491
 492 sub pp_leaveloop {
 493  my ($self, $op) = @_;
 494
 495  diag "* leaveloop" if $DEBUG;
 496
 497  $op = $op->first;
 498  my ($r1, $l1);
 499  if (name($op) eq 'enteriter') {
 500   ($r1, $l1) = $self->inspect($op);
 501   return $r1, $l1 if $r1 and zero $l1;
 502  }
 503
 504  $op = $op->sibling;
 505  my $r = (name($op->first) eq 'and') ? ($self->inspect($op->first->first->sibling))[0]
 506                                      : ($self->inspect($op))[0];
 507  my $c = 1 - count $r;
 508  diag "& leaveloop" if $DEBUG;
 509  return $r, $c ? { 0 => $c } : undef;
 510 }
 511
 512 sub pp_flip {
 513  my ($self, $op) = @_;
 514
 515  $op = $op->first;
 516  return $self->inspect($op) if name($op) ne 'range';
 517
 518  my ($r, $l);
 519  my $begin = $op->first;
 520  if (name($begin) eq 'const') {
 521   my $end = $begin->sibling;
 522   if (name($end) eq 'const') {
 523    $begin = $self->const_sv($begin);
 524    $end   = $self->const_sv($end);
 525    {
 526     no warnings 'numeric';
 527     $begin = int ${$begin->object_2svref};
 528     $end   = int ${$end->object_2svref};
 529    }
 530    return undef, $end - $begin + 1;
 531   } else {
 532    ($r, $l) = $self->inspect($end);
 533   }
 534  } else {
 535   ($r, $l) = $self->inspect($begin);
 536  }
 537
 538  my $c = 1 - count $r;
 539  return $r, ($l && $c) ? { 'list' => $c } : undef
 540 }
 541
 542 sub pp_grepwhile {
 543  my ($self, $op) = @_;
 544
 545  $op = $op->first;
 546  return $self->inspect($op) if name($op) ne 'grepstart';
 547  $op = $op->first->sibling;
 548
 549  my ($r2, $l2) = $self->inspect($op->sibling);
 550  return $r2, $l2 if $r2 and zero $l2;
 551  diag Dumper [ $r2, $l2 ] if $DEBUG;
 552  my $c = count $l2; # First one to happen
 553
 554  my ($r1, $l1) = $self->inspect($op);
 555  diag Dumper [ $r1, $l1 ] if $DEBUG;
 556  return (add $r2, scale $c, $r1), undef if $r1 and zero $l1 and not zero $l2;
 557  return { 'list' => 1 }, undef if list $l2;
 558
 559  $l2 = { $l2 => 1 } unless ref $l2;
 560  my $r = add $r2, scale $c,
 561                    normalize
 562                     add map { power $r1, $_, $l2->{$_} } keys %$l2;
 563  $c = 1 - count $r;
 564  return $r, $c ? { ((zero $l2) ? 0 : 'list') => $c } : undef;
 565 }
 566
 567 sub pp_mapwhile {
 568  my ($self, $op) = @_;
 569
 570  $op = $op->first;
 571  return $self->inspect($op) if name($op) ne 'mapstart';
 572  $op = $op->first->sibling;
 573
 574  my ($r2, $l2) = $self->inspect($op->sibling);
 575  return $r2, $l2 if $r2 and zero $l2;
 576  my $c = count $l2; # First one to happen
 577
 578  my ($r1, $l1) = $self->inspect($op);
 579  return (add $r2, scale $c, $r1), undef if $r1 and zero $l1 and not zero $l2;
 580  diag Dumper [ [ $r1, $l1 ], [ $r2, $l2 ] ] if $DEBUG;
 581
 582  $l2 = { $l2 => 1 } unless ref $l2;
 583  my $r = add $r2, scale $c,
 584                    normalize
 585                     add map { power $r1, $_, $l2->{$_} } keys %$l2;
 586  $c = 1 - count $r;
 587  my $l = scale $c, normalize add map { power $l1, $_, $l2->{$_} } keys %$l2;
 588  return $r, $l;
 589 }
 590
 591 =head1 EXPORT
 592
 593 An object-oriented module shouldn't export any function, and so does this one.
 594
 595 =head1 CAVEATS
 596
 597 The algorithm may be pessimistic (things seen as C<list> while they are of fixed length) but not optimistic (the opposite, duh).
 598
 599 C<wantarray> isn't specialized when encountered in the optree.
 600
 601 =head1 DEPENDENCIES
 602
 603 L<perl> 5.8.1.
 604
 605 L<Carp> (standard since perl 5), L<B> (since perl 5.005), L<XSLoader> (since perl 5.006) and L<List::Util> (since perl 5.007003).
 606
 607 =head1 AUTHOR
 608
 609 Vincent Pit, C<< <perl at profvince.com> >>, L<http://www.profvince.com>.
 610
 611 You can contact me by mail or on #perl @ FreeNode (vincent or Prof_Vince).
 612
 613 =head1 BUGS
 614
 615 Please report any bugs or feature requests to C<bug-b-nary at rt.cpan.org>, or through the web interface at L<http://rt.cpan.org/NoAuth/ReportBug.html?Queue=Sub-Nary>.  I will be notified, and then you'll automatically be notified of progress on your bug as I make changes.
 616
 617 =head1 SUPPORT
 618
 619 You can find documentation for this module with the perldoc command.
 620
 621     perldoc Sub::Nary
 622
 623 Tests code coverage report is available at L<http://www.profvince.com/perl/cover/Sub-Nary>.
 624
 625 =head1 ACKNOWLEDGEMENTS
 626
 627 Thanks to Sebastien Aperghis-Tramoni for helping to name this module.
 628
 629 =head1 COPYRIGHT & LICENSE
 630
 631 Copyright 2008 Vincent Pit, all rights reserved.
 632
 633 This program is free software; you can redistribute it and/or modify it under the same terms as Perl itself.
 634
 635 =cut
 636
 637 1; # End of Sub::Nary