lib/LaTeX/TikZ/Set/Polyline.pm

   1 package LaTeX::TikZ::Set::Polyline;
   2
   3 use strict;
   4 use warnings;
   5
   6 =head1 NAME
   7
   8 LaTeX::TikZ::Set::Polyline - A set object representing a line.
   9
  10 =head1 VERSION
  11
  12 Version 0.01
  13
  14 =cut
  15
  16 our $VERSION = '0.01';
  17
  18 use LaTeX::TikZ::Set::Point;
  19
  20 use Any::Moose;
  21 use Any::Moose 'Util::TypeConstraints';
  22
  23 with 'LaTeX::TikZ::Set::Op';
  24
  25 subtype 'LaTeX::TikZ::Set::Polyline::Vertices'
  26      => as 'ArrayRef[LaTeX::TikZ::Set::Point]'
  27      => where { @$_ >= 2 }
  28      => message { 'at least two LaTeX::TikZ::Set::Point objects are needed in order to build a polyline' };
  29
  30 coerce 'LaTeX::TikZ::Set::Polyline::Vertices'
  31     => from 'ArrayRef[Any]'
  32     => via { [ map LaTeX::TikZ::Set::Point->new(point => $_), @$_ ] };
  33
  34 has '_points' => (
  35  is       => 'ro',
  36  isa      => 'LaTeX::TikZ::Set::Polyline::Vertices',
  37  init_arg => 'points',
  38  required => 1,
  39  coerce   => 1,
  40 );
  41
  42 sub points { @{$_[0]->_points} }
  43
  44 has 'closed' => (
  45  is      => 'ro',
  46  isa     => 'Bool',
  47  default => 0,
  48 );
  49
  50 sub path {
  51  my $set = shift;
  52
  53  join ' -- ', map($_->path(@_), $set->points),
  54               ($set->closed ? 'cycle' : ());
  55 }
  56
  57 use LaTeX::TikZ::Interface polyline => sub {
  58  shift;
  59
  60  __PACKAGE__->new(points => \@_);
  61 };
  62
  63 use LaTeX::TikZ::Interface closed_polyline => sub {
  64  shift;
  65
  66  __PACKAGE__->new(points => \@_, closed => 1);
  67 };
  68
  69 __PACKAGE__->meta->make_immutable;
  70
  71 =head1 AUTHOR
  72
  73 Vincent Pit, C<< <perl at profvince.com> >>, L<http://www.profvince.com>.
  74
  75 You can contact me by mail or on C<irc.perl.org> (vincent).
  76
  77 =head1 BUGS
  78
  79 Please report any bugs or feature requests to C<bug-latex-tikz at rt.cpan.org>, or through the web interface at L<http://rt.cpan.org/NoAuth/ReportBug.html?Queue=LaTeX-TikZ>.
  80 I will be notified, and then you'll automatically be notified of progress on your bug as I make changes.
  81
  82 =head1 SUPPORT
  83
  84 You can find documentation for this module with the perldoc command.
  85
  86     perldoc LaTeX::TikZ
  87
  88 =head1 COPYRIGHT & LICENSE
  89
  90 Copyright 2010 Vincent Pit, all rights reserved.
  91
  92 This program is free software; you can redistribute it and/or modify it under the same terms as Perl itself.
  93
  94 =cut
  95
  96 1; # End of LaTeX::TikZ::Set::Polyline