lib/CPANPLUS/Dist/Gentoo.pm

   1 package CPANPLUS::Dist::Gentoo;
   2
   3 use strict;
   4 use warnings;
   5
   6 use Cwd qw/abs_path/;
   7 use File::Copy qw/copy/;
   8 use File::Path qw/mkpath/;
   9 use File::Spec::Functions qw/catdir catfile/;
  10
  11 use IPC::Cmd qw/run can_run/;
  12
  13 use CPANPLUS::Error;
  14
  15 use base qw/CPANPLUS::Dist::Base/;
  16
  17 =head1 NAME
  18
  19 CPANPLUS::Dist::Gentoo - CPANPLUS backend generating Gentoo ebuilds.
  20
  21 =head1 VERSION
  22
  23 Version 0.04
  24
  25 =cut
  26
  27 our $VERSION = '0.04';
  28
  29 =head1 SYNOPSIS
  30
  31     cpan2dist --format=CPANPLUS::Dist::Gentoo \
  32               --dist-opts overlay=/usr/local/portage \
  33               --dist-opts distdir=/usr/portage/distfiles \
  34               --dist-opts manifest=yes \
  35               --dist-opts keywords=x86 \
  36               --dist-opts header="# Copyright 1999-2008 Gentoo Foundation" \
  37               --dist-opts footer="# End" \
  38               Any::Module You::Like
  39
  40 =head1 DESCRPITON
  41
  42 This module is a CPANPLUS backend that recursively generates Gentoo ebuilds for a given package in the specified overlay (defaults to F</usr/local/portage>), updates the manifest, and even emerges it (together with its dependencies) if the user requires it. You need write permissions on the directory where Gentoo fetches its source files (usually F</usr/portage/distfiles>). You also need to specify the correct keyword for your architecture if it differs from the default C<x86>.
  43
  44 The generated ebuilds are placed into the C<perl-gcpanp> category. They favour depending on C<perl-core>, C<dev-perl> or C<perl-gcpan> (in that order) rather than C<perl-gcpanp>.
  45
  46 =head1 INSTALLATION
  47
  48 After installing this module, you should append C<perl-gcpanp> to your F</etc/portage/categories> file.
  49
  50 =head1 METHODS
  51
  52 All the methods are inherited from L<CPANPLUS::Dist::Base>. Please refer to its documentation for precise information on what's done at each step.
  53
  54 =cut
  55
  56 use constant CATEGORY => 'perl-gcpanp';
  57
  58 sub format_available {
  59  for my $prog (qw/emerge ebuild/) {
  60   unless (can_run($prog)) {
  61    error "$prog is required to write ebuilds -- aborting";
  62    return 0;
  63   }
  64  }
  65  return 1;
  66 }
  67
  68 sub init {
  69  my ($self) = @_;
  70  my $stat = $self->status;
  71  my $conf = $self->parent->parent->configure_object;
  72
  73  $stat->mk_accessors(qw/name version author dist desc uri src license deps
  74                         eb_name eb_version eb_dir eb_file fetched_arch
  75                         overlay distdir keywords do_manifest header footer
  76                         force verbose/);
  77
  78  $stat->force($conf->get_conf('force'));
  79  $stat->verbose($conf->get_conf('verbose'));
  80
  81  return 1;
  82 }
  83
  84 my %gentooism = (
  85  'Crypt-RSA'         => 'crypt-rsa',
  86  'Digest'            => 'digest-base',
  87  'Locale-Maketext'   => 'locale-maketext',
  88  'Math-Pari'         => 'math-pari',
  89  'Net-Ping'          => 'net-ping',
  90  'PathTools'         => 'File-Spec',
  91  'PodParser'         => 'Pod-Parser',
  92  'Set-Scalar'        => 'set-scalar',
  93  'Tie-EncryptedHash' => 'tie-encryptedhash',
  94  'YAML'              => 'yaml',
  95 );
  96
  97 sub prepare {
  98  my $self = shift;
  99  my $mod  = $self->parent;
 100  my $stat = $self->status;
 101  my $int  = $mod->parent;
 102  my $conf = $int->configure_object;
 103
 104  my %opts = @_;
 105
 106  $stat->prepared(0);
 107
 108  my $keywords = delete $opts{'keywords'};
 109  $keywords = 'x86' unless defined $keywords;
 110  $keywords = [ split ' ', $keywords ];
 111  $stat->keywords($keywords);
 112
 113  my $manifest = delete $opts{'manifest'};
 114  $manifest = 1 unless defined $manifest;
 115  $manifest = 0 if $manifest =~ /^\s*no?\s*$/i;
 116  $stat->do_manifest($manifest);
 117
 118  my $header = delete $opts{'header'};
 119  if (defined $header) {
 120   1 while chomp $header;
 121   $header .= "\n\n";
 122  } else {
 123   $header = '';
 124  }
 125  $stat->header($header);
 126
 127  my $footer = delete $opts{'footer'};
 128  if (defined $footer) {
 129   $footer = "\n" . $footer;
 130  } else {
 131   $footer = '';
 132  }
 133  $stat->footer($footer);
 134
 135  my $overlay = delete $opts{'overlay'};
 136  $overlay = (defined $overlay) ? abs_path $overlay : '/usr/local/portage';
 137  $stat->overlay($overlay);
 138
 139  my $distdir = delete $opts{'distdir'};
 140  $distdir = (defined $distdir) ? abs_path $distdir : '/usr/portage/distfiles';
 141  $stat->distdir($distdir);
 142
 143  if ($stat->do_manifest && !-w $stat->distdir) {
 144   error 'distdir isn\'t writable -- aborting';
 145   return 0;
 146  }
 147  $stat->fetched_arch($mod->status->fetch);
 148
 149  my $name = $mod->package_name;
 150  $stat->name($name);
 151
 152  my $version = $mod->package_version;
 153  $stat->version($version);
 154
 155  my $author = $mod->author->cpanid;
 156  $stat->author($author);
 157
 158  $stat->dist($name . '-' . $version);
 159
 160  $version =~ s/[^\d._]+//g;
 161  $version =~ s/^[._]*//;
 162  $version =~ s/[._]*$//;
 163  $version =~ s/[._]*_[._]*/_/g;
 164  {
 165   ($version, my $patch, my @rest) = split /_/, $version;
 166   $version .= '_p' . $patch if defined $patch;
 167   $version .= join('.', '', @rest) if @rest;
 168  }
 169  $stat->eb_version($version);
 170
 171  $stat->eb_name($gentooism{$name} || $name);
 172
 173  $stat->eb_dir(catdir($stat->overlay, CATEGORY, $stat->eb_name));
 174
 175  my $file = catfile($stat->eb_dir,
 176                     $stat->eb_name . '-' . $stat->eb_version . '.ebuild');
 177  if (-e $file) {
 178   my $skip = 1;
 179   if ($stat->force) {
 180    if (-w $file) {
 181     1 while unlink $file;
 182     $skip = 0;
 183    } else {
 184     error "Can't force rewriting of $file -- skipping";
 185    }
 186   } else {
 187    msg 'Ebuild already generated for ' . $stat->dist . ' -- skipping';
 188   }
 189   if ($skip) {
 190    $stat->prepared(1);
 191    $stat->created(1);
 192    return 1;
 193   }
 194  }
 195  $stat->eb_file($file);
 196
 197  $self->SUPER::prepare(%opts);
 198
 199  my $desc = $mod->description;
 200  ($desc = $name) =~ s/-+/::/g unless $desc;
 201  $stat->desc($desc);
 202
 203  $stat->uri('http://search.cpan.org/dist/' . $name);
 204
 205  unless ($author =~ /^(.)(.)/) {
 206   error 'Wrong author name -- aborting';
 207   return 0;
 208  }
 209  $stat->src("mirror://cpan/modules/by-authors/id/$1/$1$2/$author/"
 210             . $mod->package);
 211
 212  $stat->license([ qw/Artistic GPL-2/ ]);
 213
 214  my $prereqs = $mod->status->prereqs;
 215  my @depends;
 216  for my $prereq (sort keys %$prereqs) {
 217   next if $prereq =~ /^perl(?:-|\z)/;
 218   my $obj = $int->module_tree($prereq);
 219   unless ($obj) {
 220    error 'Wrong module object -- aborting';
 221    return 0;
 222   }
 223   next if $obj->package_is_perl_core;
 224   {
 225    my $version;
 226    if ($prereqs->{$prereq}) {
 227     if ($obj->installed_version && $obj->installed_version < $obj->version) {
 228      $version = $obj->installed_version;
 229     } else {
 230      $version = $obj->package_version;
 231     }
 232    }
 233    push @depends, [ $obj , $version ];
 234   }
 235  }
 236  $stat->deps(\@depends);
 237
 238  $stat->prepared(1);
 239  return 1;
 240 }
 241
 242 sub create {
 243  my $self = shift;
 244  my $stat = $self->status;
 245
 246  unless ($stat->prepared) {
 247   error 'Can\'t create ' . $stat->dist . ' since it was never prepared -- aborting';
 248   return 0;
 249  }
 250
 251  if ($stat->created) {
 252   msg $stat->dist . ' was already created -- skipping';
 253   return 1;
 254  }
 255
 256  $self->SUPER::create(@_);
 257
 258  my $dir = $stat->eb_dir;
 259  unless (-d $dir) {
 260   eval { mkpath $dir };
 261   if ($@) {
 262    error "mkpath($dir): $@";
 263    return 0;
 264   }
 265  }
 266
 267  my $d = $stat->header;
 268  $d   .= "# Generated by CPANPLUS::Dist::Gentoo version $VERSION\n\n";
 269  $d   .= 'MODULE_AUTHOR="' . $stat->author . "\"\ninherit perl-module\n\n";
 270  $d   .= 'S="${WORKDIR}/' . $stat->dist . "\"\n";
 271  $d   .= 'DESCRIPTION="' . $stat->desc . "\"\n";
 272  $d   .= 'HOMEPAGE="' . $stat->uri . "\"\n";
 273  $d   .= 'SRC_URI="' . $stat->src . "\"\n";
 274  $d   .= "SLOT=\"0\"\n";
 275  $d   .= 'LICENSE="|| ( ' . join(' ', sort @{$stat->license}) . " )\"\n";
 276  $d   .= 'KEYWORDS="' . join(' ', sort @{$stat->keywords}) . "\"\n";
 277  $d   .= 'DEPEND="' . join "\n",
 278   'dev-lang/perl',
 279   map {
 280    my $a = $_->[0]->package_name;
 281    $a = $gentooism{$a} || $a;
 282    my $x = '';
 283    if (defined $_->[1]) {
 284     $x  = '>=';
 285     $a .= '-' . $_->[1];
 286    }
 287    '|| ( ' . join(' ', map "$x$_/$a",
 288                            qw/perl-core dev-perl perl-gcpan/, CATEGORY)
 289            . ' )';
 290   } @{$stat->deps};
 291  $d   .= "\"\n";
 292  $d   .= "SRC_TEST=\"do\"\n";
 293  $d   .= $stat->footer;
 294
 295  my $file = $stat->eb_file;
 296  open my $eb, '>', $file or do {
 297   error "open($file): $! -- aborting";
 298   return 0;
 299  };
 300  print $eb $d;
 301  close $eb;
 302
 303  if ($stat->do_manifest) {
 304   unless (copy $stat->fetched_arch, $stat->distdir) {
 305    error "Couldn\'t copy the distribution file to distdir ($!) -- aborting";
 306    1 while unlink $file;
 307    return 0;
 308   }
 309
 310   msg 'Adding Manifest entry for ' . $stat->dist;
 311   unless ($self->_run([ 'ebuild', $file, 'manifest' ], 0)) {
 312    1 while unlink $file;
 313    return 0;
 314   }
 315  }
 316
 317  return 1;
 318 }
 319
 320 sub install {
 321  my $self = shift;
 322  my $stat = $self->status;
 323  my $conf = $self->parent->parent->configure_object;
 324
 325  my $sudo = $conf->get_program('sudo');
 326  my @cmd = ('emerge', '=' . $stat->eb_name . '-' . $stat->eb_version);
 327  unshift @cmd, $sudo if $sudo;
 328
 329  return $self->_run(\@cmd, 1);
 330 }
 331
 332 sub uninstall {
 333  my $self = shift;
 334  my $stat = $self->status;
 335  my $conf = $self->parent->parent->configure_object;
 336
 337  my $sudo = $conf->get_program('sudo');
 338  my @cmd = ('emerge', '-C', '=' . $stat->eb_name . '-' . $stat->eb_version);
 339  unshift @cmd, $sudo if $sudo;
 340
 341  return $self->_run(\@cmd, 1);
 342 }
 343
 344 sub _run {
 345  my ($self, $cmd, $verbose) = @_;
 346  my $stat = $self->status;
 347
 348  my ($success, $errmsg, $output) = do {
 349   local $ENV{PORTDIR_OVERLAY}     = $stat->overlay;
 350   local $ENV{PORTAGE_RO_DISTDIRS} = $stat->distdir;
 351   run command => $cmd, verbose => $verbose;
 352  };
 353
 354  unless ($success) {
 355   error "$errmsg -- aborting";
 356   if (not $verbose and defined $output and $self->status->verbose) {
 357    my $msg = join '', @$output;
 358    1 while chomp $msg;
 359    error $msg;
 360   }
 361  }
 362
 363  return $success;
 364 }
 365
 366 =head1 DEPENDENCIES
 367
 368 Gentoo (L<http://gentoo.org>).
 369
 370 L<CPANPLUS>, L<IPC::Cmd> (core modules since 5.9.5).
 371
 372 L<Cwd> (since perl 5) L<File::Path> (5.001), L<File::Copy> (5.002), L<File::Spec::Functions> (5.00504).
 373
 374 =head1 SEE ALSO
 375
 376 L<cpan2dist>.
 377
 378 L<CPANPLUS::Dist::Base>, L<CPANPLUS::Dist::Deb>, L<CPANPLUS::Dist::Mdv>.
 379
 380 =head1 AUTHOR
 381
 382 Vincent Pit, C<< <perl at profvince.com> >>, L<http://www.profvince.com>.
 383
 384 You can contact me by mail or on C<irc.perl.org> (vincent).
 385
 386 =head1 BUGS
 387
 388 Please report any bugs or feature requests to C<bug-cpanplus-dist-gentoo at rt.cpan.org>, or through the web interface at L<http://rt.cpan.org/NoAuth/ReportBug.html?Queue=CPANPLUS-Dist-Gentoo>.  I will be notified, and then you'll automatically be notified of progress on your bug as I make changes.
 389
 390 =head1 SUPPORT
 391
 392 You can find documentation for this module with the perldoc command.
 393
 394     perldoc CPANPLUS::Dist::Gentoo
 395
 396 =head1 ACKNOWLEDGEMENTS
 397
 398 The module is to some extend cargo-culted from L<CPANPLUS::Dist::Deb> and L<CPANPLUS::Dist::Mdv>.
 399
 400 Kent Fredric, for testing and suggesting improvements.
 401
 402 =head1 COPYRIGHT & LICENSE
 403
 404 Copyright 2008 Vincent Pit, all rights reserved.
 405
 406 This program is free software; you can redistribute it and/or modify it under the same terms as Perl itself.
 407
 408 =cut
 409
 410 1; # End of CPANPLUS::Dist::Gentoo