lib/LaTeX/TikZ/Set/Sequence.pm

   1 package LaTeX::TikZ::Set::Sequence;
   2
   3 use strict;
   4 use warnings;
   5
   6 =head1 NAME
   7
   8 LaTeX::TikZ::Set::Sequence - A set object grouping a sequence of objects.
   9
  10 =head1 VERSION
  11
  12 Version 0.02
  13
  14 =cut
  15
  16 our $VERSION = '0.02';
  17
  18 use List::Util ();
  19
  20 use LaTeX::TikZ::Scope;
  21
  22 use LaTeX::TikZ::Interface;
  23 use LaTeX::TikZ::Functor;
  24
  25 use Any::Moose;
  26 use Any::Moose 'Util::TypeConstraints'
  27                => [ qw<subtype as where find_type_constraint> ];
  28
  29 =head1 RELATIONSHIPS
  30
  31 This class consumes the L<LaTeX::TikZ::Set> and L<LaTeX::TikZ::Set::Mutable> roles, and as such implements the L</draw> and L</add> methods.
  32
  33 =cut
  34
  35 with qw<
  36  LaTeX::TikZ::Set
  37  LaTeX::TikZ::Set::Mutable
  38 >;
  39
  40 subtype 'LaTeX::TikZ::Set::Sequence::Elements'
  41      => as 'Object'
  42      => where {
  43              $_->does('LaTeX::TikZ::Set::Path')
  44           or $_->isa('LaTeX::TikZ::Set::Sequence')
  45      };
  46
  47 =head1 ATTRIBUTES
  48
  49 =head2 C<kids>
  50
  51 The L<LaTeX::TikZ::Set::Path> or L<LaTeX::TikZ::Set::Sequence> objects that from the sequence.
  52
  53 =cut
  54
  55 has '_kids' => (
  56  is       => 'ro',
  57  isa      => 'Maybe[ArrayRef[LaTeX::TikZ::Set::Sequence::Elements]]',
  58  init_arg => 'kids',
  59  default  => sub { [ ] },
  60 );
  61
  62 sub kids { @{$_[0]->_kids} }
  63
  64 =head1 METHODS
  65
  66 =head2 C<add>
  67
  68 =cut
  69
  70 my $ltsse_tc = find_type_constraint('LaTeX::TikZ::Set::Sequence::Elements');
  71
  72 sub add {
  73  my $set = shift;
  74
  75  $ltsse_tc->assert_valid($_) for @_;
  76
  77  push @{$set->_kids}, @_;
  78
  79  $set;
  80 }
  81
  82 =head2 C<draw>
  83
  84 =cut
  85
  86 sub draw {
  87  my $set = shift;
  88
  89  my @kids = $set->kids;
  90  return [ ] unless @kids;
  91
  92  List::Util::reduce { LaTeX::TikZ::Scope::fold($a, $b) }
  93   map $_->draw(@_),
  94    @kids;
  95 }
  96
  97 LaTeX::TikZ::Interface->register(
  98  seq => sub {
  99   shift;
 100
 101   __PACKAGE__->new(kids => \@_);
 102  },
 103 );
 104
 105 LaTeX::TikZ::Functor->default_rule(
 106  (__PACKAGE__) => sub {
 107   my ($functor, $set, @args) = @_;
 108   $set->new(kids => [ map $_->$functor(@args), $set->kids ])
 109  }
 110 );
 111
 112 __PACKAGE__->meta->make_immutable;
 113
 114 =head1 SEE ALSO
 115
 116 L<LaTeX::TikZ>, L<LaTeX::TikZ::Set::Path>, L<LaTeX::TikZ::Set::Mutable>.
 117
 118 =head1 AUTHOR
 119
 120 Vincent Pit, C<< <perl at profvince.com> >>, L<http://www.profvince.com>.
 121
 122 You can contact me by mail or on C<irc.perl.org> (vincent).
 123
 124 =head1 BUGS
 125
 126 Please report any bugs or feature requests to C<bug-latex-tikz at rt.cpan.org>, or through the web interface at L<http://rt.cpan.org/NoAuth/ReportBug.html?Queue=LaTeX-TikZ>.
 127 I will be notified, and then you'll automatically be notified of progress on your bug as I make changes.
 128
 129 =head1 SUPPORT
 130
 131 You can find documentation for this module with the perldoc command.
 132
 133     perldoc LaTeX::TikZ
 134
 135 =head1 COPYRIGHT & LICENSE
 136
 137 Copyright 2010 Vincent Pit, all rights reserved.
 138
 139 This program is free software; you can redistribute it and/or modify it under the same terms as Perl itself.
 140
 141 =cut
 142
 143 1; # End of LaTeX::TikZ::Set::Sequence