lib/Scope/Upper.pm

   1 package Scope::Upper;
   2
   3 use strict;
   4 use warnings;
   5
   6 =head1 NAME
   7
   8 Scope::Upper - Act on upper scopes.
   9
  10 =head1 VERSION
  11
  12 Version 0.10
  13
  14 =cut
  15
  16 our $VERSION;
  17 BEGIN {
  18  $VERSION = '0.10';
  19 }
  20
  21 =head1 SYNOPSIS
  22
  23     package X;
  24
  25     use Scope::Upper qw/reap localize localize_elem localize_delete :words/;
  26
  27     sub desc { shift->{desc} }
  28
  29     sub set_tag {
  30      my ($desc) = @_;
  31
  32      # First localize $x so that it gets destroyed last
  33      localize '$x' => bless({ desc => $desc }, __PACKAGE__) => UP; # one scope up
  34
  35      reap sub {
  36       my $pkg = caller;
  37       my $x = do { no strict 'refs'; ${$pkg.'::x'} }; # Get the $x in the scope
  38       print $x->desc . ": done\n";
  39      } => SCOPE 1; # same as UP here
  40
  41      localize_elem '%SIG', '__WARN__' => sub {
  42       my $pkg = caller;
  43       my $x = do { no strict 'refs'; ${$pkg.'::x'} }; # Get the $x in the scope
  44       CORE::warn($x->desc . ': ' . join('', @_));
  45      } => UP CALLER 0; # same as UP here
  46
  47      # delete last @ARGV element
  48      localize_delete '@ARGV', -1 => UP SUB HERE; # same as UP here
  49     }
  50
  51     package Y;
  52
  53     {
  54      X::set_tag('pie');
  55      # $x is now a X object, and @ARGV has one element less
  56      warn 'what'; # warns "pie: what at ..."
  57      ...
  58     } # "pie: done" is printed
  59
  60     package Z;
  61
  62     use Scope::Upper qw/unwind want_at :words/;
  63
  64     sub try (&) {
  65      my @result = shift->();
  66      my $cx = SUB UP SUB;
  67      unwind +(want_at($cx) ? @result : scalar @result) => $cx;
  68     }
  69
  70     ...
  71
  72     sub zap {
  73      try {
  74       return @things; # returns to try() and then outside zap()
  75       # not reached
  76      }
  77      # not reached
  78     }
  79
  80     my @what = zap(); # @what contains @things
  81
  82 =head1 DESCRIPTION
  83
  84 This module lets you defer actions I<at run-time> that will take place when the control flow returns into an upper scope.
  85 Currently, you can:
  86
  87 =over 4
  88
  89 =item *
  90
  91 hook an upper scope end with L</reap> ;
  92
  93 =item *
  94
  95 localize variables, array/hash values or deletions of elements in higher contexts with respectively L</localize>, L</localize_elem> and L</localize_delete> ;
  96
  97 =item *
  98
  99 return values immediately to an upper level with L</unwind>, and know which context was in use then with L</want_at>.
 100
 101 =back
 102
 103 =head1 FUNCTIONS
 104
 105 In all those functions, C<$context> refers to the target scope.
 106
 107 You have to use one or a combination of L</WORDS> to build the C<$context> passed to these functions.
 108 This is needed in order to ensure that the module still works when your program is ran in the debugger.
 109 The only thing you can assume is that it is an I<absolute> indicator of the frame, which means that you can safely store it at some point and use it when needed, and it will still denote the original scope.
 110
 111 =cut
 112
 113 BEGIN {
 114  require XSLoader;
 115  XSLoader::load(__PACKAGE__, $VERSION);
 116 }
 117
 118 =head2 C<reap $callback, $context>
 119
 120 Add a destructor that calls C<$callback> (in void context) when the upper scope represented by C<$context> ends.
 121
 122 =head2 C<localize $what, $value, $context>
 123
 124 A C<local> delayed to the time of first return into the upper scope denoted by C<$context>.
 125 C<$what> can be :
 126
 127 =over 4
 128
 129 =item *
 130
 131 A glob, in which case C<$value> can either be a glob or a reference.
 132 L</localize> follows then the same syntax as C<local *x = $value>.
 133 For example, if C<$value> is a scalar reference, then the C<SCALAR> slot of the glob will be set to C<$$value> - just like C<local *x = \1> sets C<$x> to C<1>.
 134
 135 =item *
 136
 137 A string beginning with a sigil, representing the symbol to localize and to assign to.
 138 If the sigil is C<'$'>, L</localize> follows the same syntax as C<local $x = $value>, i.e. C<$value> isn't dereferenced.
 139 For example,
 140
 141     localize '$x', \'foo' => HERE;
 142
 143 will set C<$x> to a reference to the string C<'foo'>.
 144 Other sigils (C<'@'>, C<'%'>, C<'&'> and C<'*'>) require C<$value> to be a reference of the corresponding type.
 145
 146 When the symbol is given by a string, it is resolved when the actual localization takes place and not when C<localize> is called.
 147 Thus, if the symbol name is not qualified, it will refer to the variable in the package where the localization actually takes place and not in the one where the C<localize> call was compiled.
 148 For example,
 149
 150     {
 151      package Scope;
 152      sub new { localize '$tag', $_[0] => UP }
 153     }
 154
 155     {
 156      package Tool;
 157      {
 158       Scope->new;
 159       ...
 160      }
 161     }
 162
 163 will localize C<$Tool::tag> and not C<$Scope::tag>.
 164
 165 =back
 166
 167 =head2 C<localize_elem $what, $key, $value, $context>
 168
 169 Similar to L</localize> but for array and hash elements.
 170 If C<$what> is a glob, the slot to fill is determined from which type of reference C<$value> is ; otherwise it's inferred from the sigil.
 171 C<$key> is either an array index or a hash key, depending of which kind of variable you localize.
 172
 173 =head2 C<localize_delete $what, $key, $context>
 174
 175 Similiar to L</localize>, but for deleting variables or array/hash elements.
 176 C<$what> can be:
 177
 178 =over 4
 179
 180 =item *
 181
 182 A glob, in which case C<$key> is ignored and the call is equivalent to C<local *x>.
 183
 184 =item *
 185
 186 A string beginning with C<'@'> or C<'%'>, for which the call is equivalent to respectiveley C<local $a[$key]; delete $a[$key]> and C<local $h{$key}; delete $h{$key}>.
 187
 188 =item *
 189
 190 A string beginning with C<'&'>, which more or less does C<undef &func> in the upper scope.
 191 It's actually more powerful, as C<&func> won't even C<exists> anymore.
 192 C<$key> is ignored.
 193
 194 =back
 195
 196 =head2 C<unwind @values, $context>
 197
 198 Returns C<@values> I<from> the context pointed by C<$context>, i.e. from the subroutine, eval or format just above C<$context>, and immediately restart the program flow at this point - thus effectively returning to (or from, depending on how you see it) an upper context.
 199
 200 The upper context isn't coerced onto C<@values>, which is hence always evaluated in list context.
 201 This means that
 202
 203     my $num = sub {
 204      my @a = ('a' .. 'z');
 205      unwind @a => HERE;
 206      # not reached
 207     }->();
 208
 209 will set C<$num> to C<'z'>.
 210 You can use L</want_at> to handle these cases.
 211
 212 =head2 C<want_at $context>
 213
 214 Like C<wantarray>, but for the subroutine/eval/format just above C<$context>.
 215
 216 The previous example can then be "corrected" :
 217
 218     my $num = sub {
 219      my @a = ('a' .. 'z');
 220      unwind +(want_at(HERE) ? @a : scalar @a) => HERE;
 221      # not reached
 222     }->();
 223
 224 will rightfully set C<$num> to C<26>.
 225
 226 =head1 CONSTANTS
 227
 228 =head2 C<SU_THREADSAFE>
 229
 230 True iff the module could have been built when thread-safety features.
 231
 232 =head1 WORDS
 233
 234 =head2 Constants
 235
 236 =head3 C<TOP>
 237
 238 Returns the context that currently represents the highest scope.
 239
 240 =head3 C<HERE>
 241
 242 The context of the current scope.
 243
 244 =head2 Getting a context from a context
 245
 246 For any of those functions, C<$from> is expected to be a context.
 247 When omitted, it defaults to the the current context.
 248
 249 =head3 C<UP $from>
 250
 251 The context of the scope just above C<$from>.
 252
 253 =head3 C<SUB $from>
 254
 255 The context of the closest subroutine above C<$from>.
 256 Note that C<$from> is returned if it is already a subroutine context ; hence C<SUB SUB == SUB>.
 257
 258 =head3 C<EVAL $from>
 259
 260 The context of the closest eval above C<$from>.
 261 Note that C<$from> is returned if it is already an eval context ; hence C<EVAL EVAL == EVAL>.
 262
 263 =head2 Getting a context from a level
 264
 265 Here, C<$level> should denote a number of scopes above the current one.
 266 When omitted, it defaults to C<0> and those functions return the same context as L</HERE>.
 267
 268 =head3 C<SCOPE $level>
 269
 270 The C<$level>-th upper context, regardless of its type.
 271
 272 =head3 C<CALLER $level>
 273
 274 The context of the C<$level>-th upper subroutine/eval/format.
 275 It kind of corresponds to the context represented by C<caller $level>, but while e.g. C<caller 0> refers to the caller context, C<CALLER 0> will refer to the top scope in the current context.
 276
 277 =head2 Examples
 278
 279 Where L</reap> fires depending on the C<$cxt> :
 280
 281     sub {
 282      eval {
 283       sub {
 284        {
 285         reap \&cleanup => $cxt;
 286         ...
 287        }     # $cxt = SCOPE(0), or HERE
 288        ...
 289       }->(); # $cxt = SCOPE(1), or UP, or SUB, or CALLER, or CALLER(0)
 290       ...
 291      };      # $cxt = SCOPE(2), or UP UP, or UP SUB, or EVAL, or CALLER(1)
 292      ...
 293     }->();   # $cxt = SCOPE(3), or SUB UP SUB, or SUB EVAL, or CALLER(2)
 294     ...
 295
 296 Where L</localize>, L</localize_elem> and L</localize_delete> act depending on the C<$cxt> :
 297
 298     sub {
 299      eval {
 300       sub {
 301        {
 302         localize '$x' => 1 => $cxt;
 303         # $cxt = SCOPE(0), or HERE
 304         ...
 305        }
 306        # $cxt = SCOPE(1), or UP, or SUB, or CALLER, or CALLER(0)
 307        ...
 308       }->();
 309       # $cxt = SCOPE(2), or UP UP, or UP SUB, or EVAL, or CALLER(1)
 310       ...
 311      };
 312      # $cxt = SCOPE(3), or SUB UP SUB, or SUB EVAL, or CALLER(2)
 313      ...
 314     }->();
 315     # $cxt = SCOPE(4), UP SUB UP SUB, or UP SUB EVAL, or UP CALLER(2), or TOP
 316     ...
 317
 318 Where L</unwind> and L</want_at> point to depending on the C<$cxt>:
 319
 320     sub {
 321      eval {
 322       sub {
 323        {
 324         unwind @things => $cxt;
 325         ...
 326        }
 327        ...
 328       }->(); # $cxt = SCOPE(0 .. 1), or HERE, or UP, or SUB, or CALLER(0)
 329       ...
 330      };      # $cxt = SCOPE(2), or UP UP, or UP SUB, or EVAL, or CALLER(1)
 331      ...
 332     }->();   # $cxt = SCOPE(3), or SUB UP SUB, or SUB EVAL, or CALLER(2)
 333     ...
 334
 335 =head1 EXPORT
 336
 337 The functions L</reap>, L</localize>, L</localize_elem>, L</localize_delete>,  L</unwind> and L</want_at> are only exported on request, either individually or by the tags C<':funcs'> and C<':all'>.
 338
 339 The constant L</SU_THREADSAFE> is also only exported on request, individually or by the tags C<':consts'> and C<':all'>.
 340
 341 Same goes for the words L</TOP>, L</HERE>, L</UP>, L</SUB>, L</EVAL>, L</SCOPE> and L</CALLER> that are only exported on request, individually or by the tags C<':words'> and C<':all'>.
 342
 343 =cut
 344
 345 use base qw/Exporter/;
 346
 347 our @EXPORT      = ();
 348 our %EXPORT_TAGS = (
 349  funcs  => [ qw/reap localize localize_elem localize_delete unwind want_at/ ],
 350  words  => [ qw/TOP HERE UP SUB EVAL SCOPE CALLER/ ],
 351  consts => [ qw/SU_THREADSAFE/ ],
 352 );
 353 our @EXPORT_OK   = map { @$_ } values %EXPORT_TAGS;
 354 $EXPORT_TAGS{'all'} = [ @EXPORT_OK ];
 355
 356 =head1 CAVEATS
 357
 358 Be careful that local variables are restored in the reverse order in which they were localized.
 359 Consider those examples:
 360
 361     local $x = 0;
 362     {
 363      reap sub { print $x } => HERE;
 364      local $x = 1;
 365      ...
 366     }
 367     # prints '0'
 368     ...
 369     {
 370      local $x = 1;
 371      reap sub { $x = 2 } => HERE;
 372      ...
 373     }
 374     # $x is 0
 375
 376 The first case is "solved" by moving the C<local> before the C<reap>, and the second by using L</localize> instead of L</reap>.
 377
 378 The effects of L</reap>, L</localize> and L</localize_elem> can't cross C<BEGIN> blocks, hence calling those functions in C<import> is deemed to be useless.
 379 This is an hopeless case because C<BEGIN> blocks are executed once while localizing constructs should do their job at each run.
 380 However, it's possible to hook the end of the current scope compilation with L<B::Hooks::EndOfScope>.
 381
 382 Some rare oddities may still happen when running inside the debugger.
 383 It may help to use a perl higher than 5.8.9 or 5.10.0, as they contain some context-related fixes.
 384
 385 =head1 DEPENDENCIES
 386
 387 L<XSLoader> (standard since perl 5.006).
 388
 389 =head1 SEE ALSO
 390
 391 L<Alias>, L<Hook::Scope>, L<Scope::Guard>, L<Guard>.
 392
 393 L<Continuation::Escape> is a thin wrapper around L<Scope::Upper> that gives you a continuation passing style interface to L</unwind>.
 394 It's easier to use, but it requires you to have control over the scope where you want to return.
 395
 396 =head1 AUTHOR
 397
 398 Vincent Pit, C<< <perl at profvince.com> >>, L<http://www.profvince.com>.
 399
 400 You can contact me by mail or on C<irc.perl.org> (vincent).
 401
 402 =head1 BUGS
 403
 404 Please report any bugs or feature requests to C<bug-scope-upper at rt.cpan.org>, or through the web interface at L<http://rt.cpan.org/NoAuth/ReportBug.html?Queue=Scope-Upper>.
 405 I will be notified, and then you'll automatically be notified of progress on your bug as I make changes.
 406
 407 =head1 SUPPORT
 408
 409 You can find documentation for this module with the perldoc command.
 410
 411     perldoc Scope::Upper
 412
 413 Tests code coverage report is available at L<http://www.profvince.com/perl/cover/Scope-Upper>.
 414
 415 =head1 ACKNOWLEDGEMENTS
 416
 417 Inspired by Ricardo Signes.
 418
 419 Thanks to Shawn M. Moore for motivation.
 420
 421 =head1 COPYRIGHT & LICENSE
 422
 423 Copyright 2008,2009,2010 Vincent Pit, all rights reserved.
 424
 425 This program is free software; you can redistribute it and/or modify it under the same terms as Perl itself.
 426
 427 =cut
 428
 429 1; # End of Scope::Upper