lib/Scope/Upper.pm

   1 package Scope::Upper;
   2
   3 use strict;
   4 use warnings;
   5
   6 =head1 NAME
   7
   8 Scope::Upper - Act on upper scopes.
   9
  10 =head1 VERSION
  11
  12 Version 0.04
  13
  14 =cut
  15
  16 our $VERSION;
  17 BEGIN {
  18  $VERSION = '0.04';
  19 }
  20
  21 =head1 SYNOPSIS
  22
  23     package X;
  24
  25     use Scope::Upper qw/reap localize localize_elem localize_delete/;
  26
  27     sub desc { shift->{desc} }
  28
  29     sub set_tag {
  30      my ($desc) = @_;
  31
  32      # First localize $x so that it gets destroyed last
  33      localize '$x' => bless({ desc => $desc }, __PACKAGE__) => 1;
  34
  35      reap sub {
  36       my $pkg = caller;
  37       my $x = do { no strict 'refs'; ${$pkg.'::x'} }; # Get the $x in the scope
  38       print $x->desc . ": done\n";
  39      } => 1;
  40
  41      localize_elem '%SIG', '__WARN__' => sub {
  42       my $pkg = caller;
  43       my $x = do { no strict 'refs'; ${$pkg.'::x'} }; # Get the $x in the scope
  44       CORE::warn($x->desc . ': ' . join('', @_));
  45      } => 1;
  46
  47      localize_delete '@ARGV', $#ARGV => 1; # delete last @ARGV element
  48     }
  49
  50     package Y;
  51
  52     {
  53      X::set_tag('pie');
  54      # $x is now a X object, and @ARGV has one element less
  55      warn 'what'; # warns "pie: what at ..."
  56      ...
  57     } # "pie: done" is printed
  58
  59     package Z;
  60
  61     use Scope::Upper qw/unwind want_at :words/;
  62
  63     sub try (&) {
  64      my @result = shift->();
  65      my $cx = SUB UP SUB;
  66      unwind +(want_at($cx) ? @result : scalar @result) => $cx;
  67     }
  68
  69     ...
  70
  71     sub zap {
  72      try {
  73       return @things; # returns to try() and then outside zap()
  74      }
  75     }
  76
  77     my @what = zap(); # @what contains @things
  78
  79 =head1 DESCRIPTION
  80
  81 This module lets you defer actions that will take place when the control flow returns into an upper scope.
  82 Currently, you can hook an upper scope end, or localize variables, array/hash values or deletions of elements in higher contexts.
  83 You can also return to an upper level and know which context was in use then.
  84
  85 =head1 FUNCTIONS
  86
  87 =cut
  88
  89 BEGIN {
  90  require XSLoader;
  91  XSLoader::load(__PACKAGE__, $VERSION);
  92 }
  93
  94 =head2 C<reap $callback, $level>
  95
  96 Add a destructor that calls C<$callback> when the C<$level>-th upper scope ends, where C<0> corresponds to the current scope.
  97
  98 =head2 C<localize $what, $value, $level>
  99
 100 A C<local> delayed to the time of first return into the C<$level>-th upper scope.
 101 C<$what> can be :
 102
 103 =over 4
 104
 105 =item *
 106
 107 A glob, in which case C<$value> can either be a glob or a reference.
 108 L</localize> follows then the same syntax as C<local *x = $value>.
 109 For example, if C<$value> is a scalar reference, then the C<SCALAR> slot of the glob will be set to C<$$value> - just like C<local *x = \1> sets C<$x> to C<1>.
 110
 111 =item *
 112
 113 A string beginning with a sigil, representing the symbol to localize and to assign to.
 114 If the sigil is C<'$'>, L</localize> follows the same syntax as C<local $x = $value>, i.e. C<$value> isn't dereferenced.
 115 For example,
 116
 117     localize '$x', \'foo' => 0;
 118
 119 will set C<$x> to a reference to the string C<'foo'>.
 120 Other sigils (C<'@'>, C<'%'>, C<'&'> and C<'*'>) require C<$value> to be a reference of the corresponding type.
 121
 122 When the symbol is given by a string, it is resolved when the actual localization takes place and not when C<localize> is called.
 123 This means that
 124
 125     sub tag { localize '$x', $_[0] => 1; }
 126
 127 will localize in the caller's namespace.
 128
 129 =back
 130
 131 =head2 C<localize_elem $what, $key, $value, $level>
 132
 133 Similar to L</localize> but for array and hash elements.
 134 If C<$what> is a glob, the slot to fill is determined from which type of reference C<$value> is ; otherwise it's inferred from the sigil.
 135 C<$key> is either an array index or a hash key, depending of which kind of variable you localize.
 136
 137 =head2 C<localize_delete $what, $key, $level>
 138
 139 Similiar to L</localize>, but for deleting variables or array/hash elements.
 140 C<$what> can be:
 141
 142 =over 4
 143
 144 =item *
 145
 146 A glob, in which case C<$key> is ignored and the call is equivalent to C<local *x>.
 147
 148 =item *
 149
 150 A string beginning with C<'@'> or C<'%'>, for which the call is equivalent to respectiveley C<local $a[$key]; delete $a[$key]> and C<local $h{$key}; delete $h{$key}>.
 151
 152 =item *
 153
 154 A string beginning with C<'&'>, which more or less does C<undef &func> in the upper scope.
 155 It's actually more powerful, as C<&func> won't even C<exists> anymore.
 156 C<$key> is ignored.
 157
 158 =back
 159
 160 =head2 C<unwind @values, $level>
 161
 162 Returns C<@values> I<from> the context indicated by C<$level>, i.e. from the subroutine, eval or format just above C<$level>.
 163
 164 The upper level isn't coerced onto C<@values>, which is hence always evaluated in list context.
 165 This means that
 166
 167     my $num = sub {
 168      my @a = ('a' .. 'z');
 169      unwind @a => 0;
 170     }->();
 171
 172 will set C<$num> to C<'z'>.
 173 You can use L</want_at> to handle these cases.
 174
 175 =head2 C<want_at $level>
 176
 177 Like C<wantarray>, but for the subroutine/eval/format context just above C<$level>.
 178
 179 The previous example can then be "corrected" :
 180
 181     my $num = sub {
 182      my @a = ('a' .. 'z');
 183      unwind +(want_at(0) ? @a : scalar @a) => 0;
 184     }->();
 185
 186 will righteously set C<$num> to C<26>.
 187
 188 =head1 WORDS
 189
 190 =head2 C<TOP>
 191
 192 Returns the level that currently represents the highest scope.
 193
 194 =head2 C<HERE>
 195
 196 The current level - i.e. C<0>.
 197
 198 =head2 C<UP $from>
 199
 200 The level of the scope just above C<$from>.
 201
 202 =head2 C<DOWN $from>
 203
 204 The level of the scope just below C<$from>.
 205
 206 =head2 C<SUB $from>
 207
 208 The level of the closest subroutine context above C<$from>.
 209
 210 =head2 C<EVAL $from>
 211
 212 The level of the closest eval context above C<$from>.
 213
 214 If C<$from> is omitted in any of those functions, the current level is used as the reference level.
 215
 216 =head2 C<CALLER $stack>
 217
 218 The level of the C<$stack>-th upper subroutine/eval/format context.
 219 It kind of corresponds to the context represented by C<caller $stack>, but while e.g. C<caller 0> refers to the caller context, C<CALLER 0> will refer to the top scope in the current context.
 220 For example,
 221
 222     reap ... => CALLER(0)
 223
 224 will fire the destructor when the current subroutine/eval/format ends.
 225
 226 =head1 EXPORT
 227
 228 The functions L</reap>, L</localize>, L</localize_elem>, L</localize_delete>,  L</unwind> and L</want_at> are only exported on request, either individually or by the tags C<':funcs'> and C<':all'>.
 229
 230 Same goes for the words L</TOP>, L</HERE>, L</UP>, L</DOWN>, L</SUB>, L</EVAL> and L</CALLER> that are only exported on request, individually or by the tags C<':words'> and C<':all'>.
 231
 232 =cut
 233
 234 use base qw/Exporter/;
 235
 236 our @EXPORT      = ();
 237 our %EXPORT_TAGS = (
 238  funcs => [ qw/reap localize localize_elem localize_delete unwind want_at/ ],
 239  words => [ qw/TOP HERE UP DOWN SUB EVAL CALLER/ ],
 240 );
 241 our @EXPORT_OK   = map { @$_ } values %EXPORT_TAGS;
 242 $EXPORT_TAGS{'all'} = [ @EXPORT_OK ];
 243
 244 =head1 CAVEATS
 245
 246 Be careful that local variables are restored in the reverse order in which they were localized.
 247 Consider those examples:
 248
 249     local $x = 0;
 250     {
 251      reap sub { print $x } => 0;
 252      local $x = 1;
 253      ...
 254     }
 255     # prints '0'
 256     ...
 257     {
 258      local $x = 1;
 259      reap sub { $x = 2 } => 0;
 260      ...
 261     }
 262     # $x is 0
 263
 264 The first case is "solved" by moving the C<local> before the C<reap>, and the second by using L</localize> instead of L</reap>.
 265
 266 L</reap>, L</localize> and L</localize_elem> effects can't cross C<BEGIN> blocks, hence calling those functions in C<import> is deemed to be useless.
 267 This is an hopeless case because C<BEGIN> blocks are executed once while localizing constructs should do their job at each run.
 268
 269 =head1 DEPENDENCIES
 270
 271 L<XSLoader> (standard since perl 5.006).
 272
 273 =head1 SEE ALSO
 274
 275 L<Alias>, L<Hook::Scope>, L<Scope::Guard>, L<Guard>.
 276
 277 =head1 AUTHOR
 278
 279 Vincent Pit, C<< <perl at profvince.com> >>, L<http://www.profvince.com>.
 280
 281 You can contact me by mail or on C<irc.perl.org> (vincent).
 282
 283 =head1 BUGS
 284
 285 Please report any bugs or feature requests to C<bug-scope-upper at rt.cpan.org>, or through the web interface at L<http://rt.cpan.org/NoAuth/ReportBug.html?Queue=Scope-Upper>.  I will be notified, and then you'll automatically be notified of progress on your bug as I make changes.
 286
 287 =head1 SUPPORT
 288
 289 You can find documentation for this module with the perldoc command.
 290
 291     perldoc Scope::Upper
 292
 293 Tests code coverage report is available at L<http://www.profvince.com/perl/cover/Scope-Upper>.
 294
 295 =head1 ACKNOWLEDGEMENTS
 296
 297 Inspired by Ricardo Signes.
 298
 299 =head1 COPYRIGHT & LICENSE
 300
 301 Copyright 2008-2009 Vincent Pit, all rights reserved.
 302
 303 This program is free software; you can redistribute it and/or modify it under the same terms as Perl itself.
 304
 305 =cut
 306
 307 1; # End of Scope::Upper