lib/indirect.pm

   1 package indirect;
   2
   3 use 5.008;
   4
   5 use strict;
   6 use warnings;
   7
   8 =head1 NAME
   9
  10 indirect - Lexically warn about using the indirect object syntax.
  11
  12 =head1 VERSION
  13
  14 Version 0.16
  15
  16 =cut
  17
  18 our $VERSION;
  19 BEGIN {
  20  $VERSION = '0.16';
  21 }
  22
  23 =head1 SYNOPSIS
  24
  25     # In a script
  26     no indirect;
  27     my $x = new Apple 1, 2, 3; # warns
  28     {
  29      use indirect;
  30      my $y = new Pear; # ok
  31      {
  32       no indirect hook => sub { die "You really wanted $_[0]\->$_[1] at $_[2]:$_[3]" };
  33       my $z = new Pineapple 'fresh'; # croaks 'You really wanted Pineapple->new at blurp.pm:13'
  34      }
  35     }
  36     try { ... }; # warns
  37
  38     no indirect ':fatal';
  39     if (defied $foo) { ... } # croaks, note the typo
  40
  41     # From the command-line
  42     perl -M-indirect -e 'my $x = new Banana;' # warns
  43
  44     # Or each time perl is ran
  45     export PERL5OPT="-M-indirect"
  46     perl -e 'my $y = new Coconut;' # warns
  47
  48 =head1 DESCRIPTION
  49
  50 When enabled (or disabled as some may prefer to say, since you actually turn it on by calling C<no indirect>), this pragma warns about indirect object syntax constructs that may have slipped into your code.
  51 This syntax is now considered harmful, since its parsing has many quirks and its use is error prone (when C<swoosh> isn't defined, C<swoosh $x> actually compiles to C<< $x->swoosh >>).
  52
  53 It currently does not warn for core functions (C<print>, C<say>, C<exec> or C<system>).
  54 This may change in the future, or may be added as optional features that would be enabled by passing options to C<unimport>.
  55
  56 This module is B<not> a source filter.
  57
  58 =cut
  59
  60 BEGIN {
  61  require XSLoader;
  62  XSLoader::load(__PACKAGE__, $VERSION);
  63 }
  64
  65 =head1 METHODS
  66
  67 =head2 C<< unimport [ hook => $hook | ':fatal' ] >>
  68
  69 Magically called when C<no indirect @opts> is encountered.
  70 Turns the module on.
  71 The policy to apply depends on what is first found in C<@opts> :
  72
  73 =over 4
  74
  75 =item *
  76
  77 If it's the string C<':fatal'>, the compilation will croak on the first indirect syntax met.
  78
  79 =item *
  80
  81 If the key/value pair C<< hook => $hook >> comes first, C<$hook> will be called for each error with a string representation of the object as C<$_[0]>, the method name as C<$_[1]>, the current file as C<$_[2]> and the line number as C<$_[3]>.
  82 If and only if the object is actually a block, C<$_[0]> is assured to start by C<'{'>.
  83
  84 =item *
  85
  86 Otherwise, a warning will be emitted for each indirect construct.
  87
  88 =back
  89
  90 =cut
  91
  92 sub unimport {
  93  shift;
  94
  95  my $hook;
  96  while (@_) {
  97   my $arg = shift;
  98   if ($arg eq 'hook') {
  99    $hook = shift;
 100   } elsif ($arg eq ':fatal') {
 101    $hook = sub { die msg(@_) };
 102   }
 103   last if $hook;
 104  }
 105  $hook = sub { warn msg(@_) } unless defined $hook;
 106
 107  $^H |= 0x00020000;
 108  $^H{+(__PACKAGE__)} = _tag($hook);
 109
 110  ();
 111 }
 112
 113 =head2 C<import>
 114
 115 Magically called at each C<use indirect>. Turns the module off.
 116
 117 =cut
 118
 119 sub import {
 120  $^H{+(__PACKAGE__)} = undef;
 121  ();
 122 }
 123
 124 =head1 FUNCTIONS
 125
 126 =head2 C<msg $object, $method, $file, $line>
 127
 128 Returns the default error message generated by C<indirect> when an invalid construct is reported.
 129
 130 =cut
 131
 132 sub msg {
 133  my $obj = $_[0];
 134
 135  join ' ', "Indirect call of method \"$_[1]\" on",
 136            ($obj =~ /^\s*\{/ ? "a block" : "object \"$obj\""),
 137            "at $_[2] line $_[3].\n";
 138 };
 139
 140 =head1 CONSTANTS
 141
 142 =head2 C<I_THREADSAFE>
 143
 144 True iff the module could have been built with thread-safety features enabled.
 145
 146 =head1 DIAGNOSTICS
 147
 148 =head2 C<Indirect call of method "%s" on object "%s" at %s line %d.>
 149
 150 The default warning/exception message thrown when an indirect call on an object is found.
 151
 152 =head2 C<Indirect call of method "%s" on a block at %s line %d.>
 153
 154 The default warning/exception message thrown when an indirect call on a block is found.
 155
 156 =head1 CAVEATS
 157
 158 The implementation was tweaked to work around several limitations of vanilla C<perl> pragmas : it's thread safe, and doesn't suffer from a C<perl 5.8.x-5.10.0> bug that causes all pragmas to propagate into C<require>d scopes.
 159
 160 C<meth $obj> (no semicolon) at the end of a file won't be seen as an indirect object syntax, although it will as soon as there is another token before the end (as in C<meth $obj;> or C<meth $obj 1>).
 161
 162 With 5.8 perls, the pragma does not propagate into C<eval STRING>.
 163 This is due to a shortcoming in the way perl handles the hints hash, which is addressed in perl 5.10.
 164
 165 =head1 DEPENDENCIES
 166
 167 L<perl> 5.8.
 168
 169 L<XSLoader> (standard since perl 5.006).
 170
 171 =head1 AUTHOR
 172
 173 Vincent Pit, C<< <perl at profvince.com> >>, L<http://www.profvince.com>.
 174
 175 You can contact me by mail or on C<irc.perl.org> (vincent).
 176
 177 =head1 BUGS
 178
 179 Please report any bugs or feature requests to C<bug-indirect at rt.cpan.org>, or through the web interface at L<http://rt.cpan.org/NoAuth/ReportBug.html?Queue=indirect>.
 180 I will be notified, and then you'll automatically be notified of progress on your bug as I make changes.
 181
 182 =head1 SUPPORT
 183
 184 You can find documentation for this module with the perldoc command.
 185
 186     perldoc indirect
 187
 188 Tests code coverage report is available at L<http://www.profvince.com/perl/cover/indirect>.
 189
 190 =head1 ACKNOWLEDGEMENTS
 191
 192 Bram, for motivation and advices.
 193
 194 Andrew Main and Florian Ragwitz, for testing on real-life code and reporting issues.
 195
 196 =head1 COPYRIGHT & LICENSE
 197
 198 Copyright 2008-2009 Vincent Pit, all rights reserved.
 199
 200 This program is free software; you can redistribute it and/or modify it under the same terms as Perl itself.
 201
 202 =cut
 203
 204 1; # End of indirect