t/40-vshift.t

   1 #!perl -T
   2
   3 use strict;
   4 use warnings;
   5
   6 use Test::More 'no_plan';
   7
   8 use Scalar::Vec::Util qw/vshift SVU_SIZE/;
   9
  10 for ([ 1, 'offset', -1 ], [ 2, 'length', '-1' ]) {
  11  my @args  = ('1') x 4;
  12  $args[$_->[0]] = $_->[2];
  13  eval { &vshift(@args) }; my $line = __LINE__;
  14  like $@, qr/^Invalid\s+negative\s+$_->[1]\s+at\s+\Q$0\E\s+line\s+$line/;
  15 }
  16
  17 my $p = SVU_SIZE;
  18 $p = 8 if $p < 8;
  19 my $n = 3 * $p;
  20 my $q = 2;
  21
  22 *myfill = *Scalar::Vec::Util::vfill_pp;
  23 *myeq   = *Scalar::Vec::Util::veq_pp;
  24
  25 sub rst { myfill($_[0], 0, $n, 0); $_[0] = '' }
  26
  27 sub pat {
  28  (undef, my $a, my $b, my $x) = @_;
  29  $_[0] = '';
  30  $x = $x ? 1 : 0;
  31  if (defined $b) {
  32   myfill($_[0], 0, $a, $x);
  33   myfill($_[0], $a, $b, 1 - $x);
  34  }
  35 }
  36
  37 sub expect {
  38  (undef, my $s, my $l, my $b, my $left, my $insert) = @_;
  39  myfill($_[0], 0, $s, 0);
  40  if ($b < $l) {
  41   if ($left) {
  42    myfill($_[0], $s,      $b,      defined $insert ? $insert : 1);
  43    myfill($_[0], $s + $b, $l - $b, 1);
  44   } else {
  45    myfill($_[0], $s,           $l - $b, 1);
  46    myfill($_[0], $s + $l - $b, $b,      defined $insert ? $insert : 1);
  47   }
  48  } else {
  49   myfill($_[0], $s, $l, defined $insert ? $insert : 1);
  50  }
  51 }
  52
  53 my ($v, $v0, $c) = ('', '') x 2;
  54
  55 sub try {
  56  my ($left, $insert) = @_;
  57  my @s = ($p - $q) .. ($p + $q);
  58  for my $s (@s) {
  59   for my $l (0 .. $n - 1) {
  60    last if $s + $l > $n;
  61    rst $v0;
  62    pat $v0, $s, $l, 0;
  63    my @b = (0);
  64    my $l2 = int($l/2);
  65    push @b, $l2 if $l2 != $l;
  66    push @b, $l + 1;
  67    for my $b (@b) {
  68     $v = $v0;
  69     rst $c;
  70     expect $c, $s, $l, $b, $left, $insert;
  71     $b = -$b unless $left;
  72     vshift $v, $s, $l => $b, $insert;
  73     my $i = defined $insert ? $insert : 'undef';
  74     ok(myeq($v, 0, $c, 0, $n), "vshift $s, $l, $b, $i");
  75     is(length $v, length $c, "vshift $s, $l, $b, $i length");
  76    }
  77   }
  78  }
  79 }
  80
  81 try 1;
  82 try 1, 0;
  83 try 1, 1;
  84 try 0;
  85 try 0, 0;
  86 try 0, 1;