t/50-vrot.t

   1 #!perl -T
   2
   3 use strict;
   4 use warnings;
   5
   6 use Test::More 'no_plan';
   7
   8 use Scalar::Vec::Util qw/vrot vcopy SVU_SIZE/;
   9
  10 my $p = SVU_SIZE;
  11 $p = 8 if $p < 8;
  12 my $n = 3 * $p;
  13 my $q = 2;
  14
  15 *myfill = *Scalar::Vec::Util::vfill_pp;
  16 *myeq   = *Scalar::Vec::Util::veq_pp;
  17
  18 sub rst { myfill($_[0], 0, $n, 0); $_[0] = '' }
  19
  20 sub pat {
  21  (undef, my $a, my $b, my $c, my $x) = @_;
  22  $_[0] = '';
  23  myfill($_[0], 0,            $a,                  $x);
  24  myfill($_[0], $a,           $b,                  1 - $x);
  25  myfill($_[0], $a + $b,      $c,                  $x);
  26  myfill($_[0], $a + $b + $c, $n - ($a + $b + $c), 1 - $x);
  27 }
  28
  29 sub expected {
  30  (undef, my $s, my $l, my $b, my $left) = @_;
  31  my $lx = int($l / 2);
  32  my $ly = $l - $lx;
  33  $b %= $l;
  34  $_[0] = '';
  35  myfill($_[0], 0, $s, 0);
  36  if ($left) {
  37   if ($b <= $ly) {
  38    myfill($_[0], $s,            $b,            0);
  39    myfill($_[0], $s + $b,       $lx,           1);
  40    myfill($_[0], $s + $b + $lx, $l - $lx - $b, 0);
  41   } else {
  42    myfill($_[0], $s,            $b - $ly, 1);
  43    myfill($_[0], $s + $b - $ly, $ly,      0);
  44    myfill($_[0], $s + $b,       $l - $b,  1);
  45   }
  46  } else {
  47   if ($b <= $lx) {
  48    myfill($_[0], $s,            $lx - $b, 1);
  49    myfill($_[0], $s + $lx - $b, $l - $lx, 0);
  50    myfill($_[0], $s + $l  - $b, $b,       1);
  51   } else {
  52    myfill($_[0], $s,                 $ly - ($b - $lx), 0);
  53    myfill($_[0], $s + $l - $b,       $lx,              1);
  54    myfill($_[0], $s + $l + $lx - $b, $b - $lx,         0);
  55   }
  56  }
  57  myfill($_[0], $s + $l, $n - $s - $l, 1);
  58 }
  59
  60 sub prnt {
  61  (undef, my $n, my $desc) = @_;
  62  my $i = 0;
  63  my $s;
  64  $s .= vec($_[0], $i++, 1) while $i < $n;
  65  diag "$desc: $s";
  66 }
  67
  68 my ($v, $v0, $c) = ('', '') x 2;
  69
  70 sub try {
  71  my ($left) = @_;
  72  my @s = ($p - $q) .. ($p + $q);
  73  for my $s (@s) {
  74   for my $l (1 .. $n - 1) {
  75    last if $s + $l > $n;
  76    my $l2 = int($l/2);
  77    rst $v0;
  78    pat $v0, $s, $l2, $l - $l2, 0;
  79    my @b = (0, 3, 5, 7, 11, 13, 17, $l2, $l2 + 1, $l + 1);
  80    @b = do { my %seen; ++$seen{$_} for @b; sort keys %seen };
  81    for my $b (@b) {
  82     $v = $v0;
  83     expected $c, $s, $l, $b, $left;
  84     $b = -$b unless $left;
  85     vrot $v, $s, $l, $b;
  86     ok(myeq($v, 0, $c, 0, $n), "vrot $s, $l, $b") or do {
  87      diag "n = $n, s = $s, l = $l, l2 = $l2";
  88      prnt $v0, $n, 'original';
  89      prnt $v, $n,  'got     ';
  90      prnt $c, $n,  'expected';
  91     };
  92     is(length $v, length $c, "vrot $s, $l, $b length");
  93    }
  94   }
  95  }
  96 }
  97
  98 try 1;
  99 try 0;