t/31-threads-teardown.t

   1 #!perl
   2
   3 use strict;
   4 use warnings;
   5
   6 use Config qw/%Config/;
   7
   8 BEGIN {
   9  if (!$Config{useithreads}) {
  10   require Test::More;
  11   Test::More->import;
  12   plan(skip_all => 'This perl wasn\'t built to support threads');
  13  }
  14 }
  15
  16 use threads;
  17
  18 use Test::More;
  19
  20 BEGIN {
  21  require Lexical::Types;
  22  if (Lexical::Types::LT_THREADSAFE()) {
  23   plan tests => 1;
  24   defined and diag "Using threads $_" for $threads::VERSION;
  25  } else {
  26   plan skip_all => 'This Lexical::Types isn\'t thread safe';
  27  }
  28 }
  29
  30 sub run_perl {
  31  my $code = shift;
  32
  33  local %ENV;
  34  system { $^X } $^X, '-T', map("-I$_", @INC), '-e', $code;
  35 }
  36
  37 SKIP:
  38 {
  39  skip 'Fails on 5.8.2 and lower' => 1 if $] <= 5.008002;
  40
  41  my $status = run_perl <<' RUN';
  42   { package IntX; package IntY; package IntZ; }
  43   my ($code, @expected);
  44   sub cb {
  45    my $e = shift(@expected) || q{DUMMY};
  46    --$code if $_[0] eq $e;
  47    ()
  48   }
  49   use threads;
  50   $code = threads->create(sub {
  51    $code = @expected = qw/IntX/;
  52    eval q{use Lexical::Types as => \&cb; my IntX $x;}; die if $@;
  53    return $code;
  54   })->join;
  55   $code += @expected = qw/IntZ/;
  56   eval q{my IntY $y;}; die if $@;
  57   eval q{use Lexical::Types as => \&cb; my IntZ $z;}; die if $@;
  58   $code += 256 if $code < 0;
  59   exit $code;
  60  RUN
  61  is $status, 0, 'loading the pragma in a thread and using it outside doesn\'t segfault';
  62 }