lib/LaTeX/TikZ/Set/Rectangle.pm

   1 package LaTeX::TikZ::Set::Rectangle;
   2
   3 use strict;
   4 use warnings;
   5
   6 =head1 NAME
   7
   8 LaTeX::TikZ::Set::Rectangle - A set object representing a rectangle.
   9
  10 =head1 VERSION
  11
  12 Version 0.01
  13
  14 =cut
  15
  16 our $VERSION = '0.01';
  17
  18 use LaTeX::TikZ::Set::Point;
  19
  20 use Any::Moose;
  21
  22 with 'LaTeX::TikZ::Set::Op';
  23
  24 has 'from' => (
  25  is       => 'ro',
  26  isa      => 'LaTeX::TikZ::Set::Point',
  27  required => 1,
  28  coerce   => 1,
  29 );
  30
  31 has 'to' => (
  32  is       => 'ro',
  33  isa      => 'LaTeX::TikZ::Set::Point',
  34  required => 1,
  35  coerce   => 1,
  36 );
  37
  38 has 'width' => (
  39  is  => 'ro',
  40  isa => 'Num',
  41 );
  42
  43 has 'height' => (
  44  is  => 'ro',
  45  isa => 'Num',
  46 );
  47
  48 sub path {
  49  my $set = shift;
  50
  51  $set->from->path(@_) . ' rectangle ' . $set->to->path(@_);
  52 }
  53
  54 my $meta = __PACKAGE__->meta;
  55 my $tc1  = $meta->find_attribute_by_name('from')->type_constraint;
  56 my $tc2  = $meta->find_attribute_by_name('to')->type_constraint;
  57
  58 around 'BUILDARGS' => sub {
  59  my $orig  = shift;
  60  my $class = shift;
  61
  62  if (@_ == 2 and $tc1->check($_[0]) and $tc2->check($_[1])) {
  63   @_ = (
  64    from => $_[0],
  65    to   => $_[1],
  66   );
  67  } else {
  68   my %args = @_;
  69   if (not exists $args{to} and exists $args{from}) {
  70    confess(<<'   MSG') unless exists $args{width} and exists $args{height};
  71 Attributes 'width' and 'height' are required when 'to' was not given
  72    MSG
  73    $args{from} = $tc1->coerce($args{from});
  74    $meta->find_attribute_by_name($_)->type_constraint->assert_valid($args{$_})
  75                                                       for qw/from width height/;
  76    my $p = $args{from}->point;
  77    $args{to} = LaTeX::TikZ::Point->new(
  78     x => $p->x + $args{width},
  79     y => $p->y + $args{height},
  80    );
  81    @_ = %args;
  82   }
  83  }
  84
  85  $class->$orig(@_);
  86 };
  87
  88 use LaTeX::TikZ::Interface rectangle => sub {
  89  shift;
  90  my ($p, $q) = @_;
  91
  92  my $is_relative = !blessed($q) && ref($q) eq 'HASH';
  93
  94  __PACKAGE__->new(
  95   from => $p,
  96   ($is_relative ? (map +($_ => $q->{$_}), qw/width height/) : (to => $q)),
  97  );
  98 };
  99
 100 __PACKAGE__->meta->make_immutable;
 101
 102 =head1 AUTHOR
 103
 104 Vincent Pit, C<< <perl at profvince.com> >>, L<http://www.profvince.com>.
 105
 106 You can contact me by mail or on C<irc.perl.org> (vincent).
 107
 108 =head1 BUGS
 109
 110 Please report any bugs or feature requests to C<bug-latex-tikz at rt.cpan.org>, or through the web interface at L<http://rt.cpan.org/NoAuth/ReportBug.html?Queue=LaTeX-TikZ>.
 111 I will be notified, and then you'll automatically be notified of progress on your bug as I make changes.
 112
 113 =head1 SUPPORT
 114
 115 You can find documentation for this module with the perldoc command.
 116
 117     perldoc LaTeX::TikZ
 118
 119 =head1 COPYRIGHT & LICENSE
 120
 121 Copyright 2010 Vincent Pit, all rights reserved.
 122
 123 This program is free software; you can redistribute it and/or modify it under the same terms as Perl itself.
 124
 125 =cut
 126
 127 1; # End of LaTeX::TikZ::Set::Rectangle