Sub/Nary.pm

   1 package Sub::Nary;
   2
   3 use 5.008001;
   4
   5 use strict;
   6 use warnings;
   7
   8 use Carp qw/croak/;
   9 use List::Util qw/reduce sum/;
  10
  11 use B qw/class ppname svref_2object OPf_KIDS/;
  12
  13 =head1 NAME
  14
  15 Sub::Nary - Try to count how many elements a subroutine can return in list context.
  16
  17 =head1 VERSION
  18
  19 Version 0.02
  20
  21 =cut
  22
  23 our $VERSION;
  24 BEGIN {
  25  $VERSION  = '0.02';
  26 }
  27
  28 =head1 SYNOPSIS
  29
  30     use Sub::Nary;
  31
  32     my $sn = Sub::Nary->new();
  33     my $r  = $sn->nary(\&hlagh);
  34
  35 =head1 DESCRIPTION
  36
  37 This module uses the L<B> framework to walk into subroutines and try to guess how many scalars are likely to be returned in list context. It's not always possible to give a definitive answer to this question at compile time, so the results are given in terms of "probability of return" (to be understood in a sense described below).
  38
  39 =head1 METHODS
  40
  41 =head2 C<new>
  42
  43 The usual constructor. Currently takes no argument.
  44
  45 =head2 C<nary $coderef>
  46
  47 Takes a code reference to a named or anonymous subroutine, and returns a hash reference whose keys are the possible numbers of returning scalars, and the corresponding values the "probability" to get them. The special key C<'list'> is used to denote a possibly infinite number of returned arguments. The return value hence would look at
  48
  49     { 1 => 0.2, 2 => 0.4, 4 => 0.3, list => 0.1 }
  50
  51 that is, we should get C<1> scalar C<1> time over C<5> and so on. The sum of all values is C<1>. The returned result, and all the results obtained from intermediate subs, are cached into the object.
  52
  53 =head2 C<flush>
  54
  55 Flushes the L<Sub::Nary> object cache. Returns the object itself.
  56
  57 =head1 PROBABILITY OF RETURN
  58
  59 The probability is computed as such :
  60
  61 =over 4
  62
  63 =item * All the returning points in the same subroutine (i.e. all the explicit C<return> and the last computed value) are considered equally possible.
  64
  65 For example, the subroutine
  66
  67     sub simple {
  68      if (rand < 0.1) {
  69       return 1;
  70      } else {
  71       return 2, 3;
  72      }
  73     }
  74
  75 is seen returning one or two arguments each with probability C<1/2>.
  76 As for
  77
  78     sub hlagh {
  79      my $x = rand;
  80      if ($x < 0.1) {
  81       return 1, 2, 3;
  82      } elsif ($x > 0.9) {
  83       return 4, 5;
  84      }
  85     }
  86
  87 it is considered to return C<1> (when the two tests fail, the last computed value is returned, which here is C<< $x > 0.9 >> evaluated in the scalar context of the test), C<2> or C<3> arguments each with probability C<1/3>.
  88
  89 =item * The total probability law for a given returning point is the convolution product of the probabilities of its list elements.
  90
  91 As such,
  92
  93     sub notsosimple {
  94      return 1, simple(), 2
  95     }
  96
  97 returns C<3> or C<4> arguments with probability C<1/2> ; and
  98
  99     sub double {
 100      return simple(), simple()
 101     }
 102
 103 never returns C<1> argument but returns C<2> with probability C<1/2 * 1/2 = 1/4>, C<3> with probability C<1/2 * 1/2 + 1/2 * 1/2 = 1/2> and C<4> with probability C<1/4> too.
 104
 105 =item * If a core function may return different numbers of scalars, each kind is considered equally possible.
 106
 107 For example, C<stat> returns C<13> elements on success and C<0> on error. The according probability will then be C<< { 0 => 0.5, 13 => 0.5 } >>.
 108
 109 =item * The C<list> state is absorbing in regard of all the other ones.
 110
 111 This is just a pedantic way to say that "list + fixed length = list".
 112 That's why
 113
 114     sub listy {
 115      return 1, simple(), @_
 116     }
 117
 118 is considered as always returning an unbounded list.
 119
 120 Also, the convolution law does not behave the same when C<list> elements are involved : in the following example,
 121
 122     sub oneorlist {
 123      if (rand < 0.1) {
 124       return 1
 125      } else {
 126       return @_
 127      }
 128     }
 129
 130     sub composed {
 131      return oneorlist(), oneorlist()
 132     }
 133
 134 C<composed> returns C<2> scalars with probability C<1/2 * 1/2 = 1/4> and a C<list> with probability C<3/4>.
 135
 136 =back
 137
 138 =cut
 139
 140 BEGIN {
 141  require XSLoader;
 142  XSLoader::load(__PACKAGE__, $VERSION);
 143 }
 144
 145 sub _check_self {
 146  croak 'First argument isn\'t a valid ' . __PACKAGE__ . ' object'
 147   unless ref $_[0] and $_[0]->isa(__PACKAGE__);
 148 }
 149
 150 sub new {
 151  my $class = shift;
 152  $class = ref($class) || $class || __PACKAGE__;
 153  bless { cache => { } }, $class;
 154 }
 155
 156 sub flush {
 157  my $self = shift;
 158  _check_self($self);
 159  $self->{cache} = { };
 160  $self;
 161 }
 162
 163 sub nary {
 164  my $self = shift;
 165  my $sub  = shift;
 166
 167  $self->{cv} = [ ];
 168  return $self->enter(svref_2object($sub));
 169 }
 170
 171 sub name ($) {
 172  my $n = $_[0]->name;
 173  $n eq 'null' ? substr(ppname($_[0]->targ), 3) : $n
 174 }
 175
 176 sub combine {
 177  reduce {{
 178   my %res;
 179   my $la = delete $a->{list};
 180   my $lb = delete $b->{list};
 181   if (defined $la || defined $lb) {
 182    $la ||= 0;
 183    $lb ||= 0;
 184    $res{list} = $la + $lb - $la * $lb;
 185   }
 186   while (my ($ka, $va) = each %$a) {
 187    $ka = int $ka;
 188    while (my ($kb, $vb) = each %$b) {
 189     my $key = $ka + int $kb;
 190     $res{$key} += $va * $vb;
 191    }
 192   }
 193   \%res
 194  }} map { (ref) ? $_ : { $_ => 1 } } grep defined, @_;
 195 }
 196
 197 sub add {
 198  reduce {
 199   $a->{$_} += $b->{$_} for keys %$b;
 200   $a
 201  } map { (ref) ? $_ : { $_ => 1 } } grep defined, @_;
 202 }
 203
 204 my %ops;
 205
 206 $ops{$_} = 1      for scalops;
 207 $ops{$_} = 0      for qw/stub nextstate/;
 208 $ops{$_} = 1      for qw/padsv/;
 209 $ops{$_} = 'list' for qw/padav/;
 210 $ops{$_} = 'list' for qw/padhv rv2hv/;
 211 $ops{$_} = 'list' for qw/padany match entereval readline/;
 212
 213 $ops{each}      = { 0 => 0.5, 2 => 0.5 };
 214 $ops{stat}      = { 0 => 0.5, 13 => 0.5 };
 215
 216 $ops{caller}    = sub { my @a = caller 0; scalar @a }->();
 217 $ops{localtime} = do { my @a = localtime; scalar @a };
 218 $ops{gmtime}    = do { my @a = gmtime; scalar @a };
 219
 220 $ops{$_} = { 0 => 0.5, 10 => 0.5 } for map "gpw$_", qw/nam uid ent/;
 221 $ops{$_} = { 0 => 0.5, 4 => 0.5 }  for map "ggr$_", qw/nam gid ent/;
 222 $ops{$_} = 'list'                  for qw/ghbyname ghbyaddr ghostent/;
 223 $ops{$_} = { 0 => 0.5, 4 => 0.5 }  for qw/gnbyname gnbyaddr gnetent/;
 224 $ops{$_} = { 0 => 0.5, 3 => 0.5 }  for qw/gpbyname gpbynumber gprotoent/;
 225 $ops{$_} = { 0 => 0.5, 4 => 0.5 }  for qw/gsbyname gsbyport gservent/;
 226
 227 sub enter {
 228  my ($self, $cv) = @_;
 229
 230  return 'list' if class($cv) ne 'CV';
 231  my $op  = $cv->ROOT;
 232  my $tag = tag($op);
 233
 234  return { %{$self->{cache}->{$tag}} } if exists $self->{cache}->{$tag};
 235
 236  # Anything can happen with recursion
 237  for (@{$self->{cv}}) {
 238   return 'list' if $tag == tag($_->ROOT);
 239  }
 240
 241  unshift @{$self->{cv}}, $cv;
 242  (my $r, undef) = $self->expect_any($op->first);
 243  shift @{$self->{cv}};
 244
 245  $r = { $r => 1} unless ref $r;
 246  my $total = sum values %$r;
 247  $r = { map { $_ => $r->{$_} / $total } keys %$r };
 248  $self->{cache}->{$tag} = { %$r };
 249  return $r;
 250 }
 251
 252 sub expect_return {
 253  my ($self, $op) = @_;
 254
 255  return ($self->expect_list($op))[0] => 1 if name($op) eq 'return';
 256
 257  if ($op->flags & OPf_KIDS) {
 258   for ($op = $op->first; not null $op; $op = $op->sibling) {
 259    my ($p, $r) = $self->expect_return($op);
 260    return $p => 1 if $r;
 261   }
 262  }
 263
 264  return;
 265 }
 266
 267 sub expect_list {
 268  my ($self, $op) = @_;
 269
 270  my $n = name($op);
 271  my $meth = $self->can('pp_' . $n);
 272  return $self->$meth($op) if $meth;
 273  if (exists $ops{$n}) {
 274   my $r = $ops{$n};
 275   $r = { %$r } if ref $r eq 'HASH';
 276   return $r => 0;
 277  }
 278
 279  if ($op->flags & OPf_KIDS) {
 280   my @res = (0);
 281   my ($p, $r);
 282   for ($op = $op->first; not null $op; $op = $op->sibling) {
 283    my $n = name($op);
 284    next if $n eq 'pushmark';
 285    if ($n eq 'nextstate'
 286        and not null(($op = $op->sibling)->sibling)) {
 287     ($p, $r) = $self->expect_return($op);
 288     return $p => 1 if $r;
 289    } else {
 290     ($p, $r) = $self->expect_any($op);
 291     return $p => 1 if $r;
 292     push @res, $p;
 293    }
 294   }
 295   return (combine @res) => 0;
 296  }
 297
 298  return;
 299 }
 300
 301 sub expect_any {
 302  my ($self, $op) = @_;
 303
 304  return ($self->expect_list($op))[0] => 1 if name($op) eq 'return';
 305
 306  if (class($op) eq 'LOGOP' and not null $op->first) {
 307   my @res;
 308   my ($p, $r);
 309
 310   my $op   = $op->first;
 311   ($p, $r) = $self->expect_return($op);
 312   return $p => 1 if $r;
 313
 314   $op = $op->sibling;
 315   push @res, ($self->expect_any($op))[0];
 316
 317   # If the logop has no else branch, it can also return the *scalar* result of
 318   # the conditional
 319   $op = $op->sibling;
 320   if (null $op) {
 321    push @res, 1;
 322   } else {
 323    push @res, ($self->expect_any($op))[0];
 324   }
 325
 326   return (add @res) => 0;
 327  }
 328
 329  return $self->expect_list($op);
 330 }
 331
 332 # Stolen from B::Deparse
 333
 334 sub padval { $_[0]->{cv}->[0]->PADLIST->ARRAYelt(1)->ARRAYelt($_[1]) }
 335
 336 sub gv_or_padgv {
 337  my ($self, $op) = @_;
 338  if (class($op) eq 'PADOP') {
 339   return $self->padval($op->padix)
 340  } else { # class($op) eq "SVOP"
 341   return $op->gv;
 342  }
 343 }
 344
 345 sub const_sv {
 346  my ($self, $op) = @_;
 347  my $sv = $op->sv;
 348  # the constant could be in the pad (under useithreads)
 349  $sv = $self->padval($op->targ) unless $$sv;
 350  return $sv;
 351 }
 352
 353 sub pp_entersub {
 354  my ($self, $op, $exp) = @_;
 355
 356  my $next = $op;
 357  while ($next->flags & OPf_KIDS) {
 358   $next = $next->first;
 359  }
 360  while (not null $next) {
 361   $op = $next;
 362   my ($p, $r) = $self->expect_return($op, $exp);
 363   return $p => 1 if $r;
 364   $next = $op->sibling;
 365  }
 366
 367  if (name($op) eq 'rv2cv') {
 368   my $n;
 369   do {
 370    $op = $op->first;
 371    my $next = $op->sibling;
 372    while (not null $next) {
 373     $op   = $next;
 374     $next = $next->sibling;
 375    }
 376    $n  = name($op)
 377   } while ($op->flags & OPf_KIDS and { map { $_ => 1 } qw/null leave/ }->{$n});
 378   return 'list' unless { map { $_ => 1 } qw/gv refgen/ }->{$n};
 379   local $self->{sub} = 1;
 380   return $self->expect_any($op, $exp);
 381  } else {
 382   # Method call ?
 383   return 'list';
 384  }
 385 }
 386
 387 sub pp_gv {
 388  my ($self, $op) = @_;
 389
 390  return $self->{sub} ? $self->enter($self->gv_or_padgv($op)->CV) : 1
 391 }
 392
 393 sub pp_anoncode {
 394  my ($self, $op) = @_;
 395
 396  return $self->{sub} ? $self->enter($self->const_sv($op)) : 1
 397 }
 398
 399 sub pp_goto {
 400  my ($self, $op) = @_;
 401
 402  my $n = name($op);
 403  while ($op->flags & OPf_KIDS) {
 404   my $nop = $op->first;
 405   my $nn  = name($nop);
 406   if ($nn eq 'pushmark') {
 407    $nop = $nop->sibling;
 408    $nn  = name($nop);
 409   }
 410   if ($n eq 'rv2cv' and $nn eq 'gv') {
 411    return $self->enter($self->gv_or_padgv($nop)->CV);
 412   }
 413   $op = $nop;
 414   $n  = $nn;
 415  }
 416
 417  return 'list';
 418 }
 419
 420 sub pp_const {
 421  my ($self, $op) = @_;
 422
 423  my $sv = $self->const_sv($op);
 424  my $c = class($sv);
 425  if ($c eq 'AV') {
 426   return $sv->FILL + 1;
 427  } elsif ($c eq 'HV') {
 428   return 2 * $sv->FILL;
 429  }
 430
 431  return 1;
 432 }
 433
 434 sub pp_aslice { $_[0]->expect_any($_[1]->first->sibling) }
 435
 436 sub pp_hslice;
 437 *pp_hslice = *pp_aslice{CODE};
 438
 439 sub pp_lslice { $_[0]->expect_any($_[1]->first) }
 440
 441 sub pp_rv2av {
 442  my ($self, $op) = @_;
 443  $op = $op->first;
 444
 445  return (name($op) eq 'const') ? $self->expect_any($op) : 'list';
 446 }
 447
 448 sub pp_aassign {
 449  my ($self, $op) = @_;
 450
 451  $op = $op->first;
 452
 453  # Can't assign to return
 454  my ($p, $r) = $self->expect_list($op->sibling);
 455  return $p => 0 if not exists $p->{list};
 456
 457  $self->expect_any($op);
 458 }
 459
 460 sub pp_leaveloop { $_[0]->expect_return($_[1]->first->sibling) }
 461
 462 sub pp_flip {
 463  my ($self, $op) = @_;
 464
 465  $op = $op->first;
 466  return 'list' if name($op) ne 'range';
 467
 468  my $begin = $op->first;
 469  if (name($begin) eq 'const') {
 470   my $end = $begin->sibling;
 471   if (name($end) eq 'const') {
 472    $begin  = $self->const_sv($begin);
 473    $end    = $self->const_sv($end);
 474    no warnings 'numeric';
 475    return int(${$end->object_2svref}) - int(${$begin->object_2svref}) + 1;
 476   } else {
 477    my ($p, $r) = $self->expect_return($end);
 478    return $p => 1 if $r;
 479   }
 480  } else {
 481   my ($p, $r) = $self->expect_return($begin);
 482   return $p => 1 if $r;
 483  }
 484
 485  return 'list'
 486 }
 487
 488 =head1 EXPORT
 489
 490 An object-oriented module shouldn't export any function, and so does this one.
 491
 492 =head1 CAVEATS
 493
 494 The algorithm may be pessimistic (things seen as C<list> while they are of fixed length) but not optimistic (the opposite, duh).
 495
 496 C<wantarray> isn't specialized when encountered in the optree.
 497
 498 =head1 DEPENDENCIES
 499
 500 L<perl> 5.8.1.
 501
 502 L<Carp> (standard since perl 5), L<B> (since perl 5.005), L<XSLoader> (since perl 5.006) and L<List::Util> (since perl 5.007003).
 503
 504 =head1 AUTHOR
 505
 506 Vincent Pit, C<< <perl at profvince.com> >>, L<http://www.profvince.com>.
 507
 508 You can contact me by mail or on #perl @ FreeNode (vincent or Prof_Vince).
 509
 510 =head1 BUGS
 511
 512 Please report any bugs or feature requests to C<bug-b-nary at rt.cpan.org>, or through the web interface at L<http://rt.cpan.org/NoAuth/ReportBug.html?Queue=Sub-Nary>.  I will be notified, and then you'll automatically be notified of progress on your bug as I make changes.
 513
 514 =head1 SUPPORT
 515
 516 You can find documentation for this module with the perldoc command.
 517
 518     perldoc Sub::Nary
 519
 520 Tests code coverage report is available at L<http://www.profvince.com/perl/cover/Sub-Nary>.
 521
 522 =head1 ACKNOWLEDGEMENTS
 523
 524 Thanks to Sebastien Aperghis-Tramoni for helping to name this module.
 525
 526 =head1 COPYRIGHT & LICENSE
 527
 528 Copyright 2008 Vincent Pit, all rights reserved.
 529
 530 This program is free software; you can redistribute it and/or modify it under the same terms as Perl itself.
 531
 532 =cut
 533
 534 1; # End of Sub::Nary