t/50-vrot.t

   1 #!perl -T
   2
   3 use strict;
   4 use warnings;
   5
   6 use Test::More 'no_plan';
   7
   8 use Scalar::Vec::Util qw/vrot vcopy SVU_SIZE/;
   9
  10 for ([ 1, 'offset', -1 ], [ 2, 'length', '-1' ]) {
  11  my @args  = ('1') x 4;
  12  $args[$_->[0]] = $_->[2];
  13  eval { &vrot(@args) }; my $line = __LINE__;
  14  like $@, qr/^Invalid\s+negative\s+$_->[1]\s+at\s+\Q$0\E\s+line\s+$line/;
  15 }
  16
  17 my $p = SVU_SIZE;
  18 $p = 8 if $p < 8;
  19 my $n = 3 * $p;
  20 my $q = 2;
  21
  22 *myfill = *Scalar::Vec::Util::vfill_pp;
  23 *myeq   = *Scalar::Vec::Util::veq_pp;
  24
  25 sub rst { myfill($_[0], 0, $n, 0); $_[0] = '' }
  26
  27 sub pat {
  28  (undef, my $a, my $b, my $c, my $x) = @_;
  29  $_[0] = '';
  30  myfill($_[0], 0,            $a,                  $x);
  31  myfill($_[0], $a,           $b,                  1 - $x);
  32  myfill($_[0], $a + $b,      $c,                  $x);
  33  myfill($_[0], $a + $b + $c, $n - ($a + $b + $c), 1 - $x);
  34 }
  35
  36 sub expected {
  37  (undef, my $s, my $l, my $b, my $left) = @_;
  38  unless ($l) {
  39   myfill($_[0], 0,  $s,      0);
  40   myfill($_[0], $s, $n - $s, 1);
  41   return;
  42  }
  43  my $lx = int($l / 2);
  44  my $ly = $l - $lx;
  45  $b %= $l;
  46  $_[0] = '';
  47  myfill($_[0], 0, $s, 0);
  48  if ($left) {
  49   if ($b <= $ly) {
  50    myfill($_[0], $s,            $b,            0);
  51    myfill($_[0], $s + $b,       $lx,           1);
  52    myfill($_[0], $s + $b + $lx, $l - $lx - $b, 0);
  53   } else {
  54    myfill($_[0], $s,            $b - $ly, 1);
  55    myfill($_[0], $s + $b - $ly, $ly,      0);
  56    myfill($_[0], $s + $b,       $l - $b,  1);
  57   }
  58  } else {
  59   if ($b <= $lx) {
  60    myfill($_[0], $s,            $lx - $b, 1);
  61    myfill($_[0], $s + $lx - $b, $l - $lx, 0);
  62    myfill($_[0], $s + $l  - $b, $b,       1);
  63   } else {
  64    myfill($_[0], $s,                 $ly - ($b - $lx), 0);
  65    myfill($_[0], $s + $l - $b,       $lx,              1);
  66    myfill($_[0], $s + $l + $lx - $b, $b - $lx,         0);
  67   }
  68  }
  69  myfill($_[0], $s + $l, $n - $s - $l, 1);
  70 }
  71
  72 sub prnt {
  73  (undef, my $n, my $desc) = @_;
  74  my $i = 0;
  75  my $s;
  76  $s .= vec($_[0], $i++, 1) while $i < $n;
  77  diag "$desc: $s";
  78 }
  79
  80 my ($v, $v0, $c) = ('', '') x 2;
  81
  82 sub try {
  83  my ($left) = @_;
  84  my @s = ($p - $q) .. ($p + $q);
  85  for my $s (@s) {
  86   for my $l (0 .. $n - 1) {
  87    last if $s + $l > $n;
  88    my $l2 = int($l/2);
  89    rst $v0;
  90    pat $v0, $s, $l2, $l - $l2, 0;
  91    my @b = (0, 3, 5, 7, 11, 13, 17, $l2, $l2 + 1, $l + 1);
  92    @b = do { my %seen; ++$seen{$_} for @b; sort keys %seen };
  93    for my $b (@b) {
  94     $v = $v0;
  95     expected $c, $s, $l, $b, $left;
  96     $b = -$b unless $left;
  97     vrot $v, $s, $l, $b;
  98     ok(myeq($v, 0, $c, 0, $n), "vrot $s, $l, $b") or do {
  99      diag "n = $n, s = $s, l = $l, l2 = $l2";
 100      prnt $v0, $n, 'original';
 101      prnt $v, $n,  'got     ';
 102      prnt $c, $n,  'expected';
 103     };
 104     is(length $v, length $c, "vrot $s, $l, $b length");
 105    }
 106   }
 107  }
 108 }
 109
 110 try 1;
 111 try 0;