lib/Test/Valgrind.pm

   1 package Test::Valgrind;
   2
   3 use strict;
   4 use warnings;
   5
   6 use Carp qw/croak/;
   7 use POSIX qw/SIGTERM/;
   8 use Fcntl qw/F_SETFD/;
   9 use Test::Builder;
  10
  11 use Perl::Destruct::Level level => 3;
  12
  13 use Test::Valgrind::Suppressions;
  14
  15 =head1 NAME
  16
  17 Test::Valgrind - Test Perl code through valgrind.
  18
  19 =head1 VERSION
  20
  21 Version 0.07
  22
  23 =cut
  24
  25 our $VERSION = '0.07';
  26
  27 =head1 SYNOPSIS
  28
  29     use Test::More;
  30     eval 'use Test::Valgrind';
  31     plan skip_all => 'Test::Valgrind is required to test your distribution with valgrind' if $@;
  32
  33     # Code to inspect for memory leaks/errors.
  34
  35 =head1 DESCRIPTION
  36
  37 This module lets you run some code through the B<valgrind> memory debugger, to test it for memory errors and leaks. Just add C<use Test::Valgrind> at the beginning of the code you want to test. Behind the hood, C<Test::Valgrind::import> forks so that the child can basically C<exec 'valgrind', $^X, $0> (except that of course C<$0> isn't right there). The parent then parses the report output by valgrind and pass or fail tests accordingly.
  38
  39 You can also use it from the command-line to test a given script :
  40
  41     perl -MTest::Valgrind leaky.pl
  42
  43 Due to the nature of perl's memory allocator, this module can't track leaks of Perl objects. This includes non-mortalized scalars and memory cycles. However, it can track leaks of chunks of memory allocated in XS extensions with C<Newx> and friends or C<malloc>. As such, it's complementary to the other very good leak detectors listed in the L</SEE ALSO> section.
  44
  45 =head1 CONFIGURATION
  46
  47 You can pass parameters to C<import> as a list of key / value pairs, where valid keys are :
  48
  49 =over 4
  50
  51 =item *
  52
  53 C<< supp => $file >>
  54
  55 Also use suppressions from C<$file> besides perl's.
  56
  57 =item *
  58
  59 C<< no_supp => $bool >>
  60
  61 If true, do not use any suppressions.
  62
  63 =item *
  64
  65 C<< callers => $number >>
  66
  67 Specify the maximum stack depth studied when valgrind encounters an error. Raising this number improves granularity. Default is 12.
  68
  69 =item *
  70
  71 C<< extra => [ @args ] >>
  72
  73 Add C<@args> to valgrind parameters.
  74
  75 =item *
  76
  77 C<< diag => $bool >>
  78
  79 If true, print the raw output of valgrind as diagnostics (may be quite verbose).
  80
  81 =item *
  82
  83 C<< no_test => $bool >>
  84
  85 If true, do not actually output the plan and the tests results.
  86
  87 =item *
  88
  89 C<< cb => sub { my ($val, $name) = @_; ...; return $passed } >>
  90
  91 Specifies a subroutine to execute for each test instead of C<Test::More::is>. It receives the number of bytes leaked in C<$_[0]> and the test name in C<$_[1]>, and is expected to return true if the test passed and false otherwise. Defaults to
  92
  93     sub {
  94      is($_[0], 0, $_[1]);
  95      (defined $_[0] and $_[0] == 0) : 1 : 0
  96     }
  97
  98 =back
  99
 100 =cut
 101
 102 my $Test = Test::Builder->new;
 103
 104 my $run;
 105
 106 sub _counter {
 107  (defined $_[0] and $_[0] == 0) ? 1 : 0;
 108 }
 109
 110 sub _tester {
 111  $Test->is_num($_[0], 0, $_[1]);
 112  _counter(@_);
 113 }
 114
 115 sub import {
 116  shift;
 117  croak 'Optional arguments must be passed as key => value pairs' if @_ % 2;
 118  my %args = @_;
 119  if (!defined $args{run} && !$run) {
 120   my ($file, $pm, $next);
 121   my $l = 0;
 122   while ($l < 1000) {
 123    $next = (caller $l++)[1];
 124    last unless defined $next;
 125    next unless $next ne '-e' and $next !~ /^\s*\(\s*eval\s*\d*\s*\)\s*$/
 126                              and -f $next;
 127    if ($next =~ /\.pm$/) {
 128     $pm = $next;
 129    } else {
 130     $file = $next;
 131    }
 132   }
 133   unless (defined $file) {
 134    $file = $pm;
 135    return unless defined $pm;
 136   }
 137   my $callers = $args{callers};
 138   $callers = 12 unless defined $callers;
 139   $callers = int $callers;
 140   my $vg = Test::Valgrind::Suppressions::VG_PATH;
 141   if (!$vg || !-x $vg) {
 142    for (split /:/, $ENV{PATH}) {
 143     $_ .= '/valgrind';
 144     if (-x) {
 145      $vg = $_;
 146      last;
 147     }
 148    }
 149    if (!$vg) {
 150     $Test->skip_all('No valgrind executable could be found in your path');
 151     return;
 152    }
 153   }
 154   pipe my $ordr, my $owtr or die "pipe(\$ordr, \$owtr): $!";
 155   pipe my $vrdr, my $vwtr or die "pipe(\$vrdr, \$vwtr): $!";
 156   my $pid = fork;
 157   if (!defined $pid) {
 158    die "fork(): $!";
 159   } elsif ($pid == 0) {
 160    setpgrp 0, 0 or die "setpgrp(0, 0): $!";
 161    close $ordr or die "close(\$ordr): $!";
 162    open STDOUT, '>&=', $owtr or die "open(STDOUT, '>&=', \$owtr): $!";
 163    close $vrdr or die "close(\$vrdr): $!";
 164    fcntl $vwtr, F_SETFD, 0 or die "fcntl(\$vwtr, F_SETFD, 0): $!";
 165    my @args = (
 166     $vg,
 167     '--tool=memcheck',
 168     '--leak-check=full',
 169     '--leak-resolution=high',
 170     '--num-callers=' . $callers,
 171     '--error-limit=yes',
 172     '--log-fd=' . fileno($vwtr)
 173    );
 174    unless ($args{no_supp}) {
 175     for (Test::Valgrind::Suppressions::supp_path(), $args{supp}) {
 176      push @args, '--suppressions=' . $_ if $_;
 177     }
 178    }
 179    if (defined $args{extra} and ref $args{extra} eq 'ARRAY') {
 180     push @args, @{$args{extra}};
 181    }
 182    push @args, $^X;
 183    push @args, '-I' . $_ for @INC;
 184    push @args, '-MTest::Valgrind=run,1', $file;
 185    print STDOUT "valgrind @args\n";
 186    local $ENV{PERL_DESTRUCT_LEVEL} = 3;
 187    local $ENV{PERL_DL_NONLAZY} = 1;
 188    exec { $args[0] } @args;
 189    die "exec @args: $!";
 190   }
 191   local $SIG{INT} = sub { kill -(SIGTERM) => $pid };
 192   $Test->plan(tests => 5) unless $args{no_test} or defined $Test->has_plan;
 193   my @tests = (
 194    'errors',
 195    'definitely lost', 'indirectly lost', 'possibly lost', 'still reachable'
 196   );
 197   my %res = map { $_ => 0 } @tests;
 198   close $owtr or die "close(\$owtr): $!";
 199   close $vwtr or die "close(\$vwtr): $!";
 200   while (<$vrdr>) {
 201    $Test->diag($_) if $args{diag};
 202    if (/^=+\d+=+\s*FATAL\s*:\s*(.*)/) {
 203     chomp(my $err = $1);
 204     $Test->diag("Valgrind error: $err");
 205     $res{$_} = undef for @tests;
 206    }
 207    if (/ERROR\s+SUMMARY\s*:\s+(\d+)/) {
 208     $res{errors} = int $1;
 209    } elsif (/([a-z][a-z\s]*[a-z])\s*:\s*([\d.,]+)/) {
 210     my ($cat, $count) = ($1, $2);
 211     if (exists $res{$cat}) {
 212      $cat =~ s/\s+/ /g;
 213      $count =~ s/[.,]//g;
 214      $res{$cat} = int $count;
 215     }
 216    }
 217   }
 218   waitpid $pid, 0;
 219   $Test->diag(do { local $/; <$ordr> }) if $args{diag};
 220   close $ordr or die "close(\$ordr): $!";
 221   my $failed = 5;
 222   my $cb = ($args{no_test} ? \&_counter
 223                            : ($args{cb} ? $args{cb} : \&_tester));
 224   for (@tests) {
 225    $failed -= $cb->($res{$_}, 'valgrind ' . $_) ? 1 : 0;
 226   }
 227   exit $failed;
 228  } else {
 229   $run = 1;
 230  }
 231 }
 232
 233 =head1 CAVEATS
 234
 235 You can't use this module to test code given by the C<-e> command-line switch.
 236
 237 Perl 5.8 is notorious for leaking like there's no tomorrow, so the suppressions are very likely not to be very accurate on it. Anyhow, results will most likely be better if your perl is built with debugging enabled. Using the latest valgrind available will also help.
 238
 239 This module is not really secure. It's definitely not taint safe. That shouldn't be a problem for test files.
 240
 241 What your tests output to STDOUT is eaten unless you pass the C<diag> option, in which case it will be reprinted as diagnostics. STDERR is kept untouched.
 242
 243 =head1 DEPENDENCIES
 244
 245 Valgrind 3.1.0 (L<http://valgrind.org>).
 246
 247 L<Carp>, L<Fcntl>, L<POSIX> (core modules since perl 5) and L<Test::Builder> (since 5.6.2).
 248
 249 L<Perl::Destruct::Level>.
 250
 251 =head1 SEE ALSO
 252
 253 L<Devel::Leak>, L<Devel::LeakTrace>, L<Devel::LeakTrace::Fast>.
 254
 255 =head1 AUTHOR
 256
 257 Vincent Pit, C<< <perl at profvince.com> >>, L<http://www.profvince.com>.
 258
 259 You can contact me by mail or on #perl @ FreeNode (vincent or Prof_Vince).
 260
 261 =head1 BUGS
 262
 263 Please report any bugs or feature requests to C<bug-test-valgrind at rt.cpan.org>, or through the web interface at L<http://rt.cpan.org/NoAuth/ReportBug.html?Queue=Test-Valgrind>.  I will be notified, and then you'll automatically be notified of progress on your bug as I make changes.
 264
 265 =head1 SUPPORT
 266
 267 You can find documentation for this module with the perldoc command.
 268
 269     perldoc Test::Valgrind
 270
 271 =head1 ACKNOWLEDGEMENTS
 272
 273 Rafaël Garcia-Suarez, for writing and instructing me about the existence of L<Perl::Destruct::Level> (Elizabeth Mattijsen is a close second).
 274
 275 H.Merijn Brand, for daring to test this thing.
 276
 277 =head1 COPYRIGHT & LICENSE
 278
 279 Copyright 2008 Vincent Pit, all rights reserved.
 280
 281 This program is free software; you can redistribute it and/or modify it under the same terms as Perl itself.
 282
 283 =cut
 284
 285 1; # End of Test::Valgrind