t/34-localize_elem-magic.t

   1 #!perl
   2
   3 use strict;
   4 use warnings;
   5
   6 use Scope::Upper qw<localize_elem UP HERE>;
   7
   8 use Test::More tests => 8;
   9
  10 {
  11  package Scope::Upper::Test::TiedArray;
  12
  13  sub TIEARRAY { bless [], $_[0] }
  14  sub STORE { $_[0]->[$_[1]] = $_[2] }
  15  sub FETCH { $_[0]->[$_[1]] }
  16  sub CLEAR { @{$_[0]} = (); }
  17  sub FETCHSIZE { scalar @{$_[0]} }
  18  sub EXTEND {}
  19 }
  20
  21 our @a;
  22
  23 {
  24  local @a;
  25  tie @a, 'Scope::Upper::Test::TiedArray';
  26  @a = (5 .. 7);
  27  {
  28   localize_elem '@a', 4 => 12 => HERE;
  29   is_deeply \@a, [ 5 .. 7, undef, 12 ], 'localize_elem @incomplete_tied_array, $nonexistent, 12 => HERE [ok]';
  30  }
  31  is_deeply \@a, [ 5 .. 7, undef, undef ], 'localize_elem @incomplete_tied_array, $nonexistent, 12 => HERE [end]';
  32 }
  33
  34 our $x;
  35
  36 {
  37  local $x;
  38  local $SIG{__WARN__} = sub { };
  39  {
  40   {
  41    localize_elem '%SIG', '__WARN__' => sub { $x = join '', @_ } => UP;
  42    is $x, undef, 'localize_elem $SIG{__WARN__} [not yet]';
  43   }
  44   warn "1\n";
  45   is $x, "1\n", 'localize_elem $SIG{__WARN__} [ok]';
  46  }
  47  warn "2\n";
  48  is $x, "1\n", 'localize_elem $SIG{__WARN__} [done]';
  49 }
  50
  51 sub runperl {
  52  my ($val, $in, $desc) = @_;
  53  system { $^X } $^X, '-e', "exit(\$ENV{SCOPE_UPPER_TEST} == $val ? 0 : 1)";
  54 SKIP: {
  55   skip "system() failed: $!" => 1 if $? == -1;
  56   if ($in) {
  57    is $?, 0, $desc;
  58   } else {
  59    isnt $?, 0, $desc;
  60   }
  61  }
  62 }
  63
  64 eval "setpgrp 0, 0";
  65
  66 my $time = time;
  67 {
  68  local $ENV{SCOPE_UPPER_TEST};
  69  {
  70   {
  71    localize_elem '%ENV', 'SCOPE_UPPER_TEST' => $time => UP;
  72    runperl $time, 0, 'localize_elem $ENV{SCOPE_UPPER_TEST} [not yet]';
  73   }
  74   runperl $time, 1, 'localize_elem $ENV{SCOPE_UPPER_TEST} [ok]';
  75  }
  76  runperl $time, 0, 'localize_elem $ENV{SCOPE_UPPER_TEST} [done]';
  77 }