lib/CPANPLUS/Dist/Gentoo.pm

   1 package CPANPLUS::Dist::Gentoo;
   2
   3 use strict;
   4 use warnings;
   5
   6 use File::Copy qw/copy/;
   7 use File::Path qw/mkpath/;
   8 use File::Spec::Functions qw/catdir catfile/;
   9
  10 use IPC::Cmd qw/run can_run/;
  11
  12 use CPANPLUS::Error;
  13
  14 use base qw/CPANPLUS::Dist::Base/;
  15
  16 =head1 NAME
  17
  18 CPANPLUS::Dist::Gentoo - CPANPLUS backend generating Gentoo ebuilds.
  19
  20 =head1 VERSION
  21
  22 Version 0.02_01
  23
  24 =cut
  25
  26 our $VERSION = '0.02_01';
  27
  28 =head1 SYNOPSIS
  29
  30     cpan2dist --format=CPANPLUS::Dist::Gentoo \
  31               --dist-opts overlay=/usr/local/portage \
  32               --dist-opts distdir=/usr/portage/distfiles \
  33               --dist-opts manifest=yes \
  34               --dist-opts keywords=x86 \
  35               Any::Module You::Like
  36
  37 =head1 DESCRPITON
  38
  39 This module is a CPANPLUS backend that recursively generates Gentoo ebuilds for a given package in the specified overlay (defaults to C</usr/local/portage>), update the manifest, and even emerge it (together with its dependencies) if the user requires it. You need write permissions on the directory where Gentoo fetches its source files (usually C</usr/portage/distfiles>).
  40
  41 The generated ebuilds are placed into the section C<perl-gcpanp>. They favour depending on C<perl-core> or C<dev-perl> rather than C<perl-gcpanp>.
  42
  43 =head1 INSTALLATION
  44
  45 After installing this module, you should append C<perl-gcpanp> to your F</etc/portage/categories> file.
  46
  47 =head1 METHODS
  48
  49 All the methods are inherited from L<CPANPLUS::Dist::Base>. Please refer to its perldoc for precise information on what's done at each step.
  50
  51 =cut
  52
  53 use constant CATEGORY => 'perl-gcpanp';
  54
  55 sub format_available {
  56  for my $prog (qw/emerge ebuild/) {
  57   unless (can_run($prog)) {
  58    error "$prog is required to write ebuilds -- aborting";
  59    return 0;
  60   }
  61  }
  62  return 1;
  63 }
  64
  65 sub init {
  66  my ($self) = @_;
  67  my $stat = $self->status;
  68  $stat->mk_accessors(qw/name version dist desc uri src license deps
  69                         eb_name eb_version eb_dir eb_file distdir fetched_arch
  70                         keywords do_manifest/);
  71
  72  return 1;
  73 }
  74
  75 my %gentooism = (
  76  'Digest'            => 'digest-base',
  77  'Locale-Maketext'   => 'locale-maketext',
  78  'Net-Ping'          => 'net-ping',
  79  'PathTools'         => 'File-Spec',
  80  'PodParser'         => 'Pod-Parser',
  81  'Set-Scalar'        => 'set-scalar',
  82  'Tie-EncryptedHash' => 'tie-encryptedhash',
  83 );
  84
  85 sub prepare {
  86  my $self = shift;
  87  my $mod  = $self->parent;
  88  my $stat = $self->status;
  89  my $int  = $mod->parent;
  90  my $conf = $int->configure_object;
  91
  92  my %opts = @_;
  93
  94  my $keywords = delete $opts{'keywords'};
  95  $keywords = 'x86' unless defined $keywords;
  96  $keywords = [ split ' ', $keywords ];
  97  $stat->keywords($keywords);
  98
  99  my $manifest = delete $opts{'manifest'};
 100  $manifest = 1 unless defined $manifest;
 101  $manifest = 0 if $manifest =~ /^\s*no?\s*$/i;
 102  $stat->do_manifest($manifest);
 103
 104  my $overlay = catdir(delete($opts{'overlay'}) || '/usr/local/portage',
 105                       CATEGORY);
 106
 107  $stat->distdir(delete($opts{'distdir'}) || '/usr/portage/distfiles');
 108  if ($stat->do_manifest && !-w $stat->distdir) {
 109   error 'distdir isn\'t writable -- aborting';
 110   return 0;
 111  }
 112  $stat->fetched_arch($mod->status->fetch);
 113
 114  my $name = $mod->package_name;
 115  $stat->name($name);
 116
 117  my $version = $mod->package_version;
 118  $stat->version($version);
 119  $stat->dist($name . '-' . $version);
 120  my $f = 1;
 121  $version =~ s/_+/$f ? do { $f = 0; '_p' } : ''/ge;
 122  1 while $version =~ s/(_p[^.]*)\.+/$1/;
 123  $stat->eb_version($version);
 124
 125  $stat->eb_name($gentooism{$stat->name} || $stat->name);
 126  $stat->eb_dir(catdir($overlay, $stat->eb_name));
 127  $stat->eb_file(catfile($stat->eb_dir,
 128                         $stat->eb_name . '-' . $stat->eb_version . '.ebuild'));
 129  if (-r $stat->eb_file) {
 130   msg 'Ebuild already generated for ' . $stat->dist . ' -- skipping';
 131   $stat->prepared(1);
 132   $stat->created(1);
 133   return 1;
 134  }
 135
 136  $self->SUPER::prepare(%opts);
 137
 138  my $desc = $mod->description;
 139  ($desc = $name) =~ s/-+/::/g unless $desc;
 140  $stat->desc($desc);
 141  $stat->uri('http://search.cpan.org/dist/' . $name);
 142  unless ($name =~ /^([^-]+)/) {
 143   error 'Wrong distribution name -- aborting';
 144   return 0;
 145  }
 146  $stat->src('mirror://cpan/modules/by-module/' . $1 . '/' . $mod->package);
 147  $stat->license([ qw/Artistic GPL-2/ ]);
 148
 149  my $prereqs = $mod->status->prereqs;
 150  my @depends;
 151  for my $prereq (sort keys %$prereqs) {
 152   next if $prereq =~ /^perl(?:-|\z)/;
 153   my $obj = $int->module_tree($prereq);
 154   unless ($obj) {
 155    error 'Wrong module object -- aborting';
 156    return 0;
 157   }
 158   next if $obj->package_is_perl_core;
 159   {
 160    my $version;
 161    if ($prereqs->{$prereq}) {
 162     if ($obj->installed_version && $obj->installed_version < $obj->version) {
 163      $version = $obj->installed_version;
 164     } else {
 165      $version = $obj->package_version;
 166     }
 167    }
 168    push @depends, [ $obj , $version ];
 169   }
 170  }
 171  $stat->deps(\@depends);
 172
 173  return 1;
 174 }
 175
 176 sub create {
 177  my $self = shift;
 178  my $stat = $self->status;
 179
 180  unless ($stat->prepared) {
 181   error 'Can\'t create ' . $stat->dist . ' since it was never prepared -- aborting';
 182   return 0;
 183  }
 184
 185  if ($stat->created) {
 186   msg $stat->dist . ' was already created -- skipping';
 187   return 1;
 188  }
 189
 190  $self->SUPER::create(@_);
 191
 192  my $dir = $stat->eb_dir;
 193  unless (-d $dir) {
 194   eval { mkpath $dir };
 195   if ($@) {
 196    error "mkpath($dir): $@";
 197    return 0;
 198   }
 199  }
 200
 201  my $d = "# Generated by CPANPLUS::Dist::Gentoo\n\ninherit perl-module\n\n";
 202  $d   .= 'S="${WORKDIR}/' . $stat->dist . "\"\n";
 203  $d   .= 'DESCRIPTION="' . $stat->desc . "\"\n";
 204  $d   .= 'HOMEPAGE="' . $stat->uri . "\"\n";
 205  $d   .= 'SRC_URI="' . $stat->src . "\"\n";
 206  $d   .= "SLOT=\"0\"\n";
 207  $d   .= 'LICENSE="|| ( ' . join(' ', sort @{$stat->license}) . " )\"\n";
 208  $d   .= 'KEYWORDS="' . join(' ', sort @{$stat->keywords}) . "\"\n";
 209  $d   .= 'DEPEND="' . join "\n",
 210   'dev-lang/perl',
 211   map {
 212    my $a = $_->[0]->package_name;
 213    my $x = '';
 214    if (defined $_->[1]) {
 215     $x  = '>=';
 216     $a .= '-' . $_->[1];
 217    }
 218    '|| ( ' . join(' ', map "$x$_/$a",
 219                            qw/perl-core dev-perl perl-gcpan/, CATEGORY)
 220            . ' )';
 221   } @{$stat->deps};
 222  $d   .= "\"\n";
 223
 224  my $file = $stat->eb_file;
 225  open my $eb, '>', $file or do {
 226   error "open($file): $! -- aborting";
 227   return 0;
 228  };
 229  print $eb $d;
 230  close $eb;
 231
 232  if ($stat->do_manifest) {
 233   unless (copy $stat->fetched_arch, $stat->distdir) {
 234    error "Couldn\'t copy the distribution file to distdir ($!) -- aborting";
 235    1 while unlink $file;
 236    return 0;
 237   }
 238
 239   msg 'Adding Manifest entry for ' . $stat->dist;
 240   my ($success, $errmsg) = run command => [ 'ebuild', $file, 'manifest' ],
 241                                verbose => 0;
 242   unless ($success) {
 243    error "$errmsg -- aborting";
 244    1 while unlink $file;
 245    return 0;
 246   }
 247  }
 248
 249  return 1;
 250 }
 251
 252 sub install {
 253  my $self = shift;
 254  my $stat = $self->status;
 255  my $conf = $self->parent->parent->configure_object;
 256
 257  my $sudo = $conf->get_program('sudo');
 258  my @cmd = ('emerge', '=' . $stat->eb_name . '-' . $stat->eb_version);
 259  unshift @cmd, $sudo if $sudo;
 260
 261  my ($success, $errmsg) = run command => \@cmd,
 262                               verbose => 1;
 263  unless ($success) {
 264   error "$errmsg -- aborting";
 265   return 0;
 266  }
 267
 268  return 1;
 269 }
 270
 271 sub uninstall {
 272  my $self = shift;
 273  my $stat = $self->status;
 274  my $conf = $self->parent->parent->configure_object;
 275
 276  my $sudo = $conf->get_program('sudo');
 277  my @cmd = ('emerge', '-C', '=' . $stat->eb_name . '-' . $stat->eb_version);
 278  unshift @cmd, $sudo if $sudo;
 279
 280  my ($success, $errmsg) = run command => \@cmd,
 281                               verbose => 1;
 282  unless ($success) {
 283   error "$errmsg -- aborting";
 284   return 0;
 285  }
 286
 287  return 1;
 288 }
 289
 290 =head1 DEPENDENCIES
 291
 292 Gentoo (L<http://gentoo.org>).
 293
 294 L<CPANPLUS>, L<IPC::Cmd> (core modules since 5.9.5).
 295
 296 L<File::Path> (since 5.001), L<File::Copy> (5.002), L<File::Spec::Functions> (5.00504).
 297
 298 =head1 SEE ALSO
 299
 300 L<cpan2dist>.
 301
 302 L<CPANPLUS::Dist::Base>, L<CPANPLUS::Dist::Deb>, L<CPANPLUS::Dist::Mdv>.
 303
 304 =head1 AUTHOR
 305
 306 Vincent Pit, C<< <perl at profvince.com> >>, L<http://www.profvince.com>.
 307
 308 You can contact me by mail or on C<irc.perl.org> (vincent).
 309
 310 =head1 BUGS
 311
 312 Please report any bugs or feature requests to C<bug-cpanplus-dist-gentoo at rt.cpan.org>, or through the web interface at L<http://rt.cpan.org/NoAuth/ReportBug.html?Queue=CPANPLUS-Dist-Gentoo>.  I will be notified, and then you'll automatically be notified of progress on your bug as I make changes.
 313
 314 =head1 SUPPORT
 315
 316 You can find documentation for this module with the perldoc command.
 317
 318     perldoc CPANPLUS::Dist::Gentoo
 319
 320 =head1 ACKNOWLEDGEMENTS
 321
 322 The module is to some extend cargo-culted from L<CPANPLUS::Dist::Deb> and L<CPANPLUS::Dist::Mdv>.
 323
 324 =head1 COPYRIGHT & LICENSE
 325
 326 Copyright 2008 Vincent Pit, all rights reserved.
 327
 328 This program is free software; you can redistribute it and/or modify it under the same terms as Perl itself.
 329
 330 =cut
 331
 332 1; # End of CPANPLUS::Dist::Gentoo