README

   1 NAME
   2     Variable::Magic - Associate user-defined magic to variables from Perl.
   3
   4 VERSION
   5     Version 0.33
   6
   7 SYNOPSIS
   8         use Variable::Magic qw/wizard cast VMG_OP_INFO_NAME/;
   9
  10         { # A variable tracer
  11          my $wiz = wizard set  => sub { print "now set to ${$_[0]}!\n" },
  12                           free => sub { print "destroyed!\n" };
  13
  14          my $a = 1;
  15          cast $a, $wiz;
  16          $a = 2;        # "now set to 2!"
  17         }               # "destroyed!"
  18
  19         { # A hash with a default value
  20          my $wiz = wizard data     => sub { $_[1] },
  21                           fetch    => sub { $_[2] = $_[1] unless exists $_[0]->{$_[2]}; () },
  22                           store    => sub { print "key $_[2] stored in $_[-1]\n" },
  23                           copy_key => 1,
  24                           op_info  => VMG_OP_INFO_NAME;
  25
  26          my %h = (_default => 0, apple => 2);
  27          cast %h, $wiz, '_default';
  28          print $h{banana}, "\n"; # "0", because the 'banana' key doesn't exist in %h
  29          $h{pear} = 1;           # "key pear stored in helem"
  30         }
  31
  32 DESCRIPTION
  33     Magic is Perl way of enhancing objects. This mechanism lets the user add
  34     extra data to any variable and hook syntaxical operations (such as
  35     access, assignment or destruction) that can be applied to it. With this
  36     module, you can add your own magic to any variable without having to
  37     write a single line of XS.
  38
  39     You'll realize that these magic variables look a lot like tied
  40     variables. It's not surprising, as tied variables are implemented as a
  41     special kind of magic, just like any 'irregular' Perl variable : scalars
  42     like $!, $( or $^W, the %ENV and %SIG hashes, the @ISA array, "vec()"
  43     and "substr()" lvalues, threads::shared variables... They all share the
  44     same underlying C API, and this module gives you direct access to it.
  45
  46     Still, the magic made available by this module differs from tieing and
  47     overloading in several ways :
  48
  49     *   It isn't copied on assignment.
  50
  51         You attach it to variables, not values (as for blessed references).
  52
  53     *   It doesn't replace the original semantics.
  54
  55         Magic callbacks usually trigger before the original action take
  56         place, and can't prevent it to happen. This also makes catching
  57         individual events easier than with "tie", where you have to provide
  58         fallbacks methods for all actions by usually inheriting from the
  59         correct "Tie::Std*" class and overriding individual methods in your
  60         own class.
  61
  62     *   It's type-agnostic.
  63
  64         The same magic can be applied on scalars, arrays, hashes, subs or
  65         globs. But the same hook (see below for a list) may trigger
  66         differently depending on the the type of the variable.
  67
  68     *   It's mostly invisible at the Perl level.
  69
  70         Magical and non-magical variables cannot be distinguished with
  71         "ref", "tied" or another trick.
  72
  73     *   It's notably faster.
  74
  75         Mainly because perl's way of handling magic is lighter by nature,
  76         and because there's no need for any method resolution. Also, since
  77         you don't have to reimplement all the variable semantics, you only
  78         pay for what you actually use.
  79
  80     The operations that can be overloaded are :
  81
  82     *   "get"
  83
  84         This magic is invoked when the variable is evaluated (does not
  85         include array/hash subscripts and slices).
  86
  87     *   "set"
  88
  89         This one is triggered each time the value of the variable changes
  90         (includes array/hash subscripts and slices).
  91
  92     *   "len"
  93
  94         This magic is a little special : it is called when the 'size' or the
  95         'length' of the variable has to be known by Perl. Typically, it's
  96         the magic involved when an array is evaluated in scalar context, but
  97         also on array assignment and loops ("for", "map" or "grep"). The
  98         callback has then to return the length as an integer.
  99
 100     *   "clear"
 101
 102         This magic is invoked when the variable is reset, such as when an
 103         array is emptied. Please note that this is different from undefining
 104         the variable, even though the magic is called when the clearing is a
 105         result of the undefine (e.g. for an array, but actually a bug
 106         prevent it to work before perl 5.9.5 - see the history).
 107
 108     *   "free"
 109
 110         This one can be considered as an object destructor. It happens when
 111         the variable goes out of scope, but not when it is undefined.
 112
 113     *   "copy"
 114
 115         This magic only applies to tied arrays and hashes. It fires when you
 116         try to access or change their elements. It is available on your perl
 117         iff "MGf_COPY" is true.
 118
 119     *   "dup"
 120
 121         Invoked when the variable is cloned across threads. Currently not
 122         available.
 123
 124     *   "local"
 125
 126         When this magic is set on a variable, all subsequent localizations
 127         of the variable will trigger the callback. It is available on your
 128         perl iff "MGf_LOCAL" is true.
 129
 130     The following actions only apply to hashes and are available iff
 131     "VMG_UVAR" is true. They are referred to as "uvar" magics.
 132
 133     *   "fetch"
 134
 135         This magic happens each time an element is fetched from the hash.
 136
 137     *   "store"
 138
 139         This one is called when an element is stored into the hash.
 140
 141     *   "exists"
 142
 143         This magic fires when a key is tested for existence in the hash.
 144
 145     *   "delete"
 146
 147         This last one triggers when a key is deleted in the hash, regardless
 148         of whether the key actually exists in it.
 149
 150     You can refer to the tests to have more insight of where the different
 151     magics are invoked.
 152
 153     To prevent any clash between different magics defined with this module,
 154     an unique numerical signature is attached to each kind of magic (i.e.
 155     each set of callbacks for magic operations). At the C level, magic
 156     tokens owned by magic created by this module have their "mg->mg_private"
 157     field set to 0x3891 or 0x3892, so please don't use these magic (sic)
 158     numbers in other extensions.
 159
 160 FUNCTIONS
 161   "wizard"
 162         wizard sig      => ...,
 163                data     => sub { ... },
 164                get      => sub { my ($ref, $data [, $op]) = @_; ... },
 165                set      => sub { my ($ref, $data [, $op]) = @_; ... },
 166                len      => sub { my ($ref, $data, $len [, $op]) = @_; ... ; return $newlen; },
 167                clear    => sub { my ($ref, $data [, $op]) = @_; ... },
 168                free     => sub { my ($ref, $data [, $op]) = @_, ... },
 169                copy     => sub { my ($ref, $data, $key, $elt [, $op]) = @_; ... },
 170                local    => sub { my ($ref, $data [, $op]) = @_; ... },
 171                fetch    => sub { my ($ref, $data, $key [, $op]) = @_; ... },
 172                store    => sub { my ($ref, $data, $key [, $op]) = @_; ... },
 173                exists   => sub { my ($ref, $data, $key [, $op]) = @_; ... },
 174                delete   => sub { my ($ref, $data, $key [, $op]) = @_; ... },
 175                copy_key => $bool,
 176                op_info  => [ 0 | VMG_OP_INFO_NAME | VMG_OP_INFO_OBJECT ]
 177
 178     This function creates a 'wizard', an opaque type that holds the magic
 179     information. It takes a list of keys / values as argument, whose keys
 180     can be :
 181
 182     *   "sig"
 183
 184         The numerical signature. If not specified or undefined, a random
 185         signature is generated. If the signature matches an already defined
 186         magic, then the existant magic object is returned.
 187
 188     *   "data"
 189
 190         A code reference to a private data constructor. It is called each
 191         time this magic is cast on a variable, and the scalar returned is
 192         used as private data storage for it. $_[0] is a reference to the
 193         magic object and @_[1 .. @_-1] are all extra arguments that were
 194         passed to "cast".
 195
 196     *   "get", "set", "len", "clear", "free", "copy", "local", "fetch",
 197         "store", "exists" and "delete"
 198
 199         Code references to the corresponding magic callbacks. You don't have
 200         to specify all of them : the magic associated with undefined entries
 201         simply won't be hooked. In those callbacks, $_[0] is always a
 202         reference to the magic object and $_[1] is always the private data
 203         (or "undef" when no private data constructor was supplied).
 204
 205         Moreover, when you pass "op_info => $num" to "wizard", the last
 206         element of @_ will be the current op name if "$num ==
 207         VMG_OP_INFO_NAME" and a "B::OP" object representing the current op
 208         if "$num == VMG_OP_INFO_OBJECT". Both have a performance hit, but
 209         just getting the name is lighter than getting the op object.
 210
 211         Other arguments are specific to the magic hooked :
 212
 213         *       "len"
 214
 215                 When the variable is an array or a scalar, $_[2] contains
 216                 the non-magical length. The callback can return the new
 217                 scalar or array length to use, or "undef" to default to the
 218                 normal length.
 219
 220         *       "copy"
 221
 222                 $_[2] is a either a copy or an alias of the current key,
 223                 which means that it is useless to try to change or cast
 224                 magic on it. $_[3] is an alias to the current element (i.e.
 225                 the value).
 226
 227         *       "fetch", "store", "exists" and "delete"
 228
 229                 $_[2] is an alias to the current key. Nothing prevents you
 230                 from changing it, but be aware that there lurk dangerous
 231                 side effects. For example, it may righteously be readonly if
 232                 the key was a bareword. You can get a copy instead by
 233                 passing "copy_key => 1" to "wizard", which allows you to
 234                 safely assign to $_[2] in order to e.g. redirect the action
 235                 to another key. This however has a little performance
 236                 drawback because of the copy.
 237
 238         All the callbacks are expected to return an integer, which is passed
 239         straight to the perl magic API. However, only the return value of
 240         the "len" callback currently holds a meaning.
 241
 242         # A simple scalar tracer
 243         my $wiz = wizard get  => sub { print STDERR "got ${$_[0]}\n" },
 244                          set  => sub { print STDERR "set to ${$_[0]}\n" },
 245                          free => sub { print STDERR "${$_[0]} was deleted\n" }
 246
 247     Note that "free" callbacks are *never* called during global destruction,
 248     as there's no way to ensure that the wizard and the "free" callback
 249     weren't destroyed before the variable.
 250
 251   "gensig"
 252     With this tool, you can manually generate random magic signature between
 253     SIG_MIN and SIG_MAX inclusive. That's the way "wizard" creates them when
 254     no signature is supplied.
 255
 256         # Generate a signature
 257         my $sig = gensig;
 258
 259   "getsig"
 260         getsig $wiz
 261
 262     This accessor returns the magic signature of this wizard.
 263
 264         # Get $wiz signature
 265         my $sig = getsig $wiz;
 266
 267   "cast"
 268         cast [$@%&*]var, [$wiz|$sig], ...
 269
 270     This function associates $wiz magic to the variable supplied, without
 271     overwriting any other kind of magic. You can also supply the numeric
 272     signature $sig instead of $wiz. It returns true on success or when $wiz
 273     magic is already present, and croaks on error or when no magic
 274     corresponds to the given signature (in case a $sig was supplied). All
 275     extra arguments specified after $wiz are passed to the private data
 276     constructor in @_[1 .. @_-1]. If the variable isn't a hash, any "uvar"
 277     callback of the wizard is safely ignored.
 278
 279         # Casts $wiz onto $x, and pass '1' to the data constructor.
 280         my $x;
 281         cast $x, $wiz, 1;
 282
 283     The "var" argument can be an array or hash value. Magic for those
 284     behaves like for any other scalar, except that it is dispelled when the
 285     entry is deleted from the container. For example, if you want to call
 286     "POSIX::tzset" each time the 'TZ' environment variable is changed in
 287     %ENV, you can use :
 288
 289         use POSIX;
 290         cast $ENV{TZ}, wizard set => sub { POSIX::tzset(); () };
 291
 292     If you want to overcome the possible deletion of the 'TZ' entry, you
 293     have no choice but to rely on "store" uvar magic.
 294
 295     "cast" can be called from any magical callback, and in particular from
 296     "data". This allows you to recursively cast magic on datastructures :
 297
 298         my $wiz;
 299         $wiz = wizard
 300                 data => sub {
 301                  my ($var, $depth) = @_;
 302                  $depth ||= 0;
 303                  my $r = ref $var;
 304                  if ($r eq 'ARRAY') {
 305                   &cast((ref() ? $_ : \$_), $wiz, $depth + 1) for @$var;
 306                  } elsif ($r eq 'HASH') {
 307                   &cast((ref() ? $_ : \$_), $wiz, $depth + 1) for values %$var;
 308                  }
 309                  return $depth;
 310                 },
 311                 free => sub {
 312                  my ($var, $depth) = @_;
 313                  my $r = ref $var;
 314                  print "free $r at depth $depth\n";
 315                  ();
 316                 };
 317
 318         {
 319          my %h = (
 320           a => [ 1, 2 ],
 321           b => { c => 3 }
 322          );
 323          cast %h, $wiz;
 324         }
 325
 326     When %h goes out of scope, this will print something among the lines of
 327     :
 328
 329         free HASH at depth 0
 330         free HASH at depth 1
 331         free SCALAR at depth 2
 332         free ARRAY at depth 1
 333         free SCALAR at depth 3
 334         free SCALAR at depth 3
 335
 336     Of course, this example does nothing with the values that are added
 337     after the "cast".
 338
 339   "getdata"
 340         getdata [$@%&*]var, [$wiz|$sig]
 341
 342     This accessor fetches the private data associated with the magic $wiz
 343     (or the signature $sig) in the variable. It croaks when $wiz or $sig do
 344     not represent a current valid magic object attached to the variable, and
 345     returns "undef" when the wizard has no data constructor or when the data
 346     is actually "undef".
 347
 348         # Get the attached data, or undef if the wizard does not attach any.
 349         my $data = getdata $x, $wiz;
 350
 351   "dispell"
 352         dispell [$@%&*]variable, [$wiz|$sig]
 353
 354     The exact opposite of "cast" : it dissociates $wiz magic from the
 355     variable. You can also pass the magic signature $sig as the second
 356     argument. This function returns true on success, 0 when no magic
 357     represented by $wiz or $sig could be found in the variable, and croaks
 358     if the supplied wizard or signature is invalid.
 359
 360         # Dispell now.
 361         die 'no such magic in $x' unless dispell $x, $wiz;
 362
 363 CONSTANTS
 364   "SIG_MIN"
 365     The minimum integer used as a signature for user-defined magic.
 366
 367   "SIG_MAX"
 368     The maximum integer used as a signature for user-defined magic.
 369
 370   "SIG_NBR"
 371         SIG_NBR = SIG_MAX - SIG_MIN + 1
 372
 373   "MGf_COPY"
 374     Evaluates to true iff the 'copy' magic is available.
 375
 376   "MGf_DUP"
 377     Evaluates to true iff the 'dup' magic is available.
 378
 379   "MGf_LOCAL"
 380     Evaluates to true iff the 'local' magic is available.
 381
 382   "VMG_UVAR"
 383     When this constant is true, you can use the "fetch,store,exists,delete"
 384     callbacks on hashes.
 385
 386   "VMG_COMPAT_ARRAY_PUSH_NOLEN"
 387     True for perls that don't call 'len' magic when you push an element in a
 388     magical array.
 389
 390   "VMG_COMPAT_ARRAY_UNSHIFT_NOLEN_VOID"
 391     True for perls that don't call 'len' magic when you unshift in void
 392     context an element in a magical array.
 393
 394   "VMG_COMPAT_ARRAY_UNDEF_CLEAR"
 395     True for perls that call 'clear' magic when undefining magical arrays.
 396
 397   "VMG_COMPAT_SCALAR_LENGTH_NOLEN"
 398     True for perls that don't call 'len' magic when taking the "length" of a
 399     magical scalar.
 400
 401   "VMG_PERL_PATCHLEVEL"
 402     The perl patchlevel this module was built with, or 0 for non-debugging
 403     perls.
 404
 405   "VMG_THREADSAFE"
 406     True iff this module could have been built with thread-safety features
 407     enabled.
 408
 409   "VMG_OP_INFO_NAME"
 410     Value to pass with "op_info" to get the current op name in the magic
 411     callbacks.
 412
 413   "VMG_OP_INFO_OBJECT"
 414     Value to pass with "op_info" to get a "B::OP" object representing the
 415     current op in the magic callbacks.
 416
 417 PERL MAGIC HISTORY
 418     The places where magic is invoked have changed a bit through perl
 419     history. Here's a little list of the most recent ones.
 420
 421     *   5.6.x
 422
 423         *p14416* : 'copy' and 'dup' magic.
 424
 425     *   5.8.9
 426
 427         *p28160* : Integration of *p25854* (see below).
 428
 429         *p32542* : Integration of *p31473* (see below).
 430
 431     *   5.9.3
 432
 433         *p25854* : 'len' magic is no longer called when pushing an element
 434         into a magic array.
 435
 436         *p26569* : 'local' magic.
 437
 438     *   5.9.5
 439
 440         *p31064* : Meaningful 'uvar' magic.
 441
 442         *p31473* : 'clear' magic wasn't invoked when undefining an array.
 443         The bug is fixed as of this version.
 444
 445     *   5.10.0
 446
 447         Since "PERL_MAGIC_uvar" is uppercased, "hv_magic_check()" triggers
 448         'copy' magic on hash stores for (non-tied) hashes that also have
 449         'uvar' magic.
 450
 451     *   5.11.x
 452
 453         *p32969* : 'len' magic is no longer invoked when calling "length"
 454         with a magical scalar.
 455
 456         *p34908* : 'len' magic is no longer called when pushing / unshifting
 457         an element into a magical array in void context. The "push" part was
 458         already covered by *p25854*.
 459
 460 EXPORT
 461     The functions "wizard", "gensig", "getsig", "cast", "getdata" and
 462     "dispell" are only exported on request. All of them are exported by the
 463     tags ':funcs' and ':all'.
 464
 465     All the constants are also only exported on request, either individually
 466     or by the tags ':consts' and ':all'.
 467
 468 CAVEATS
 469     If you store a magic object in the private data slot, the magic won't be
 470     accessible by "getdata" since it's not copied by assignment. The only
 471     way to address this would be to return a reference.
 472
 473     If you define a wizard with a "free" callback and cast it on itself,
 474     this destructor won't be called because the wizard will be destroyed
 475     first.
 476
 477 DEPENDENCIES
 478     perl 5.8.
 479
 480     Carp (standard since perl 5), XSLoader (standard since perl 5.006).
 481
 482     Copy tests need Tie::Array (standard since perl 5.005) and Tie::Hash
 483     (since 5.002).
 484
 485     Some uvar tests need Hash::Util::FieldHash (standard since perl
 486     5.009004).
 487
 488     Glob tests need Symbol (standard since perl 5.002).
 489
 490     Threads tests need threads and threads::shared.
 491
 492 SEE ALSO
 493     perlguts and perlapi for internal information about magic.
 494
 495     perltie and overload for other ways of enhancing objects.
 496
 497 AUTHOR
 498     Vincent Pit, "<perl at profvince.com>", <http://www.profvince.com>.
 499
 500     You can contact me by mail or on "irc.perl.org" (vincent).
 501
 502 BUGS
 503     Please report any bugs or feature requests to "bug-variable-magic at
 504     rt.cpan.org", or through the web interface at
 505     <http://rt.cpan.org/NoAuth/ReportBug.html?Queue=Variable-Magic>. I will
 506     be notified, and then you'll automatically be notified of progress on
 507     your bug as I make changes.
 508
 509 SUPPORT
 510     You can find documentation for this module with the perldoc command.
 511
 512         perldoc Variable::Magic
 513
 514     Tests code coverage report is available at
 515     <http://www.profvince.com/perl/cover/Variable-Magic>.
 516
 517 COPYRIGHT & LICENSE
 518     Copyright 2007-2009 Vincent Pit, all rights reserved.
 519
 520     This program is free software; you can redistribute it and/or modify it
 521     under the same terms as Perl itself.
 522