lib/LaTeX/TikZ/Set/Polyline.pm

   1 package LaTeX::TikZ::Set::Polyline;
   2
   3 use strict;
   4 use warnings;
   5
   6 =head1 NAME
   7
   8 LaTeX::TikZ::Set::Polyline - A set object representing a line.
   9
  10 =head1 VERSION
  11
  12 Version 0.01
  13
  14 =cut
  15
  16 our $VERSION = '0.01';
  17
  18 use LaTeX::TikZ::Set::Point;
  19
  20 use LaTeX::TikZ::Interface;
  21 use LaTeX::TikZ::Functor;
  22
  23 use Any::Moose;
  24 use Any::Moose 'Util::TypeConstraints';
  25
  26 with 'LaTeX::TikZ::Set::Op';
  27
  28 subtype 'LaTeX::TikZ::Set::Polyline::Vertices'
  29      => as 'ArrayRef[LaTeX::TikZ::Set::Point]'
  30      => where { @$_ >= 2 }
  31      => message { 'at least two LaTeX::TikZ::Set::Point objects are needed in order to build a polyline' };
  32
  33 coerce 'LaTeX::TikZ::Set::Polyline::Vertices'
  34     => from 'ArrayRef[Any]'
  35     => via { [ map LaTeX::TikZ::Set::Point->new(point => $_), @$_ ] };
  36
  37 has '_points' => (
  38  is       => 'ro',
  39  isa      => 'LaTeX::TikZ::Set::Polyline::Vertices',
  40  init_arg => 'points',
  41  required => 1,
  42  coerce   => 1,
  43 );
  44
  45 sub points { @{$_[0]->_points} }
  46
  47 has 'closed' => (
  48  is      => 'ro',
  49  isa     => 'Bool',
  50  default => 0,
  51 );
  52
  53 sub path {
  54  my $set = shift;
  55
  56  join ' -- ', map($_->path(@_), $set->points),
  57               ($set->closed ? 'cycle' : ());
  58 }
  59
  60 LaTeX::TikZ::Interface->register(
  61  polyline => sub {
  62   shift;
  63
  64   __PACKAGE__->new(points => \@_);
  65  },
  66  closed_polyline => sub {
  67   shift;
  68
  69   __PACKAGE__->new(points => \@_, closed => 1);
  70  },
  71 );
  72
  73 LaTeX::TikZ::Functor->default_rule(
  74  (__PACKAGE__) => sub {
  75   my ($functor, $set, @args) = @_;
  76   $set->new(
  77    points => [ map $_->$functor(@args), $set->points ],
  78    closed => $set->closed,
  79   );
  80  }
  81 );
  82
  83 __PACKAGE__->meta->make_immutable;
  84
  85 =head1 AUTHOR
  86
  87 Vincent Pit, C<< <perl at profvince.com> >>, L<http://www.profvince.com>.
  88
  89 You can contact me by mail or on C<irc.perl.org> (vincent).
  90
  91 =head1 BUGS
  92
  93 Please report any bugs or feature requests to C<bug-latex-tikz at rt.cpan.org>, or through the web interface at L<http://rt.cpan.org/NoAuth/ReportBug.html?Queue=LaTeX-TikZ>.
  94 I will be notified, and then you'll automatically be notified of progress on your bug as I make changes.
  95
  96 =head1 SUPPORT
  97
  98 You can find documentation for this module with the perldoc command.
  99
 100     perldoc LaTeX::TikZ
 101
 102 =head1 COPYRIGHT & LICENSE
 103
 104 Copyright 2010 Vincent Pit, all rights reserved.
 105
 106 This program is free software; you can redistribute it and/or modify it under the same terms as Perl itself.
 107
 108 =cut
 109
 110 1; # End of LaTeX::TikZ::Set::Polyline