lib/indirect.pm

   1 package indirect;
   2
   3 use 5.008;
   4
   5 use strict;
   6 use warnings;
   7
   8 =head1 NAME
   9
  10 indirect - Lexically warn about using the indirect object syntax.
  11
  12 =head1 VERSION
  13
  14 Version 0.11
  15
  16 =cut
  17
  18 our $VERSION;
  19 BEGIN {
  20  $VERSION = '0.11';
  21 }
  22
  23 =head1 SYNOPSIS
  24
  25     no indirect;
  26     my $x = new Apple 1, 2, 3; # warns
  27     {
  28      use indirect;
  29      my $y = new Pear; # ok
  30     }
  31     no indirect ':fatal';
  32     if (defied $foo) { ... } # croaks, note the typo
  33
  34 =head1 DESCRIPTION
  35
  36 When enabled (or disabled as some may prefer to say, since you actually turn it on by calling C<no indirect>), this pragma warns about indirect object syntax constructs that may have slipped into your code. This syntax is now considered harmful, since its parsing has many quirks and its use is error prone (when C<sub> isn't defined, C<sub $x> is actually interpreted as C<< $x->sub >>).
  37
  38 It currently does not warn when the object is enclosed between braces (like C<meth { $obj } @args>) or for core functions (C<print> or C<say>). This may change in the future, or may be added as optional features that would be enabled by passing options to C<unimport>.
  39
  40 This module is B<not> a source filter.
  41
  42 =head1 METHODS
  43
  44 =head2 C<unimport @opts>
  45
  46 Magically called when C<no indirect @opts> is encountered. Turns the module on. If C<@opts> contains C<':fatal'>, the module will croak on the first indirect syntax met.
  47
  48 =head2 C<import>
  49
  50 Magically called at each C<use indirect>. Turns the module off.
  51
  52 =cut
  53
  54 BEGIN {
  55  require XSLoader;
  56  XSLoader::load(__PACKAGE__, $VERSION);
  57 }
  58
  59 sub import {
  60  $^H{+(__PACKAGE__)} = undef;
  61  ();
  62 }
  63
  64 my $msg = sub { "Indirect call of method \"$_[1]\" on object \"$_[0]\"" };
  65
  66 sub unimport {
  67  (undef, my $type) = @_;
  68  $^H |= 0x00020000;
  69  my $cb = (defined $type and $type eq ':fatal')
  70            ? sub { die  $msg->(@_) }
  71            : sub { warn $msg->(@_) };
  72  $^H{+(__PACKAGE__)} = _tag($cb);
  73  ();
  74 }
  75
  76 =head1 CAVEATS
  77
  78 C<meth $obj> (no semicolon) at the end of a file won't be seen as an indirect object syntax, although it will as soon as there is another token before the end (as in C<meth $obj;> or C<meth $obj 1>).
  79
  80 With 5.8 perls, the pragma does not propagate into C<eval STRING>.
  81 This is due to a shortcoming in the way perl handles the hints hash, which is addressed in perl 5.10.
  82
  83 =head1 DEPENDENCIES
  84
  85 L<perl> 5.8.
  86
  87 L<XSLoader> (standard since perl 5.006).
  88
  89 =head1 AUTHOR
  90
  91 Vincent Pit, C<< <perl at profvince.com> >>, L<http://www.profvince.com>.
  92
  93 You can contact me by mail or on C<irc.perl.org> (vincent).
  94
  95 =head1 BUGS
  96
  97 Please report any bugs or feature requests to C<bug-indirect at rt.cpan.org>, or through the web interface at L<http://rt.cpan.org/NoAuth/ReportBug.html?Queue=indirect>.  I will be notified, and then you'll automatically be notified of progress on your bug as I make changes.
  98
  99 =head1 SUPPORT
 100
 101 You can find documentation for this module with the perldoc command.
 102
 103     perldoc indirect
 104
 105 Tests code coverage report is available at L<http://www.profvince.com/perl/cover/indirect>.
 106
 107 =head1 ACKNOWLEDGEMENTS
 108
 109 Bram, for motivation and advices.
 110
 111 =head1 COPYRIGHT & LICENSE
 112
 113 Copyright 2008-2009 Vincent Pit, all rights reserved.
 114
 115 This program is free software; you can redistribute it and/or modify it under the same terms as Perl itself.
 116
 117 =cut
 118
 119 1; # End of indirect