lib/LaTeX/TikZ/Set/Sequence.pm

   1 package LaTeX::TikZ::Set::Sequence;
   2
   3 use strict;
   4 use warnings;
   5
   6 =head1 NAME
   7
   8 LaTeX::TikZ::Set::Sequence - A set object grouping a sequence of objects.
   9
  10 =head1 VERSION
  11
  12 Version 0.01
  13
  14 =cut
  15
  16 our $VERSION = '0.01';
  17
  18 use List::Util ();
  19
  20 use LaTeX::TikZ::Scope;
  21
  22 use Any::Moose;
  23 use Any::Moose 'Util::TypeConstraints'
  24                => [ qw/subtype as where find_type_constraint/ ];
  25
  26 with qw(
  27  LaTeX::TikZ::Set
  28  LaTeX::TikZ::Set::Mutable
  29 );
  30
  31 subtype 'LaTeX::TikZ::Set::Sequence::Elements'
  32      => as 'Object'
  33      => where {
  34              $_->does('LaTeX::TikZ::Set::Op')
  35           or $_->isa('LaTeX::TikZ::Set::Sequence')
  36      };
  37
  38 has '_kids' => (
  39  is       => 'ro',
  40  isa      => 'Maybe[ArrayRef[LaTeX::TikZ::Set::Sequence::Elements]]',
  41  init_arg => 'kids',
  42  default  => sub { [ ] },
  43 );
  44
  45 sub kids { @{$_[0]->_kids} }
  46
  47 my $ltsse_tc = find_type_constraint('LaTeX::TikZ::Set::Sequence::Elements');
  48
  49 sub add {
  50  my $set = shift;
  51
  52  $ltsse_tc->assert_valid($_) for @_;
  53
  54  push @{$set->_kids}, @_;
  55
  56  $set;
  57 }
  58
  59 sub draw {
  60  my $set = shift;
  61
  62  List::Util::reduce { LaTeX::TikZ::Scope::fold($a, $b) }
  63   map $_->draw(@_),
  64    $set->kids;
  65 }
  66
  67 use LaTeX::TikZ::Interface seq => sub {
  68  shift;
  69
  70  __PACKAGE__->new(kids => \@_);
  71 };
  72
  73 __PACKAGE__->meta->make_immutable;
  74
  75 =head1 AUTHOR
  76
  77 Vincent Pit, C<< <perl at profvince.com> >>, L<http://www.profvince.com>.
  78
  79 You can contact me by mail or on C<irc.perl.org> (vincent).
  80
  81 =head1 BUGS
  82
  83 Please report any bugs or feature requests to C<bug-latex-tikz at rt.cpan.org>, or through the web interface at L<http://rt.cpan.org/NoAuth/ReportBug.html?Queue=LaTeX-TikZ>.
  84 I will be notified, and then you'll automatically be notified of progress on your bug as I make changes.
  85
  86 =head1 SUPPORT
  87
  88 You can find documentation for this module with the perldoc command.
  89
  90     perldoc LaTeX::TikZ
  91
  92 =head1 COPYRIGHT & LICENSE
  93
  94 Copyright 2010 Vincent Pit, all rights reserved.
  95
  96 This program is free software; you can redistribute it and/or modify it under the same terms as Perl itself.
  97
  98 =cut
  99
 100 1; # End of LaTeX::TikZ::Set::Sequence