TikZ/Set.pm

   1 package LaTeX::TikZ::Set;
   2
   3 use strict;
   4 use warnings;
   5
   6 =head1 NAME
   7
   8 LaTeX::TikZ::Set - Base role for LaTeX::TikZ set objects.
   9
  10 =head1 VERSION
  11
  12 Version 0.01
  13
  14 =cut
  15
  16 our $VERSION = '0.01';
  17
  18 use Scope::Guard ();
  19
  20 use LaTeX::TikZ::Scope;
  21
  22 use LaTeX::TikZ::Tools;
  23
  24 use Any::Moose 'Role';
  25
  26 requires qw(
  27  draw
  28 );
  29
  30 has '_mods' => (
  31  is       => 'ro',
  32  isa      => 'Maybe[ArrayRef[LaTeX::TikZ::Mod]]',
  33  init_arg => 'mods',
  34  default  => sub { [ ] },
  35  lazy     => 1,
  36 );
  37
  38 sub mods { @{$_[0]->_mods} }
  39
  40 my $ltm_tc  = LaTeX::TikZ::Tools::type_constraint('LaTeX::TikZ::Mod');
  41 my $ltml_tc = LaTeX::TikZ::Tools::type_constraint('LaTeX::TikZ::Mod::Layer');
  42 my $ltmc_tc = LaTeX::TikZ::Tools::type_constraint('LaTeX::TikZ::Mod::Clip');
  43
  44 sub mod {
  45  my $set = shift;
  46
  47  my @mods = map $ltm_tc->coerce($_), @_;
  48  $ltm_tc->assert_valid($_) for @mods;
  49
  50  push @{$set->_mods}, @mods;
  51
  52  $set;
  53 }
  54
  55 {
  56  our %mods;
  57  our $last_mod = 0;
  58
  59  around 'draw' => sub {
  60   my ($orig, $set, $tikz) = @_;
  61
  62   local $last_mod = $last_mod;
  63
  64   # Save a deep copy
  65   my %saved_idx = map { $_ => $#{$mods{$_}} } keys %mods;
  66   my $guard     = Scope::Guard->new(sub {
  67    for (keys %mods) {
  68     if (exists $saved_idx{$_}) {
  69      $#{$mods{$_}} = $saved_idx{$_};
  70     } else {
  71      delete $mods{$_};
  72     }
  73    }
  74   });
  75
  76   my (@mods, $last_layer);
  77 MOD:
  78   for my $mod ($set->mods) {
  79    my $is_layer = $ltml_tc->check($mod);
  80    $last_layer  = $mod if $is_layer;
  81    my $tag = $mod->tag;
  82    my $old = $mods{$tag} || [];
  83    for (@$old) {
  84     next MOD if $_->[0]->cover($mod);
  85    }
  86    push @{$mods{$tag}}, [ $mod, $last_mod++, $is_layer ];
  87    push @mods,          $mod;
  88   }
  89
  90   if ($last_layer) {
  91    # Clips and mods don't propagate through layers. Hence if a layer is set,
  92    # force their reuse.
  93    @mods = $last_layer;
  94    push @mods, map $_->[0],
  95                 sort { $a->[1] <=> $b->[1] }
  96                  grep !$_->[2],
  97                   map @$_,
  98                    values %mods;
  99   }
 100
 101   my $body = $set->$orig($tikz);
 102
 103   if (@mods) {
 104    $body = LaTeX::TikZ::Scope->new
 105                              ->mod(map $_->apply($tikz), @mods)
 106                              ->body($body);
 107   }
 108
 109   $body;
 110  };
 111 }
 112
 113 sub layer {
 114  return $_[0] unless @_ > 1;
 115
 116  my $layer = $_[1];
 117
 118  $_[0]->mod(
 119   $ltml_tc->check($layer) ? $layer
 120                           : LaTeX::TikZ::Mod::Layer->new(name => $layer)
 121  )
 122 }
 123
 124 sub clip {
 125  return $_[0] unless @_ > 1;
 126
 127  $_[0]->mod(
 128   map {
 129    $ltmc_tc->check($_) ? $_ : LaTeX::TikZ::Mod::Clip->new(clip => $_)
 130   } @_[1 .. $#_]
 131  )
 132 }
 133
 134 =head1 AUTHOR
 135
 136 Vincent Pit, C<< <perl at profvince.com> >>, L<http://www.profvince.com>.
 137
 138 You can contact me by mail or on C<irc.perl.org> (vincent).
 139
 140 =head1 BUGS
 141
 142 Please report any bugs or feature requests to C<bug-latex-tikz at rt.cpan.org>, or through the web interface at L<http://rt.cpan.org/NoAuth/ReportBug.html?Queue=LaTeX-TikZ>.
 143 I will be notified, and then you'll automatically be notified of progress on your bug as I make changes.
 144
 145 =head1 SUPPORT
 146
 147 You can find documentation for this module with the perldoc command.
 148
 149     perldoc LaTeX::TikZ
 150
 151 =head1 COPYRIGHT & LICENSE
 152
 153 Copyright 2010 Vincent Pit, all rights reserved.
 154
 155 This program is free software; you can redistribute it and/or modify it under the same terms as Perl itself.
 156
 157 =cut
 158
 159 1; # End of LaTeX::TikZ::Set