lib/Sub/Nary.pm

   1 package Sub::Nary;
   2
   3 use 5.008001;
   4
   5 use strict;
   6 use warnings;
   7
   8 use Carp qw/croak/;
   9 use List::Util qw/reduce sum/;
  10
  11 use B qw/class ppname svref_2object OPf_KIDS/;
  12
  13 =head1 NAME
  14
  15 Sub::Nary - Try to count how many elements a subroutine can return in list context.
  16
  17 =head1 VERSION
  18
  19 Version 0.01
  20
  21 =cut
  22
  23 our $VERSION;
  24 BEGIN {
  25  $VERSION  = '0.01';
  26 }
  27
  28 =head1 SYNOPSIS
  29
  30     use Sub::Nary;
  31
  32     my $sn = Sub::Nary->new();
  33     my $r  = $sn->nary(\&hlagh);
  34
  35 =head1 DESCRIPTION
  36
  37 This module uses the L<B> framework to walk into subroutines and try to guess how many scalars are likely to be returned in list context. It's not always possible to give a definitive answer to this question at compile time, so the results are given in terms of "probability of return" (to be understood in a sense described below).
  38
  39 =head1 METHODS
  40
  41 =head2 C<new>
  42
  43 The usual constructor. Currently takes no argument.
  44
  45 =head2 C<nary $coderef>
  46
  47 Takes a code reference to a named or anonymous subroutine, and returns a hash reference whose keys are the possible numbers of returning scalars, and the corresponding values the "probability" to get them. The special key C<'list'> is used to denote a possibly infinite number of returned arguments. The return value hence would look at
  48
  49     { 1 => 0.2, 2 => 0.4, 4 => 0.3, list => 0.1 }
  50
  51 that is, we should get C<1> scalar C<1> time over C<5> and so on. The sum of all values is C<1>. The returned result, and all the results obtained from intermediate subs, are cached into the object.
  52
  53 =head2 C<flush>
  54
  55 Flushes the L<Sub::Nary> object cache. Returns the object itself.
  56
  57 =head1 PROBABILITY OF RETURN
  58
  59 The probability is computed as such :
  60
  61 =over 4
  62
  63 =item * All the returning points in the same subroutine (i.e. all the explicit C<return> and the last computed value) are considered equally possible.
  64
  65 For example, the subroutine
  66
  67     sub simple {
  68      if (rand < 0.1) {
  69       return 1;
  70      } else {
  71       return 2, 3;
  72      }
  73     }
  74
  75 is seen returning one or two arguments each with probability C<1/2>.
  76 As for
  77
  78     sub hlagh {
  79      my $x = rand;
  80      if ($x < 0.1) {
  81       return 1, 2, 3;
  82      } elsif ($x > 0.9) {
  83       return 4, 5;
  84      }
  85     }
  86
  87 it is considered to return C<1> (when the two tests fail, the last computed value is returned, which here is C<< $x > 0.9 >> evaluated in the scalar context of the test), C<2> or C<3> arguments each with probability C<1/3>.
  88
  89 =item * The total probability law for a given returning point is the convolution product of the probabilities of its list elements.
  90
  91 As such,
  92
  93     sub notsosimple {
  94      return 1, simple(), 2
  95     }
  96
  97 returns C<3> or C<4> arguments with probability C<1/2> ; and
  98
  99     sub double {
 100      return simple(), simple()
 101     }
 102
 103 never returns C<1> argument but returns C<2> with probability C<1/2 * 1/2 = 1/4>, C<3> with probability C<1/2 * 1/2 + 1/2 * 1/2 = 1/2> and C<4> with probability C<1/4> too.
 104
 105 =item * The C<list> state is absorbing in regard of all the other ones.
 106
 107 This is just a pedantic way to say that "list + fixed length = list".
 108 That's why
 109
 110     sub listy {
 111      return 1, simple(), @_
 112     }
 113
 114 is considered as always returning an unbounded list.
 115
 116 Also, the convolution law does not behave the same when C<list> elements are involved : in the following example,
 117
 118     sub oneorlist {
 119      if (rand < 0.1) {
 120       return 1
 121      } else {
 122       return @_
 123      }
 124     }
 125
 126     sub composed {
 127      return oneorlist(), oneorlist()
 128     }
 129
 130 C<composed> returns C<2> scalars with probability C<1/2 * 1/2 = 1/4> and a C<list> with probability C<3/4>.
 131
 132 =back
 133
 134 =cut
 135
 136 BEGIN {
 137  require XSLoader;
 138  XSLoader::load(__PACKAGE__, $VERSION);
 139 }
 140
 141 sub _check_self {
 142  croak 'First argument isn\'t a valid ' . __PACKAGE__ . ' object'
 143   unless ref $_[0] and $_[0]->isa(__PACKAGE__);
 144 }
 145
 146 sub new {
 147  my $class = shift;
 148  $class = ref($class) || $class || __PACKAGE__;
 149  bless { cache => { } }, $class;
 150 }
 151
 152 sub flush {
 153  my $self = shift;
 154  _check_self($self);
 155  $self->{cache} = { };
 156  $self;
 157 }
 158
 159 sub nary {
 160  my $self = shift;
 161  my $sub  = shift;
 162
 163  $self->{cv} = [ ];
 164  return $self->enter(svref_2object($sub));
 165 }
 166
 167 sub name ($) {
 168  my $n = $_[0]->name;
 169  $n eq 'null' ? substr(ppname($_[0]->targ), 3) : $n
 170 }
 171
 172 sub combine {
 173  reduce {{
 174   my %res;
 175   my $la = delete $a->{list};
 176   my $lb = delete $b->{list};
 177   if (defined $la || defined $lb) {
 178    $la ||= 0;
 179    $lb ||= 0;
 180    $res{list} = $la + $lb - $la * $lb;
 181   }
 182   while (my ($ka, $va) = each %$a) {
 183    $ka = int $ka;
 184    while (my ($kb, $vb) = each %$b) {
 185     my $key = $ka + int $kb;
 186     $res{$key} += $va * $vb;
 187    }
 188   }
 189   \%res
 190  }} map { (ref) ? $_ : { $_ => 1 } } grep defined, @_;
 191 }
 192
 193 sub add {
 194  reduce {
 195   $a->{$_} += $b->{$_} for keys %$b;
 196   $a
 197  } map { (ref) ? $_ : { $_ => 1 } } grep defined, @_;
 198 }
 199
 200 my %ops;
 201
 202 $ops{$_} = 1      for scalops;
 203 $ops{$_} = 0      for qw/stub nextstate/;
 204 $ops{$_} = 1      for qw/padsv/;
 205 $ops{$_} = 'list' for qw/padav/;
 206 $ops{$_} = 'list' for qw/padhv rv2hv/;
 207 $ops{$_} = 'list' for qw/padany match entereval readline/;
 208
 209 $ops{each}      = { 0 => 0.5, 2 => 0.5 };
 210 $ops{stat}      = { 0 => 0.5, 13 => 0.5 };
 211
 212 $ops{caller}    = sub { my @a = caller 0; scalar @a }->();
 213 $ops{localtime} = do { my @a = localtime; scalar @a };
 214 $ops{gmtime}    = do { my @a = gmtime; scalar @a };
 215
 216 $ops{$_} = { 0 => 0.5, 10 => 0.5 } for map "gpw$_", qw/nam uid ent/;
 217 $ops{$_} = { 0 => 0.5, 4 => 0.5 }  for map "ggr$_", qw/nam gid ent/;
 218 $ops{$_} = 'list'                  for qw/ghbyname ghbyaddr ghostent/;
 219 $ops{$_} = { 0 => 0.5, 4 => 0.5 }  for qw/gnbyname gnbyaddr gnetent/;
 220 $ops{$_} = { 0 => 0.5, 3 => 0.5 }  for qw/gpbyname gpbynumber gprotoent/;
 221 $ops{$_} = { 0 => 0.5, 4 => 0.5 }  for qw/gsbyname gsbyport gservent/;
 222
 223 sub enter {
 224  my ($self, $cv) = @_;
 225
 226  return 'list' if class($cv) ne 'CV';
 227  my $op  = $cv->ROOT;
 228  my $tag = tag($op);
 229
 230  return { %{$self->{cache}->{$tag}} } if exists $self->{cache}->{$tag};
 231
 232  # Anything can happen with recursion
 233  for (@{$self->{cv}}) {
 234   return 'list' if $tag == tag($_->ROOT);
 235  }
 236
 237  unshift @{$self->{cv}}, $cv;
 238  (my $r, undef) = $self->expect_any($op->first);
 239  shift @{$self->{cv}};
 240
 241  $r = { $r => 1} unless ref $r;
 242  my $total = sum values %$r;
 243  $r = { map { $_ => $r->{$_} / $total } keys %$r };
 244  $self->{cache}->{$tag} = { %$r };
 245  return $r;
 246 }
 247
 248 sub expect_return {
 249  my ($self, $op) = @_;
 250
 251  return ($self->expect_list($op))[0] => 1 if name($op) eq 'return';
 252
 253  if ($op->flags & OPf_KIDS) {
 254   for ($op = $op->first; not null $op; $op = $op->sibling) {
 255    my ($p, $r) = $self->expect_return($op);
 256    return $p => 1 if $r;
 257   }
 258  }
 259
 260  return;
 261 }
 262
 263 sub expect_list {
 264  my ($self, $op) = @_;
 265
 266  my $n = name($op);
 267  my $meth = $self->can('pp_' . $n);
 268  return $self->$meth($op) if $meth;
 269  if (exists $ops{$n}) {
 270   my $r = $ops{$n};
 271   $r = { %$r } if ref $r eq 'HASH';
 272   return $r => 0;
 273  }
 274
 275  if ($op->flags & OPf_KIDS) {
 276   my @res = (0);
 277   my ($p, $r);
 278   for ($op = $op->first; not null $op; $op = $op->sibling) {
 279    my $n = name($op);
 280    next if $n eq 'pushmark';
 281    if ($n eq 'nextstate'
 282        and not null(($op = $op->sibling)->sibling)) {
 283     ($p, $r) = $self->expect_return($op);
 284     return $p => 1 if $r;
 285    } else {
 286     ($p, $r) = $self->expect_any($op);
 287     return $p => 1 if $r;
 288     push @res, $p;
 289    }
 290   }
 291   return (combine @res) => 0;
 292  }
 293
 294  return;
 295 }
 296
 297 sub expect_any {
 298  my ($self, $op) = @_;
 299
 300  return ($self->expect_list($op))[0] => 1 if name($op) eq 'return';
 301
 302  if (class($op) eq 'LOGOP' and not null $op->first) {
 303   my @res;
 304   my ($p, $r);
 305
 306   my $op   = $op->first;
 307   ($p, $r) = $self->expect_return($op);
 308   return $p => 1 if $r;
 309
 310   $op = $op->sibling;
 311   push @res, ($self->expect_any($op))[0];
 312
 313   # If the logop has no else branch, it can also return the *scalar* result of
 314   # the conditional
 315   $op = $op->sibling;
 316   if (null $op) {
 317    push @res, 1;
 318   } else {
 319    push @res, ($self->expect_any($op))[0];
 320   }
 321
 322   return (add @res) => 0;
 323  }
 324
 325  return $self->expect_list($op);
 326 }
 327
 328 # Stolen from B::Deparse
 329
 330 sub padval { $_[0]->{cv}->[0]->PADLIST->ARRAYelt(1)->ARRAYelt($_[1]) }
 331
 332 sub gv_or_padgv {
 333  my ($self, $op) = @_;
 334  if (class($op) eq 'PADOP') {
 335   return $self->padval($op->padix)
 336  } else { # class($op) eq "SVOP"
 337   return $op->gv;
 338  }
 339 }
 340
 341 sub const_sv {
 342  my ($self, $op) = @_;
 343  my $sv = $op->sv;
 344  # the constant could be in the pad (under useithreads)
 345  $sv = $self->padval($op->targ) unless $$sv;
 346  return $sv;
 347 }
 348
 349 sub pp_entersub {
 350  my ($self, $op, $exp) = @_;
 351
 352  my $next = $op;
 353  while ($next->flags & OPf_KIDS) {
 354   $next = $next->first;
 355  }
 356  while (not null $next) {
 357   $op = $next;
 358   my ($p, $r) = $self->expect_return($op, $exp);
 359   return $p => 1 if $r;
 360   $next = $op->sibling;
 361  }
 362
 363  if (name($op) eq 'rv2cv') {
 364   my $n;
 365   do {
 366    $op = $op->first;
 367    my $next = $op->sibling;
 368    while (not null $next) {
 369     $op   = $next;
 370     $next = $next->sibling;
 371    }
 372    $n  = name($op)
 373   } while ($op->flags & OPf_KIDS and { map { $_ => 1 } qw/null leave/ }->{$n});
 374   return 'list' unless { map { $_ => 1 } qw/gv refgen/ }->{$n};
 375   local $self->{sub} = 1;
 376   return $self->expect_any($op, $exp);
 377  } else {
 378   # Method call ?
 379   return 'list';
 380  }
 381 }
 382
 383 sub pp_gv {
 384  my ($self, $op) = @_;
 385
 386  return $self->{sub} ? $self->enter($self->gv_or_padgv($op)->CV) : 1
 387 }
 388
 389 sub pp_anoncode {
 390  my ($self, $op) = @_;
 391
 392  return $self->{sub} ? $self->enter($self->const_sv($op)) : 1
 393 }
 394
 395 sub pp_goto {
 396  my ($self, $op) = @_;
 397
 398  my $n = name($op);
 399  while ($op->flags & OPf_KIDS) {
 400   my $nop = $op->first;
 401   my $nn  = name($nop);
 402   if ($nn eq 'pushmark') {
 403    $nop = $nop->sibling;
 404    $nn  = name($nop);
 405   }
 406   if ($n eq 'rv2cv' and $nn eq 'gv') {
 407    return $self->enter($self->gv_or_padgv($nop)->CV);
 408   }
 409   $op = $nop;
 410   $n  = $nn;
 411  }
 412
 413  return 'list';
 414 }
 415
 416 sub pp_const {
 417  my ($self, $op) = @_;
 418
 419  my $sv = $self->const_sv($op);
 420  my $c = class($sv);
 421  if ($c eq 'AV') {
 422   return $sv->FILL + 1;
 423  } elsif ($c eq 'HV') {
 424   return 2 * $sv->FILL;
 425  }
 426
 427  return 1;
 428 }
 429
 430 sub pp_aslice { $_[0]->expect_any($_[1]->first->sibling) }
 431
 432 sub pp_hslice;
 433 *pp_hslice = *pp_aslice{CODE};
 434
 435 sub pp_lslice { $_[0]->expect_any($_[1]->first) }
 436
 437 sub pp_rv2av {
 438  my ($self, $op) = @_;
 439  $op = $op->first;
 440
 441  return (name($op) eq 'const') ? $self->expect_any($op) : 'list';
 442 }
 443
 444 sub pp_aassign {
 445  my ($self, $op) = @_;
 446
 447  $op = $op->first;
 448
 449  # Can't assign to return
 450  my ($p, $r) = $self->expect_list($op->sibling);
 451  return $p => 0 if not exists $p->{list};
 452
 453  $self->expect_any($op);
 454 }
 455
 456 sub pp_leaveloop { $_[0]->expect_return($_[1]->first->sibling) }
 457
 458 sub pp_flip {
 459  my ($self, $op) = @_;
 460
 461  $op = $op->first;
 462  return 'list' if name($op) ne 'range';
 463
 464  my $begin = $op->first;
 465  if (name($begin) eq 'const') {
 466   my $end = $begin->sibling;
 467   if (name($end) eq 'const') {
 468    $begin  = $self->const_sv($begin);
 469    $end    = $self->const_sv($end);
 470    no warnings 'numeric';
 471    return int(${$end->object_2svref}) - int(${$begin->object_2svref}) + 1;
 472   } else {
 473    my ($p, $r) = $self->expect_return($end);
 474    return $p => 1 if $r;
 475   }
 476  } else {
 477   my ($p, $r) = $self->expect_return($begin);
 478   return $p => 1 if $r;
 479  }
 480
 481  return 'list'
 482 }
 483
 484 =head1 EXPORT
 485
 486 An object-oriented module shouldn't export any function, and so does this one.
 487
 488 =head1 CAVEATS
 489
 490 The algorithm may be pessimistic (things seen as C<list> while they are of fixed length) but not optimistic (the opposite, duh).
 491
 492 C<wantarray> isn't specialized when encountered in the optree.
 493
 494 =head1 DEPENDENCIES
 495
 496 L<perl> 5.8.1.
 497
 498 L<Carp> (standard since perl 5), L<B> (since perl 5.005), L<XSLoader> (since perl 5.006) and L<List::Util> (since perl 5.007003).
 499
 500 =head1 AUTHOR
 501
 502 Vincent Pit, C<< <perl at profvince.com> >>, L<http://www.profvince.com>.
 503
 504 You can contact me by mail or on #perl @ FreeNode (vincent or Prof_Vince).
 505
 506 =head1 BUGS
 507
 508 Please report any bugs or feature requests to C<bug-b-nary at rt.cpan.org>, or through the web interface at L<http://rt.cpan.org/NoAuth/ReportBug.html?Queue=Sub-Nary>.  I will be notified, and then you'll automatically be notified of progress on your bug as I make changes.
 509
 510 =head1 SUPPORT
 511
 512 You can find documentation for this module with the perldoc command.
 513
 514     perldoc Sub::Nary
 515
 516 Tests code coverage report is available at L<http://www.profvince.com/perl/cover/Sub-Nary>.
 517
 518 =head1 ACKNOWLEDGEMENTS
 519
 520 Thanks to Sebastien Aperghis-Tramoni for helping to name this module.
 521
 522 =head1 COPYRIGHT & LICENSE
 523
 524 Copyright 2008 Vincent Pit, all rights reserved.
 525
 526 This program is free software; you can redistribute it and/or modify it under the same terms as Perl itself.
 527
 528 =cut
 529
 530 1; # End of Sub::Nary