lib/Scope/Upper.pm

   1 package Scope::Upper;
   2
   3 use strict;
   4 use warnings;
   5
   6 =head1 NAME
   7
   8 Scope::Upper - Act on upper scopes.
   9
  10 =head1 VERSION
  11
  12 Version 0.05
  13
  14 =cut
  15
  16 our $VERSION;
  17 BEGIN {
  18  $VERSION = '0.05';
  19 }
  20
  21 =head1 SYNOPSIS
  22
  23     package X;
  24
  25     use Scope::Upper qw/reap localize localize_elem localize_delete UP/;
  26
  27     sub desc { shift->{desc} }
  28
  29     sub set_tag {
  30      my ($desc) = @_;
  31
  32      # First localize $x so that it gets destroyed last
  33      localize '$x' => bless({ desc => $desc }, __PACKAGE__) => UP;
  34
  35      reap sub {
  36       my $pkg = caller;
  37       my $x = do { no strict 'refs'; ${$pkg.'::x'} }; # Get the $x in the scope
  38       print $x->desc . ": done\n";
  39      } => UP;
  40
  41      localize_elem '%SIG', '__WARN__' => sub {
  42       my $pkg = caller;
  43       my $x = do { no strict 'refs'; ${$pkg.'::x'} }; # Get the $x in the scope
  44       CORE::warn($x->desc . ': ' . join('', @_));
  45      } => UP;
  46
  47      localize_delete '@ARGV', $#ARGV => UP; # delete last @ARGV element
  48     }
  49
  50     package Y;
  51
  52     {
  53      X::set_tag('pie');
  54      # $x is now a X object, and @ARGV has one element less
  55      warn 'what'; # warns "pie: what at ..."
  56      ...
  57     } # "pie: done" is printed
  58
  59     package Z;
  60
  61     use Scope::Upper qw/unwind want_at :words/;
  62
  63     sub try (&) {
  64      my @result = shift->();
  65      my $cx = SUB UP SUB;
  66      unwind +(want_at($cx) ? @result : scalar @result) => $cx;
  67     }
  68
  69     ...
  70
  71     sub zap {
  72      try {
  73       return @things; # returns to try() and then outside zap()
  74      }
  75     }
  76
  77     my @what = zap(); # @what contains @things
  78
  79 =head1 DESCRIPTION
  80
  81 This module lets you defer actions that will take place when the control flow returns into an upper scope.
  82 Currently, you can hook an upper scope end, or localize variables, array/hash values or deletions of elements in higher contexts.
  83 You can also return to an upper level and know which context was in use then.
  84
  85 =head1 WORDS
  86
  87 These control words are to be used to indicate the target scope.
  88
  89 =head2 C<TOP>
  90
  91 Returns the level that currently represents the highest scope.
  92
  93 =head2 C<HERE>
  94
  95 The current level.
  96
  97 =head2 C<UP $from>
  98
  99 The level of the scope just above C<$from>.
 100
 101 =head2 C<SUB $from>
 102
 103 The level of the closest subroutine context above C<$from>.
 104
 105 =head2 C<EVAL $from>
 106
 107 The level of the closest eval context above C<$from>.
 108
 109 If C<$from> is omitted in any of those functions, the current level is used as the reference level.
 110
 111 =head2 C<CALLER $stack>
 112
 113 The level of the C<$stack>-th upper subroutine/eval/format context.
 114 It kind of corresponds to the context represented by C<caller $stack>, but while e.g. C<caller 0> refers to the caller context, C<CALLER 0> will refer to the top scope in the current context.
 115
 116 =head1 FUNCTIONS
 117
 118 =cut
 119
 120 BEGIN {
 121  require XSLoader;
 122  XSLoader::load(__PACKAGE__, $VERSION);
 123 }
 124
 125 =head2 C<reap $callback, $level>
 126
 127 Add a destructor that calls C<$callback> when the C<$level>-th upper scope ends, where C<0> corresponds to the current scope.
 128
 129 =head2 C<localize $what, $value, $level>
 130
 131 A C<local> delayed to the time of first return into the C<$level>-th upper scope.
 132 C<$what> can be :
 133
 134 =over 4
 135
 136 =item *
 137
 138 A glob, in which case C<$value> can either be a glob or a reference.
 139 L</localize> follows then the same syntax as C<local *x = $value>.
 140 For example, if C<$value> is a scalar reference, then the C<SCALAR> slot of the glob will be set to C<$$value> - just like C<local *x = \1> sets C<$x> to C<1>.
 141
 142 =item *
 143
 144 A string beginning with a sigil, representing the symbol to localize and to assign to.
 145 If the sigil is C<'$'>, L</localize> follows the same syntax as C<local $x = $value>, i.e. C<$value> isn't dereferenced.
 146 For example,
 147
 148     localize '$x', \'foo' => HERE;
 149
 150 will set C<$x> to a reference to the string C<'foo'>.
 151 Other sigils (C<'@'>, C<'%'>, C<'&'> and C<'*'>) require C<$value> to be a reference of the corresponding type.
 152
 153 When the symbol is given by a string, it is resolved when the actual localization takes place and not when C<localize> is called.
 154 This means that
 155
 156     sub tag { localize '$x', $_[0] => UP }
 157
 158 will localize in the caller's namespace.
 159
 160 =back
 161
 162 =head2 C<localize_elem $what, $key, $value, $level>
 163
 164 Similar to L</localize> but for array and hash elements.
 165 If C<$what> is a glob, the slot to fill is determined from which type of reference C<$value> is ; otherwise it's inferred from the sigil.
 166 C<$key> is either an array index or a hash key, depending of which kind of variable you localize.
 167
 168 =head2 C<localize_delete $what, $key, $level>
 169
 170 Similiar to L</localize>, but for deleting variables or array/hash elements.
 171 C<$what> can be:
 172
 173 =over 4
 174
 175 =item *
 176
 177 A glob, in which case C<$key> is ignored and the call is equivalent to C<local *x>.
 178
 179 =item *
 180
 181 A string beginning with C<'@'> or C<'%'>, for which the call is equivalent to respectiveley C<local $a[$key]; delete $a[$key]> and C<local $h{$key}; delete $h{$key}>.
 182
 183 =item *
 184
 185 A string beginning with C<'&'>, which more or less does C<undef &func> in the upper scope.
 186 It's actually more powerful, as C<&func> won't even C<exists> anymore.
 187 C<$key> is ignored.
 188
 189 =back
 190
 191 =head2 C<unwind @values, $level>
 192
 193 Returns C<@values> I<from> the context indicated by C<$level>, i.e. from the subroutine, eval or format just above C<$level>.
 194
 195 The upper level isn't coerced onto C<@values>, which is hence always evaluated in list context.
 196 This means that
 197
 198     my $num = sub {
 199      my @a = ('a' .. 'z');
 200      unwind @a => HERE;
 201     }->();
 202
 203 will set C<$num> to C<'z'>.
 204 You can use L</want_at> to handle these cases.
 205
 206 =head2 C<want_at $level>
 207
 208 Like C<wantarray>, but for the subroutine/eval/format context just above C<$level>.
 209
 210 The previous example can then be "corrected" :
 211
 212     my $num = sub {
 213      my @a = ('a' .. 'z');
 214      unwind +(want_at(HERE) ? @a : scalar @a) => HERE;
 215     }->();
 216
 217 will righteously set C<$num> to C<26>.
 218
 219 =head1 EXPORT
 220
 221 The functions L</reap>, L</localize>, L</localize_elem>, L</localize_delete>,  L</unwind> and L</want_at> are only exported on request, either individually or by the tags C<':funcs'> and C<':all'>.
 222
 223 Same goes for the words L</TOP>, L</HERE>, L</UP>, L</SUB>, L</EVAL> and L</CALLER> that are only exported on request, individually or by the tags C<':words'> and C<':all'>.
 224
 225 =cut
 226
 227 use base qw/Exporter/;
 228
 229 our @EXPORT      = ();
 230 our %EXPORT_TAGS = (
 231  funcs => [ qw/reap localize localize_elem localize_delete unwind want_at/ ],
 232  words => [ qw/TOP HERE UP SUB EVAL CALLER/ ],
 233 );
 234 our @EXPORT_OK   = map { @$_ } values %EXPORT_TAGS;
 235 $EXPORT_TAGS{'all'} = [ @EXPORT_OK ];
 236
 237 =head1 CAVEATS
 238
 239 Be careful that local variables are restored in the reverse order in which they were localized.
 240 Consider those examples:
 241
 242     local $x = 0;
 243     {
 244      reap sub { print $x } => HERE;
 245      local $x = 1;
 246      ...
 247     }
 248     # prints '0'
 249     ...
 250     {
 251      local $x = 1;
 252      reap sub { $x = 2 } => HERE;
 253      ...
 254     }
 255     # $x is 0
 256
 257 The first case is "solved" by moving the C<local> before the C<reap>, and the second by using L</localize> instead of L</reap>.
 258
 259 L</reap>, L</localize> and L</localize_elem> effects can't cross C<BEGIN> blocks, hence calling those functions in C<import> is deemed to be useless.
 260 This is an hopeless case because C<BEGIN> blocks are executed once while localizing constructs should do their job at each run.
 261
 262 =head1 DEPENDENCIES
 263
 264 L<XSLoader> (standard since perl 5.006).
 265
 266 =head1 SEE ALSO
 267
 268 L<Alias>, L<Hook::Scope>, L<Scope::Guard>, L<Guard>.
 269
 270 =head1 AUTHOR
 271
 272 Vincent Pit, C<< <perl at profvince.com> >>, L<http://www.profvince.com>.
 273
 274 You can contact me by mail or on C<irc.perl.org> (vincent).
 275
 276 =head1 BUGS
 277
 278 Please report any bugs or feature requests to C<bug-scope-upper at rt.cpan.org>, or through the web interface at L<http://rt.cpan.org/NoAuth/ReportBug.html?Queue=Scope-Upper>.  I will be notified, and then you'll automatically be notified of progress on your bug as I make changes.
 279
 280 =head1 SUPPORT
 281
 282 You can find documentation for this module with the perldoc command.
 283
 284     perldoc Scope::Upper
 285
 286 Tests code coverage report is available at L<http://www.profvince.com/perl/cover/Scope-Upper>.
 287
 288 =head1 ACKNOWLEDGEMENTS
 289
 290 Inspired by Ricardo Signes.
 291
 292 =head1 COPYRIGHT & LICENSE
 293
 294 Copyright 2008-2009 Vincent Pit, all rights reserved.
 295
 296 This program is free software; you can redistribute it and/or modify it under the same terms as Perl itself.
 297
 298 =cut
 299
 300 1; # End of Scope::Upper