lib/indirect.pm

   1 package indirect;
   2
   3 use 5.008;
   4
   5 use strict;
   6 use warnings;
   7
   8 =head1 NAME
   9
  10 indirect - Lexically warn about using the indirect object syntax.
  11
  12 =head1 VERSION
  13
  14 Version 0.15
  15
  16 =cut
  17
  18 our $VERSION;
  19 BEGIN {
  20  $VERSION = '0.15';
  21 }
  22
  23 =head1 SYNOPSIS
  24
  25     # In a script
  26     no indirect;
  27     my $x = new Apple 1, 2, 3; # warns
  28     {
  29      use indirect;
  30      my $y = new Pear; # ok
  31      {
  32       no indirect hook => sub { die "You really wanted $_[0]\->$_[1] at $_[2]:$_[3]" };
  33       my $z = new Pineapple 'fresh'; # croaks 'You really wanted Pineapple->new at blurp.pm:13'
  34      }
  35     }
  36     no indirect ':fatal';
  37     if (defied $foo) { ... } # croaks, note the typo
  38
  39     # From the command-line
  40     perl -M-indirect -e 'my $x = new Banana;' # warns
  41
  42     # Or each time perl is ran
  43     export PERL5OPT="-M-indirect"
  44     perl -e 'my $y = new Coconut;' # warns
  45
  46 =head1 DESCRIPTION
  47
  48 When enabled (or disabled as some may prefer to say, since you actually turn it on by calling C<no indirect>), this pragma warns about indirect object syntax constructs that may have slipped into your code.
  49 This syntax is now considered harmful, since its parsing has many quirks and its use is error prone (when C<swoosh> isn't defined, C<swoosh $x> actually compiles to C<< $x->swoosh >>).
  50
  51 It currently does not warn for core functions (C<print>, C<say>, C<exec> or C<system>).
  52 This may change in the future, or may be added as optional features that would be enabled by passing options to C<unimport>.
  53
  54 This module is B<not> a source filter.
  55
  56 =cut
  57
  58 BEGIN {
  59  require XSLoader;
  60  XSLoader::load(__PACKAGE__, $VERSION);
  61 }
  62
  63 =head1 METHODS
  64
  65 =head2 C<< unimport [ hook => $hook | ':fatal' ] >>
  66
  67 Magically called when C<no indirect @opts> is encountered.
  68 Turns the module on.
  69 The policy to apply depends on what is first found in C<@opts> :
  70
  71 =over 4
  72
  73 =item *
  74
  75 If it's the string C<':fatal'>, the compilation will croak on the first indirect syntax met.
  76
  77 =item *
  78
  79 If the key/value pair C<< hook => $hook >> comes first, C<$hook> will be called for each error with the object name as C<$_[0]>, the method name as C<$_[1]>, the current file as C<$_[2]> and the line number as C<$_[3]>.
  80
  81 =item *
  82
  83 Otherwise, a warning will be emitted for each indirect construct.
  84
  85 =back
  86
  87 =cut
  88
  89 sub unimport {
  90  shift;
  91
  92  my $hook;
  93  while (@_) {
  94   my $arg = shift;
  95   if ($arg eq 'hook') {
  96    $hook = shift;
  97   } elsif ($arg eq ':fatal') {
  98    $hook = sub { die msg(@_) };
  99   }
 100   last if $hook;
 101  }
 102  $hook = sub { warn msg(@_) } unless defined $hook;
 103
 104  $^H |= 0x00020000;
 105  $^H{+(__PACKAGE__)} = _tag($hook);
 106
 107  ();
 108 }
 109
 110 =head2 C<import>
 111
 112 Magically called at each C<use indirect>. Turns the module off.
 113
 114 =cut
 115
 116 sub import {
 117  $^H{+(__PACKAGE__)} = undef;
 118  ();
 119 }
 120
 121 =head1 FUNCTIONS
 122
 123 =head2 C<msg $object, $method, $file, $line>
 124
 125 Returns the default error message generated by C<indirect> when an invalid construct is reported.
 126
 127 =cut
 128
 129 sub msg {
 130  my $obj = $_[0];
 131
 132  join ' ', "Indirect call of method \"$_[1]\" on",
 133            ($obj =~ /^\s*\{/ ? "a block" : "object \"$obj\""),
 134            "at $_[2] line $_[3].\n";
 135 };
 136
 137 =head1 CONSTANTS
 138
 139 =head2 C<I_THREADSAFE>
 140
 141 True iff the module could have been built with thread-safety features enabled.
 142
 143 =head1 CAVEATS
 144
 145 The implementation was tweaked to work around several limitations of vanilla C<perl> pragmas : it's thread safe, and doesn't suffer from a C<perl 5.8.x-5.10.0> bug that causes all pragmas to propagate into C<require>d scopes.
 146
 147 C<meth $obj> (no semicolon) at the end of a file won't be seen as an indirect object syntax, although it will as soon as there is another token before the end (as in C<meth $obj;> or C<meth $obj 1>).
 148
 149 With 5.8 perls, the pragma does not propagate into C<eval STRING>.
 150 This is due to a shortcoming in the way perl handles the hints hash, which is addressed in perl 5.10.
 151
 152 =head1 DEPENDENCIES
 153
 154 L<perl> 5.8.
 155
 156 L<XSLoader> (standard since perl 5.006).
 157
 158 =head1 AUTHOR
 159
 160 Vincent Pit, C<< <perl at profvince.com> >>, L<http://www.profvince.com>.
 161
 162 You can contact me by mail or on C<irc.perl.org> (vincent).
 163
 164 =head1 BUGS
 165
 166 Please report any bugs or feature requests to C<bug-indirect at rt.cpan.org>, or through the web interface at L<http://rt.cpan.org/NoAuth/ReportBug.html?Queue=indirect>.
 167 I will be notified, and then you'll automatically be notified of progress on your bug as I make changes.
 168
 169 =head1 SUPPORT
 170
 171 You can find documentation for this module with the perldoc command.
 172
 173     perldoc indirect
 174
 175 Tests code coverage report is available at L<http://www.profvince.com/perl/cover/indirect>.
 176
 177 =head1 ACKNOWLEDGEMENTS
 178
 179 Bram, for motivation and advices.
 180
 181 =head1 COPYRIGHT & LICENSE
 182
 183 Copyright 2008-2009 Vincent Pit, all rights reserved.
 184
 185 This program is free software; you can redistribute it and/or modify it under the same terms as Perl itself.
 186
 187 =cut
 188
 189 1; # End of indirect