lib/CPANPLUS/Dist/Gentoo/Atom.pm

   1 package CPANPLUS::Dist::Gentoo::Atom;
   2
   3 use strict;
   4 use warnings;
   5
   6 our $VERSION = '0.08';
   7
   8 use Carp         ();
   9 use Scalar::Util ();
  10
  11 use overload (
  12  '<=>' => \&_spaceship,
  13  'cmp' => \&_cmp,
  14  '""'  => \&_stringify,
  15 );
  16
  17 use CPANPLUS::Dist::Gentoo::Version;
  18
  19 my $version_rx = $CPANPLUS::Dist::Gentoo::Version::version_rx;
  20
  21 sub new {
  22  my $class = shift;
  23  $class = ref($class) || $class;
  24
  25  my %args = @_;
  26
  27  my ($category, $name, $version);
  28  if (defined $args{name}) {
  29   ($category, $name, $version) = @args{qw/category name version/};
  30   Carp::confess('Category unspecified') unless defined $category;
  31   /[^\w-]/ and Carp::confess('Invalid argument') for $name, $category;
  32  } elsif (defined $args{atom}) {
  33   my $atom = $args{atom};
  34   $atom =~ m{^([\w-]+)/([\w-]+)-v?($version_rx)$}
  35                                                or Carp::confess('Invalid atom');
  36   ($category, $name, $version) = ($1, $2, $3);
  37  } elsif (defined $args{ebuild}) {
  38   my $ebuild = $args{ebuild};
  39   $ebuild =~ m{/([\w-]+)/([\w-]+)/\2-v?($version_rx)\.ebuild$}
  40                                              or Carp::confess('Invalid ebuild');
  41   ($category, $name, $version) = ($1, $2, $3);
  42  } else {
  43   Carp::confess('Not enough information for building an atom object');
  44  }
  45
  46  if (defined $version) {
  47   unless (Scalar::Util::blessed($version)
  48                               and $_->isa('CPANPLUS::Dist::Gentoo::Version')) {
  49    $version = CPANPLUS::Dist::Gentoo::Version->new($version);
  50   }
  51  }
  52
  53  my $range = $args{range};
  54  if (defined $version) {
  55   if (defined $range) {
  56    Carp::confess("Invalid range $range")
  57                                       unless grep $range eq $_, qw|< <= = >= >|;
  58   } else {
  59    $range = '=';
  60   }
  61  } else {
  62   Carp::confess('Range atoms require a valid version')
  63                                             if defined $range and length $range;
  64  }
  65
  66  bless {
  67   category => $category,
  68   name     => $name,
  69   version  => $version,
  70   range    => $range,
  71   ebuild   => $args{ebuild},
  72  }, $class;
  73 }
  74
  75 BEGIN {
  76  eval "sub $_ { \$_[0]->{$_} }" for qw/category name version range ebuild/;
  77 }
  78
  79 sub qualified_name { join '/', $_[0]->category, $_[0]->name }
  80
  81 sub _spaceship {
  82  my ($a1, $a2, $r) = @_;
  83
  84  my $v1 = $a1->version;
  85
  86  my $v2;
  87  if (Scalar::Util::blessed($a2) and $a2->isa(__PACKAGE__)) {
  88   Carp::confess('Can\'t compare atoms of different packages')
  89                     if $a1->category ne $a2->category or $a1->name ne $a2->name;
  90   $v2 = $a2->version;
  91  } else {
  92   $v2 = $a2;
  93  }
  94
  95  ($v1, $v2) = ($v2, $v1) if $r;
  96
  97  return $v1 <=> $v2;
  98 }
  99
 100 sub _cmp {
 101  my ($a1, $a2, $r) = @_;
 102
 103  my $s1 = $a1->qualified_name;
 104  my $v1 = $a1->version;
 105  $s1   .= "-$v1" if defined $v1;
 106
 107  my $s2;
 108  if (Scalar::Util::blessed($a2) and $a2->isa(__PACKAGE__)) {
 109   $s2    = $a2->qualified_name;
 110   my $v2 = $a2->version;
 111   $s2   .= "-$v2" if defined $v2;
 112  } else {
 113   $s2 = $a2;
 114  }
 115
 116  $s1 cmp $s2;
 117 }
 118
 119 sub _stringify {
 120  my ($a) = @_;
 121
 122  my $atom = $a->qualified_name;
 123
 124  my $version = $a->version;
 125  $atom = $a->range . $atom . '-' . $version if defined $version;
 126
 127  return $atom;
 128 }
 129
 130 my %order = (
 131  '<'  => -2,
 132  '<=' => -1,
 133   '=' =>  0,
 134  '>=' =>  1,
 135  '>'  =>  2,
 136 );
 137
 138 sub and {
 139  shift unless length ref $_[0];
 140
 141  my $a1 = shift;
 142  my $a2 = shift;
 143  $a2 = $a2->and(@_) if @_;
 144
 145  my $p1 = $a1->qualified_name;
 146  my $p2 = $a2->qualified_name;
 147  Carp::confess("Atoms for different packages $p1 and $p2") unless $p1 eq $p2;
 148
 149  my $v1 = $a1->version;
 150  return $a2 unless defined $v1;
 151  my $r1 = $a1->range; # Defined if $v1 is defined
 152
 153  my $v2 = $a2->version;
 154  return $a1 unless defined $v2;
 155  my $r2 = $a2->range; # defined if $v2 is defined
 156
 157  my $o1 = $order{$r1};
 158  my $o2 = $order{$r2};
 159
 160  Carp::confess("Incompatible ranges $r1$p1 and $r2$p2") if $o1 * $o2 < 0;
 161
 162  if ($r2 eq '=') {
 163   ($a1, $a2) = ($a2, $a1);
 164   ($v1, $v2) = ($v2, $v1);
 165   ($r1, $r2) = ($r2, $r1);
 166   ($o1, $o2) = ($o2, $o1);
 167  }
 168
 169  if ($r1 eq '=') {
 170   my $r = $r2 eq '=' ? '==' : $r2;
 171   Carp::confess("Version mismatch $v1 $r $v2") unless eval "\$a1 $r \$a2";
 172   return $a1;
 173  } elsif ($o1 > 0) {
 174   return $a1 < $a2 ? $a2 : $a1;
 175  } else {
 176   return $a1 < $a2 ? $a1 : $a2;
 177  }
 178 }
 179
 180 sub fold {
 181  shift unless length ref $_[0];
 182
 183  my %seen;
 184  for my $atom (@_) {
 185   my $key = $atom->qualified_name;
 186
 187   my $cur = $seen{$key};
 188   $seen{$key} = defined $cur ? $cur->and($atom) : $atom;
 189  }
 190
 191  return values %seen;
 192 }
 193
 194 1;