lib/CPANPLUS/Dist/Gentoo/Atom.pm

   1 package CPANPLUS::Dist::Gentoo::Atom;
   2
   3 use strict;
   4 use warnings;
   5
   6 our $VERSION = '0.08';
   7
   8 use Carp         ();
   9 use Scalar::Util ();
  10
  11 use overload (
  12  '<=>' => \&_spaceship,
  13  '""'  => \&_stringify,
  14 );
  15
  16 use CPANPLUS::Dist::Gentoo::Version;
  17
  18 my $version_rx = $CPANPLUS::Dist::Gentoo::Version::version_rx;
  19
  20 sub new {
  21  my $class = shift;
  22  $class = ref($class) || $class;
  23
  24  my %args = @_;
  25
  26  my ($category, $name, $version);
  27  if (defined $args{name}) {
  28   ($category, $name, $version) = @args{qw/category name version/};
  29   Carp::confess('Category unspecified') unless defined $category;
  30   /[^\w-]/ and Carp::confess('Invalid argument') for $name, $category;
  31  } elsif (defined $args{atom}) {
  32   my $atom = $args{atom};
  33   $atom =~ m{^([\w-]+)/([\w-]+)-v?($version_rx)$}
  34                                                or Carp::confess('Invalid atom');
  35   ($category, $name, $version) = ($1, $2, $3);
  36  } elsif (defined $args{ebuild}) {
  37   my $ebuild = $args{ebuild};
  38   $ebuild =~ m{/([\w-]+)/([\w-]+)/\2-v?($version_rx)\.ebuild$}
  39                                              or Carp::confess('Invalid ebuild');
  40   ($category, $name, $version) = ($1, $2, $3);
  41  } else {
  42   Carp::confess('Not enough information for building an atom object');
  43  }
  44
  45  if (defined $version) {
  46   unless (Scalar::Util::blessed($version)
  47                               and $_->isa('CPANPLUS::Dist::Gentoo::Version')) {
  48    $version = CPANPLUS::Dist::Gentoo::Version->new($version);
  49   }
  50  }
  51
  52  my $range = $args{range};
  53  if (defined $version) {
  54   if (defined $range) {
  55    Carp::confess("Invalid range $range")
  56                                       unless grep $range eq $_, qw|< <= = >= >|;
  57   } else {
  58    $range = '=';
  59   }
  60  } else {
  61   Carp::confess('Range atoms require a valid version')
  62                                             if defined $range and length $range;
  63  }
  64
  65  bless {
  66   category => $category,
  67   name     => $name,
  68   version  => $version,
  69   range    => $range,
  70   ebuild   => $args{ebuild},
  71  }, $class;
  72 }
  73
  74 BEGIN {
  75  eval "sub $_ { \$_[0]->{$_} }" for qw/category name version range ebuild/;
  76 }
  77
  78 sub _spaceship {
  79  my ($a1, $a2, $r) = @_;
  80
  81  my $v1 = $a1->version;
  82
  83  my $v2;
  84  if (Scalar::Util::blessed($a2) and $a2->isa(__PACKAGE__)) {
  85   Carp::confess('Can\'t compare atoms of different packages')
  86                     if $a1->category ne $a2->category or $a1->name ne $a2->name;
  87   $v2 = $a2->version;
  88  } else {
  89   $v2 = $a2;
  90  }
  91
  92  ($v1, $v2) = ($v2, $v1) if $r;
  93
  94  return $v1 <=> $v2;
  95 }
  96
  97 sub _stringify {
  98  my ($a) = @_;
  99
 100  my $atom = $a->category . '/' . $a->name;
 101
 102  my $version = $a->version;
 103  $atom = $a->range . $atom . '-' . $version if defined $version;
 104
 105  return $atom;
 106 }
 107
 108 my %order = (
 109  '<'  => -2,
 110  '<=' => -1,
 111   '=' =>  0,
 112  '>=' =>  1,
 113  '>'  =>  2,
 114 );
 115
 116 sub and {
 117  shift unless length ref $_[0];
 118
 119  my $a1 = shift;
 120  my $a2 = shift;
 121  $a2 = $a2->and(@_) if @_;
 122
 123  my $p1 = join '/', $a1->category, $a1->name;
 124  my $p2 = join '/', $a2->category, $a2->name;
 125  Carp::confess("Atoms for different packages $p1 and $p2") unless $p1 eq $p2;
 126
 127  my $v1 = $a1->version;
 128  return $a2 unless defined $v1;
 129  my $r1 = $a1->range; # Defined if $v1 is defined
 130
 131  my $v2 = $a2->version;
 132  return $a1 unless defined $v2;
 133  my $r2 = $a2->range; # defined if $v2 is defined
 134
 135  my $o1 = $order{$r1};
 136  my $o2 = $order{$r2};
 137
 138  Carp::confess("Incompatible ranges $r1$p1 and $r2$p2") if $o1 * $o2 < 0;
 139
 140  if ($r2 eq '=') {
 141   ($a1, $a2) = ($a2, $a1);
 142   ($v1, $v2) = ($v2, $v1);
 143   ($r1, $r2) = ($r2, $r1);
 144   ($o1, $o2) = ($o2, $o1);
 145  }
 146
 147  if ($r1 eq '=') {
 148   my $r = $r2 eq '=' ? '==' : $r2;
 149   Carp::confess("Version mismatch $v1 $r $v2") unless eval "\$a1 $r \$a2";
 150   return $a1;
 151  } elsif ($o1 > 0) {
 152   return $a1 < $a2 ? $a2 : $a1;
 153  } else {
 154   return $a1 < $a2 ? $a1 : $a2;
 155  }
 156 }
 157
 158 sub fold {
 159  shift unless length ref $_[0];
 160
 161  my %seen;
 162  for my $atom (@_) {
 163   my $key = join '/', $atom->category, $atom->name;
 164
 165   my $cur = $seen{$key};
 166   $seen{$key} = defined $cur ? $cur->and($atom) : $atom;
 167  }
 168
 169  return values %seen;
 170 }
 171
 172 1;