Makefile.PL

   1 use 5.006;
   2
   3 use strict;
   4 use warnings;
   5 use ExtUtils::MakeMaker;
   6
   7 use Config;
   8 use File::Spec;
   9
  10 sub validate_exe {
  11  my ($name, $preferred_path) = @_;
  12
  13  my (@candidates, @args);
  14  if (File::Spec->file_name_is_absolute($name)) {
  15   # No need to look for args if the name is absolute.
  16   @candidates = $name;
  17  } else {
  18   my @path;
  19   if (defined $preferred_path) {
  20    @path = ($preferred_path, grep { $_ ne $preferred_path } File::Spec->path);
  21   } else {
  22    @path = File::Spec->path;
  23   }
  24
  25   (my $base, @args) = split ' ', $name;
  26   for my $path_entry (@path) {
  27    my ($vol, $dir, $file) = File::Spec->splitpath($path_entry, 1);
  28    next if defined $file and length $file;
  29    push @candidates, File::Spec->catpath($vol, $dir, $base);
  30   }
  31  }
  32
  33  for my $path (@candidates) {
  34   my $command = MM->maybe_command($path);
  35   if (defined $command) {
  36    $command .= " @args" if @args;
  37    return $command;
  38   }
  39  }
  40
  41  return;
  42 }
  43
  44 sub check_exe {
  45  my ($desc, $arg_var, $config_var, $env_var, $preferred_path) = @_;
  46
  47  my $exe;
  48
  49  for (@ARGV) {
  50   if (/^\Q$arg_var\E=(.*)/) {
  51    $exe = validate_exe($1, $preferred_path);
  52    last if defined $exe;
  53   }
  54  }
  55
  56  if (defined $exe) {
  57   print "Forcing the use of $exe as the $desc.\n";
  58  } else {
  59   print "Checking for a valid $desc in the PATH... ";
  60   $exe = validate_exe($Config{$config_var}, $preferred_path);
  61   # Only fall back to env if we cannot find the one used to build perl.
  62   if (not defined $exe and defined $ENV{$env_var}) {
  63    $exe = validate_exe($ENV{$env_var}, $preferred_path);
  64   }
  65   if (defined $exe) {
  66    print "$exe\n";
  67   } else {
  68    print "none\n";
  69   }
  70  }
  71
  72  return $exe;
  73 }
  74
  75 my $pp;
  76 for my $i (0 .. $#ARGV) {
  77  my $arg = $ARGV[$i];
  78  if ($arg =~ /^PP=(.*)/) {
  79   my $val = $1;
  80   if (do { no warnings 'numeric'; int $val } or $val =~ /^(?:y|yes)$/i) {
  81    print "Forcing the pure-Perl implementation from the arguments passed to Makefile.PL.\n";
  82    $pp = 1;
  83    last;
  84   }
  85   $ARGV[$i] = undef;
  86  }
  87 }
  88
  89 @ARGV = grep defined, @ARGV;
  90
  91 my ($cc, $ld);
  92 unless ($pp) {
  93  $cc = check_exe('C compiler', 'CC', 'cc', 'CC');
  94  if (defined $cc) {
  95   my ($vol, $dir, $file) = File::Spec->splitpath($cc);
  96   my $preferred_path = File::Spec->catpath($vol, $dir, '');
  97   $ld = check_exe('linker', 'LD', 'ld', 'LD', $preferred_path);
  98  }
  99 }
 100
 101 sub is_little_endian {
 102  my $order = $Config{byteorder};
 103  return 0 unless $order;
 104  my $len = length $order;
 105  if ($len > 8) {
 106   $order = substr $order, 0, 8;
 107   $len   = 8;
 108  }
 109  return $order eq (join '', 1 .. $len);
 110 }
 111
 112 my %PARAMS;
 113 my @DEFINES;
 114
 115 if (defined $cc and defined $ld) {
 116  $PARAMS{C}  = [ 'Util.c' ];
 117  $PARAMS{XS} = { 'Util.xs' => 'Util.c' };
 118  $PARAMS{CC} = $cc;
 119  $PARAMS{LD} = $ld;
 120
 121  my $bits = 8;
 122  if (not is_little_endian()) {
 123   print "Forcing unit size of 8 on non-little-endian systems.\n";
 124  } else {
 125   print "Checking unit size in bits... ";
 126   my $size  = 1;
 127   my $align = $Config{alignbytes} || 1;
 128   my @units = (8, 16, 32, 64);
 129   for my $unit (@units) {
 130    my $unit_size = $Config{"u${unit}size"};
 131    if ($unit_size and $unit_size <= $align) {
 132     $bits = $unit;
 133     $size = $unit_size;
 134    }
 135   }
 136   print "$bits (actually $size bytes for $align bytes alignment).\n";
 137  }
 138  push @DEFINES, '-DBV_UNIT="' . ($Config{"u${bits}type"} || "U$bits") . '"';
 139  push @DEFINES, "-DSVU_SIZE=$bits";
 140 } else {
 141  $PARAMS{C}      = [ ];
 142  $PARAMS{XS}     = { };
 143  $PARAMS{OBJECT} = '';
 144  print "Falling back to the pure-Perl implementation.\n";
 145 }
 146
 147 $PARAMS{DEFINE} = join ' ', @DEFINES if @DEFINES;
 148
 149 my $dist = 'Scalar-Vec-Util';
 150
 151 (my $name = $dist) =~ s{-}{::}g;
 152
 153 (my $file = $dist) =~ s{-}{/}g;
 154 $file = "lib/$file.pm";
 155
 156 my %PREREQ_PM = (
 157  'Exporter' => 0,
 158  'Carp'     => 0,
 159  'XSLoader' => 0,
 160  'base'     => 0,
 161 );
 162
 163 my %BUILD_REQUIRES = (
 164  'Config'              => 0,
 165  'ExtUtils::MakeMaker' => 0,
 166  'File::Spec'          => 0,
 167  'Test::More'          => 0,
 168  %PREREQ_PM,
 169 );
 170
 171 my %META = (
 172  configure_requires => {
 173   'Config'              => 0,
 174   'ExtUtils::MakeMaker' => 0,
 175   'File::Spec'          => 0,
 176  },
 177  build_requires => {
 178   %BUILD_REQUIRES,
 179  },
 180  dynamic_config => 1,
 181  resources => {
 182   bugtracker => "http://rt.cpan.org/Dist/Display.html?Name=$dist",
 183   homepage   => "http://search.cpan.org/dist/$dist/",
 184   license    => 'http://dev.perl.org/licenses/',
 185   repository => "http://git.profvince.com/?p=perl%2Fmodules%2F$dist.git",
 186  },
 187 );
 188
 189 WriteMakefile(
 190  NAME             => $name,
 191  AUTHOR           => 'Vincent Pit <perl@profvince.com>',
 192  LICENSE          => 'perl',
 193  VERSION_FROM     => $file,
 194  ABSTRACT_FROM    => $file,
 195  PL_FILES         => {},
 196  BUILD_REQUIRES   => \%BUILD_REQUIRES,
 197  PREREQ_PM        => \%PREREQ_PM,
 198  MIN_PERL_VERSION => '5.006',
 199  META_MERGE       => \%META,
 200  dist             => {
 201   PREOP    => "pod2text -u $file > \$(DISTVNAME)/README",
 202   COMPRESS => 'gzip -9f', SUFFIX => 'gz'
 203  },
 204  clean            => {
 205   FILES => "$dist-* *.gcov *.gcda *.gcno cover_db Debian_CPANTS.txt*"
 206  },
 207  %PARAMS,
 208 );
 209
 210 1;
 211
 212 package MY;
 213
 214 sub postamble {
 215  my $cv = join ' -coverage ', 'cover',
 216                             qw<statement branch condition path subroutine time>;
 217  <<POSTAMBLE;
 218 cover test_cover:
 219         $cv -test
 220 POSTAMBLE
 221 }