lib/indirect.pm

   1 package indirect;
   2
   3 use 5.008;
   4
   5 use strict;
   6 use warnings;
   7
   8 =head1 NAME
   9
  10 indirect - Lexically warn about using the indirect object syntax.
  11
  12 =head1 VERSION
  13
  14 Version 0.11
  15
  16 =cut
  17
  18 our $VERSION;
  19 BEGIN {
  20  $VERSION = '0.11';
  21 }
  22
  23 =head1 SYNOPSIS
  24
  25     # In a script
  26     no indirect;
  27     my $x = new Apple 1, 2, 3; # warns
  28     {
  29      use indirect;
  30      my $y = new Pear; # ok
  31      {
  32       no indirect hook => sub { die "You really wanted $_[0]\->$_[1]" };
  33       my $z = new Pineapple 'fresh'; # croaks 'You really wanted Pineapple->new'
  34      }
  35     }
  36     no indirect ':fatal';
  37     if (defied $foo) { ... } # croaks, note the typo
  38
  39     # From the command-line
  40     perl -M-indirect -e 'my $x = new Banana;' # warns
  41
  42     # Or each time perl is ran
  43     export PERL5OPT="-M-indirect"
  44     perl -e 'my $y = new Coconut;' # warns
  45
  46 =head1 DESCRIPTION
  47
  48 When enabled (or disabled as some may prefer to say, since you actually turn it on by calling C<no indirect>), this pragma warns about indirect object syntax constructs that may have slipped into your code.
  49 This syntax is now considered harmful, since its parsing has many quirks and its use is error prone (when C<sub> isn't defined, C<sub $x> is actually interpreted as C<< $x->sub >>).
  50
  51 It currently does not warn when the object is enclosed between braces (like C<meth { $obj } @args>) or for core functions (C<print> or C<say>).
  52 This may change in the future, or may be added as optional features that would be enabled by passing options to C<unimport>.
  53
  54 This module is B<not> a source filter.
  55
  56 =cut
  57
  58 BEGIN {
  59  require XSLoader;
  60  XSLoader::load(__PACKAGE__, $VERSION);
  61 }
  62
  63 =head1 METHODS
  64
  65 =head2 C<< unimport [ hook => $hook | ':fatal' ] >>
  66
  67 Magically called when C<no indirect @opts> is encountered.
  68 Turns the module on.
  69 The policy to apply depends on what is first found in C<@opts> :
  70
  71 =over 4
  72
  73 =item *
  74
  75 If it's the string C<':fatal'>, the compilation will croak on the first indirect syntax met.
  76
  77 =item *
  78
  79 If the key/value pair C<< hook => $hook >> comes first, C<$hook> will be called for each error with the object name as C<$_[0]> and the method name as C<$_[1]>.
  80
  81 =item *
  82
  83 Otherwise, a warning will be emitted for each indirect construct.
  84
  85 =back
  86
  87 =cut
  88
  89 my $msg = sub { "Indirect call of method \"$_[1]\" on object \"$_[0]\"" };
  90
  91 sub unimport {
  92  shift;
  93
  94  my $hook;
  95  while (@_) {
  96   my $arg = shift;
  97   if ($arg eq 'hook') {
  98    $hook = shift;
  99   } elsif ($arg eq ':fatal') {
 100    $hook = sub { die $msg->(@_) };
 101   }
 102   last if $hook;
 103  }
 104  $hook = sub { warn $msg->(@_) } unless defined $hook;
 105
 106  $^H |= 0x00020000;
 107  $^H{+(__PACKAGE__)} = _tag($hook);
 108
 109  ();
 110 }
 111
 112 =head2 C<import>
 113
 114 Magically called at each C<use indirect>. Turns the module off.
 115
 116 =cut
 117
 118 sub import {
 119  $^H{+(__PACKAGE__)} = undef;
 120  ();
 121 }
 122
 123 =head1 CONSTANTS
 124
 125 =head2 C<I_THREADSAFE>
 126
 127 True iff the module could have been built when thread-safety features.
 128
 129 =head1 CAVEATS
 130
 131 C<meth $obj> (no semicolon) at the end of a file won't be seen as an indirect object syntax, although it will as soon as there is another token before the end (as in C<meth $obj;> or C<meth $obj 1>).
 132
 133 With 5.8 perls, the pragma does not propagate into C<eval STRING>.
 134 This is due to a shortcoming in the way perl handles the hints hash, which is addressed in perl 5.10.
 135
 136 =head1 DEPENDENCIES
 137
 138 L<perl> 5.8.
 139
 140 L<XSLoader> (standard since perl 5.006).
 141
 142 =head1 AUTHOR
 143
 144 Vincent Pit, C<< <perl at profvince.com> >>, L<http://www.profvince.com>.
 145
 146 You can contact me by mail or on C<irc.perl.org> (vincent).
 147
 148 =head1 BUGS
 149
 150 Please report any bugs or feature requests to C<bug-indirect at rt.cpan.org>, or through the web interface at L<http://rt.cpan.org/NoAuth/ReportBug.html?Queue=indirect>.
 151 I will be notified, and then you'll automatically be notified of progress on your bug as I make changes.
 152
 153 =head1 SUPPORT
 154
 155 You can find documentation for this module with the perldoc command.
 156
 157     perldoc indirect
 158
 159 Tests code coverage report is available at L<http://www.profvince.com/perl/cover/indirect>.
 160
 161 =head1 ACKNOWLEDGEMENTS
 162
 163 Bram, for motivation and advices.
 164
 165 =head1 COPYRIGHT & LICENSE
 166
 167 Copyright 2008-2009 Vincent Pit, all rights reserved.
 168
 169 This program is free software; you can redistribute it and/or modify it under the same terms as Perl itself.
 170
 171 =cut
 172
 173 1; # End of indirect