lib/Sub/Nary.pm

   1 package Sub::Nary;
   2
   3 use 5.008001;
   4
   5 use strict;
   6 use warnings;
   7
   8 use Carp qw/croak/;
   9 use List::Util qw/reduce sum/;
  10
  11 use B qw/class ppname svref_2object OPf_KIDS/;
  12
  13 =head1 NAME
  14
  15 Sub::Nary - Try to count how many elements a subroutine can return in list context.
  16
  17 =head1 VERSION
  18
  19 Version 0.01
  20
  21 =cut
  22
  23 our $VERSION;
  24 BEGIN {
  25  $VERSION  = '0.01';
  26 }
  27
  28 =head1 SYNOPSIS
  29
  30     use Sub::Nary;
  31
  32     my $sn = Sub::Nary->new();
  33     my $r  = $sn->nary(\&hlagh);
  34
  35 =head1 DESCRIPTION
  36
  37 This module uses the L<B> framework to walk into subroutines and try to guess how many scalars are likely to be returned in list context. It's not always possible to give a definitive answer to this question at compile time, so the results are given in terms of "probability of return" (to be understood in a sense described below).
  38
  39 =head1 METHODS
  40
  41 =head2 C<new>
  42
  43 The usual constructor. Currently takes no argument.
  44
  45 =head2 C<nary $coderef>
  46
  47 Takes a code reference to a named or anonymous subroutine, and returns a hash reference whose keys are the possible numbers of returning scalars, and the corresponding values the "probability" to get them. The special key C<'list'> is used to denote a possibly infinite number of returned arguments. The return value hence would look at
  48
  49     { 1 => 0.2, 2 => 0.4, 4 => 0.3, list => 0.1 }
  50
  51 that is, we should get C<1> scalar C<1> time over C<5> and so on. The sum of all values is C<1>. The returned result, and all the results obtained from intermediate subs, are cached into the object.
  52
  53 =head2 C<flush>
  54
  55 Flushes the L<Sub::Nary> object cache. Returns the object itself.
  56
  57 =head1 PROBABILITY OF RETURN
  58
  59 The probability is computed as such :
  60
  61 =over 4
  62
  63 =item * All the returning points in the same subroutine (i.e. all the explicit C<return> and the last computed value) are considered equally possible.
  64
  65 For example, the subroutine
  66
  67     sub simple {
  68      if (rand < 0.1) {
  69       return 1;
  70      } else {
  71       return 2, 3;
  72      }
  73     }
  74
  75 is seen returning one or two arguments each with probability C<1/2>.
  76 As for
  77
  78     sub hlagh {
  79      my $x = rand;
  80      if ($x < 0.1) {
  81       return 1, 2, 3;
  82      } elsif ($x > 0.9) {
  83       return 4, 5;
  84      }
  85     }
  86
  87 it is considered to return C<1> (when the two tests fail, the last computed value is returned, which here is C<< $x > 0.9 >> evaluated in the scalar context of the test), C<2> or C<3> arguments each with probability C<1/3>.
  88
  89 =item * The total probability law for a given returning point is the convolution product of the probabilities of its list elements.
  90
  91 As such,
  92
  93     sub notsosimple {
  94      return 1, simple(), 2
  95     }
  96
  97 returns C<3> or C<4> arguments with probability C<1/2> ; and
  98
  99     sub double {
 100      return simple(), simple()
 101     }
 102
 103 never returns C<1> argument but returns C<2> with probability C<1/2 * 1/2 = 1/4>, C<3> with probability C<1/2 * 1/2 + 1/2 * 1/2 = 1/2> and C<4> with probability C<1/4> too.
 104
 105 =item * The C<list> state is absorbing in regard of all the other ones.
 106
 107 This is just a pedantic way to say that "list + fixed length = list".
 108 That's why
 109
 110     sub listy {
 111      return 1, simple(), @_
 112     }
 113
 114 is considered as always returning an unbounded list.
 115
 116 Also, the convolution law does not behave the same when C<list> elements are involved : in the following example,
 117
 118     sub oneorlist {
 119      if (rand < 0.1) {
 120       return 1
 121      } else {
 122       return @_
 123      }
 124     }
 125
 126     sub composed {
 127      return oneorlist(), oneorlist()
 128     }
 129
 130 C<composed> returns C<2> scalars with probability C<1/2 * 1/2 = 1/4> and a C<list> with probability C<3/4>.
 131
 132 =back
 133
 134 =cut
 135
 136 BEGIN {
 137  require XSLoader;
 138  XSLoader::load(__PACKAGE__, $VERSION);
 139 }
 140
 141 sub _check_self {
 142  croak 'First argument isn\'t a valid ' . __PACKAGE__ . ' object'
 143   unless ref $_[0] and $_[0]->isa(__PACKAGE__);
 144 }
 145
 146 sub new {
 147  my $class = shift;
 148  $class = ref($class) || $class || __PACKAGE__;
 149  bless { cache => { } }, $class;
 150 }
 151
 152 sub flush {
 153  my $self = shift;
 154  _check_self($self);
 155  $self->{cache} = { };
 156  $self;
 157 }
 158
 159 sub nary {
 160  my $self = shift;
 161  my $sub  = shift;
 162
 163  $self->{cv} = [ ];
 164  return $self->enter(svref_2object($sub));
 165 }
 166
 167 sub name ($) {
 168  my $n = $_[0]->name;
 169  $n eq 'null' ? substr(ppname($_[0]->targ), 3) : $n
 170 }
 171
 172 sub combine {
 173  reduce {{
 174   my %res;
 175   my $la = delete $a->{list};
 176   my $lb = delete $b->{list};
 177   if (defined $la || defined $lb) {
 178    $la ||= 0;
 179    $lb ||= 0;
 180    $res{list} = $la + $lb - $la * $lb;
 181   }
 182   while (my ($ka, $va) = each %$a) {
 183    $ka = int $ka;
 184    while (my ($kb, $vb) = each %$b) {
 185     my $key = $ka + int $kb;
 186     $res{$key} += $va * $vb;
 187    }
 188   }
 189   \%res
 190  }} map { (ref) ? $_ : { $_ => 1 } } grep defined, @_;
 191 }
 192
 193 sub add {
 194  reduce {
 195   $a->{$_} += $b->{$_} for keys %$b;
 196   $a
 197  } map { (ref) ? $_ : { $_ => 1 } } grep defined, @_;
 198 }
 199
 200 my %ops;
 201 $ops{$_} = 1      for scalops;
 202 $ops{$_} = 0      for qw/stub nextstate/;
 203 $ops{$_} = 1      for qw/padsv/;
 204 $ops{$_} = 'list' for qw/padav/;
 205 $ops{$_} = 'list' for qw/padhv rv2hv/;
 206 $ops{$_} = 'list' for qw/padany flip match entereval readline/;
 207
 208 sub enter {
 209  my ($self, $cv) = @_;
 210
 211  return 'list' if class($cv) ne 'CV';
 212  my $op  = $cv->ROOT;
 213  my $tag = tag($op);
 214
 215  return { %{$self->{cache}->{$tag}} } if exists $self->{cache}->{$tag};
 216
 217  # Anything can happen with recursion
 218  for (@{$self->{cv}}) {
 219   return 'list' if $tag == tag($_->ROOT);
 220  }
 221
 222  unshift @{$self->{cv}}, $cv;
 223  (my $r, undef) = $self->expect_any($op->first);
 224  shift @{$self->{cv}};
 225
 226  $r = { $r => 1} unless ref $r;
 227  my $total = sum values %$r;
 228  $r = { map { $_ => $r->{$_} / $total } keys %$r };
 229  $self->{cache}->{$tag} = { %$r };
 230  return $r;
 231 }
 232
 233 sub expect_return {
 234  my ($self, $op) = @_;
 235
 236  return ($self->expect_list($op))[0] => 1 if name($op) eq 'return';
 237
 238  if ($op->flags & OPf_KIDS) {
 239   for ($op = $op->first; not null $op; $op = $op->sibling) {
 240    my ($p, $r) = $self->expect_return($op);
 241    return $p => 1 if $r;
 242   }
 243  }
 244
 245  return;
 246 }
 247
 248 sub expect_list {
 249  my ($self, $op) = @_;
 250
 251  my $n = name($op);
 252  my $meth = $self->can('pp_' . $n);
 253  return $self->$meth($op) if $meth;
 254  return $ops{$n} => 0 if exists $ops{$n};
 255
 256  if ($op->flags & OPf_KIDS) {
 257   my @res = (0);
 258   my ($p, $r);
 259   for ($op = $op->first; not null $op; $op = $op->sibling) {
 260    my $n = name($op);
 261    next if $n eq 'pushmark';
 262    if ($n eq 'nextstate'
 263        and not null(($op = $op->sibling)->sibling)) {
 264     ($p, $r) = $self->expect_return($op);
 265     return $p => 1 if $r;
 266    } else {
 267     ($p, $r) = $self->expect_any($op);
 268     return $p => 1 if $r;
 269     push @res, $p;
 270    }
 271   }
 272   return (combine @res) => 0;
 273  }
 274
 275  return;
 276 }
 277
 278 sub expect_any {
 279  my ($self, $op) = @_;
 280
 281  return ($self->expect_list($op))[0] => 1 if name($op) eq 'return';
 282
 283  if (class($op) eq 'LOGOP' and not null $op->first) {
 284   my @res;
 285   my ($p, $r);
 286
 287   my $op   = $op->first;
 288   ($p, $r) = $self->expect_return($op);
 289   return $p => 1 if $r;
 290
 291   $op = $op->sibling;
 292   push @res, ($self->expect_any($op))[0];
 293
 294   # If the logop has no else branch, it can also return the *scalar* result of
 295   # the conditional
 296   $op = $op->sibling;
 297   if (null $op) {
 298    push @res, 1;
 299   } else {
 300    push @res, ($self->expect_any($op))[0];
 301   }
 302
 303   return (add @res) => 0;
 304  }
 305
 306  return $self->expect_list($op);
 307 }
 308
 309 # Stolen from B::Deparse
 310
 311 sub padval { $_[0]->{cv}->[0]->PADLIST->ARRAYelt(1)->ARRAYelt($_[1]) }
 312
 313 sub gv_or_padgv {
 314  my ($self, $op) = @_;
 315  if (class($op) eq 'PADOP') {
 316   return $self->padval($op->padix)
 317  } else { # class($op) eq "SVOP"
 318   return $op->gv;
 319  }
 320 }
 321
 322 sub const_sv {
 323  my ($self, $op) = @_;
 324  my $sv = $op->sv;
 325  # the constant could be in the pad (under useithreads)
 326  $sv = $self->padval($op->targ) unless $$sv;
 327  return $sv;
 328 }
 329
 330 sub pp_entersub {
 331  my ($self, $op, $exp) = @_;
 332
 333  my $next = $op;
 334  while ($next->flags & OPf_KIDS) {
 335   $next = $next->first;
 336  }
 337  while (not null $next) {
 338   $op = $next;
 339   my ($p, $r) = $self->expect_return($op, $exp);
 340   return $p => 1 if $r;
 341   $next = $op->sibling;
 342  }
 343
 344  if (name($op) eq 'rv2cv') {
 345   my $n;
 346   do {
 347    $op = $op->first;
 348    my $next = $op->sibling;
 349    while (not null $next) {
 350     $op   = $next;
 351     $next = $next->sibling;
 352    }
 353    $n  = name($op)
 354   } while ($op->flags & OPf_KIDS and { map { $_ => 1 } qw/null leave/ }->{$n});
 355   return 'list' unless { map { $_ => 1 } qw/gv refgen/ }->{$n};
 356   local $self->{sub} = 1;
 357   return $self->expect_any($op, $exp);
 358  } else {
 359   # Method call ?
 360   return 'list';
 361  }
 362 }
 363
 364 sub pp_gv {
 365  my ($self, $op) = @_;
 366
 367  return $self->{sub} ? $self->enter($self->gv_or_padgv($op)->CV) : 1
 368 }
 369
 370 sub pp_anoncode {
 371  my ($self, $op) = @_;
 372
 373  return $self->{sub} ? $self->enter($self->const_sv($op)) : 1
 374 }
 375
 376 sub pp_goto {
 377  my ($self, $op) = @_;
 378
 379  my $n = name($op);
 380  while ($op->flags & OPf_KIDS) {
 381   my $nop = $op->first;
 382   my $nn  = name($nop);
 383   if ($nn eq 'pushmark') {
 384    $nop = $nop->sibling;
 385    $nn  = name($nop);
 386   }
 387   if ($n eq 'rv2cv' and $nn eq 'gv') {
 388    return $self->enter($self->gv_or_padgv($nop)->CV);
 389   }
 390   $op = $nop;
 391   $n  = $nn;
 392  }
 393
 394  return 'list';
 395 }
 396
 397 sub pp_const {
 398  my ($self, $op) = @_;
 399
 400  if (class($op) eq 'SVOP' and (my $sv = $self->const_sv($op))) {
 401   my $c = class($sv);
 402   if ($c eq 'AV') {
 403    return $sv->FILL + 1;
 404   } elsif ($c eq 'HV') {
 405    return 2 * $sv->FILL;
 406   }
 407  }
 408
 409  return 1;
 410 }
 411
 412 sub pp_aslice { $_[0]->expect_any($_[1]->first->sibling) }
 413
 414 sub pp_hslice;
 415 *pp_hslice = *pp_aslice{CODE};
 416
 417 sub pp_lslice { $_[0]->expect_any($_[1]->first) }
 418
 419 sub pp_rv2av {
 420  my ($self, $op) = @_;
 421  $op = $op->first;
 422
 423  return (name($op) eq 'const') ? $self->expect_any($op) : 'list';
 424 }
 425
 426 sub pp_aassign { $_[0]->expect_any($_[1]->first) }
 427
 428 sub pp_leaveloop { $_[0]->expect_return($_[1]->first->sibling) }
 429
 430 =head1 EXPORT
 431
 432 An object-oriented module shouldn't export any function, and so does this one.
 433
 434 =head1 CAVEATS
 435
 436 The algorithm may be pessimistic (things seen as C<list> while they are of fixed length) but not optimistic (the opposite, duh).
 437
 438 C<wantarray> isn't specialized when encountered in the optree.
 439
 440 =head1 DEPENDENCIES
 441
 442 L<perl> 5.8.1.
 443
 444 L<Carp> (standard since perl 5), L<B> (since perl 5.005), L<XSLoader> (since perl 5.006) and L<List::Util> (since perl 5.007003).
 445
 446 =head1 AUTHOR
 447
 448 Vincent Pit, C<< <perl at profvince.com> >>, L<http://www.profvince.com>.
 449
 450 You can contact me by mail or on #perl @ FreeNode (vincent or Prof_Vince).
 451
 452 =head1 BUGS
 453
 454 Please report any bugs or feature requests to C<bug-b-nary at rt.cpan.org>, or through the web interface at L<http://rt.cpan.org/NoAuth/ReportBug.html?Queue=Sub-Nary>.  I will be notified, and then you'll automatically be notified of progress on your bug as I make changes.
 455
 456 =head1 SUPPORT
 457
 458 You can find documentation for this module with the perldoc command.
 459
 460     perldoc Sub::Nary
 461
 462 Tests code coverage report is available at L<http://www.profvince.com/perl/cover/Sub-Nary>.
 463
 464 =head1 ACKNOWLEDGEMENTS
 465
 466 Thanks to Sebastien Aperghis-Tramoni for helping to name this module.
 467
 468 =head1 COPYRIGHT & LICENSE
 469
 470 Copyright 2008 Vincent Pit, all rights reserved.
 471
 472 This program is free software; you can redistribute it and/or modify it under the same terms as Perl itself.
 473
 474 =cut
 475
 476 1; # End of Sub::Nary