lib/indirect.pm

   1 package indirect;
   2
   3 use 5.008;
   4
   5 use strict;
   6 use warnings;
   7
   8 =head1 NAME
   9
  10 indirect - Lexically warn about using the indirect object syntax.
  11
  12 =head1 VERSION
  13
  14 Version 0.17
  15
  16 =cut
  17
  18 our $VERSION;
  19 BEGIN {
  20  $VERSION = '0.17';
  21 }
  22
  23 =head1 SYNOPSIS
  24
  25     # In a script
  26     no indirect;
  27     my $x = new Apple 1, 2, 3; # warns
  28     {
  29      use indirect;
  30      my $y = new Pear; # ok
  31      {
  32       no indirect hook => sub { die "You really wanted $_[0]\->$_[1] at $_[2]:$_[3]" };
  33       my $z = new Pineapple 'fresh'; # croaks 'You really wanted Pineapple->new at blurp.pm:13'
  34      }
  35     }
  36     try { ... }; # warns
  37
  38     no indirect ':fatal';
  39     if (defied $foo) { ... } # croaks, note the typo
  40
  41     # From the command-line
  42     perl -M-indirect -e 'my $x = new Banana;' # warns
  43
  44     # Or each time perl is ran
  45     export PERL5OPT="-M-indirect"
  46     perl -e 'my $y = new Coconut;' # warns
  47
  48 =head1 DESCRIPTION
  49
  50 When enabled (or disabled as some may prefer to say, since you actually turn it on by calling C<no indirect>), this pragma warns about indirect object syntax constructs that may have slipped into your code.
  51 This syntax is now considered harmful, since its parsing has many quirks and its use is error prone (when C<swoosh> isn't defined, C<swoosh $x> actually compiles to C<< $x->swoosh >>).
  52
  53 It currently does not warn for core functions (C<print>, C<say>, C<exec> or C<system>).
  54 This may change in the future, or may be added as optional features that would be enabled by passing options to C<unimport>.
  55
  56 This module is B<not> a source filter.
  57
  58 =cut
  59
  60 BEGIN {
  61  if ($ENV{PERL_INDIRECT_PM_DISABLE}) {
  62   *_tag = sub ($) { 1 };
  63  } else {
  64   require XSLoader;
  65   XSLoader::load(__PACKAGE__, $VERSION);
  66  }
  67 }
  68
  69 =head1 METHODS
  70
  71 =head2 C<< unimport [ hook => $hook | ':fatal' ] >>
  72
  73 Magically called when C<no indirect @opts> is encountered.
  74 Turns the module on.
  75 The policy to apply depends on what is first found in C<@opts> :
  76
  77 =over 4
  78
  79 =item *
  80
  81 If it's the string C<':fatal'>, the compilation will croak on the first indirect syntax met.
  82
  83 =item *
  84
  85 If the key/value pair C<< hook => $hook >> comes first, C<$hook> will be called for each error with a string representation of the object as C<$_[0]>, the method name as C<$_[1]>, the current file as C<$_[2]> and the line number as C<$_[3]>.
  86 If and only if the object is actually a block, C<$_[0]> is assured to start by C<'{'>.
  87
  88 =item *
  89
  90 Otherwise, a warning will be emitted for each indirect construct.
  91
  92 =back
  93
  94 =cut
  95
  96 sub unimport {
  97  shift;
  98
  99  my $hook;
 100  while (@_) {
 101   my $arg = shift;
 102   if ($arg eq 'hook') {
 103    $hook = shift;
 104   } elsif ($arg eq ':fatal') {
 105    $hook = sub { die msg(@_) };
 106   }
 107   last if $hook;
 108  }
 109  $hook = sub { warn msg(@_) } unless defined $hook;
 110
 111  $^H |= 0x00020000;
 112  $^H{+(__PACKAGE__)} = _tag($hook);
 113
 114  ();
 115 }
 116
 117 =head2 C<import>
 118
 119 Magically called at each C<use indirect>. Turns the module off.
 120
 121 =cut
 122
 123 sub import {
 124  $^H{+(__PACKAGE__)} = undef;
 125  ();
 126 }
 127
 128 =head1 FUNCTIONS
 129
 130 =head2 C<msg $object, $method, $file, $line>
 131
 132 Returns the default error message generated by C<indirect> when an invalid construct is reported.
 133
 134 =cut
 135
 136 sub msg {
 137  my $obj = $_[0];
 138
 139  join ' ', "Indirect call of method \"$_[1]\" on",
 140            ($obj =~ /^\s*\{/ ? "a block" : "object \"$obj\""),
 141            "at $_[2] line $_[3].\n";
 142 };
 143
 144 =head1 CONSTANTS
 145
 146 =head2 C<I_THREADSAFE>
 147
 148 True iff the module could have been built with thread-safety features enabled.
 149
 150 =head1 DIAGNOSTICS
 151
 152 =head2 C<Indirect call of method "%s" on object "%s" at %s line %d.>
 153
 154 The default warning/exception message thrown when an indirect call on an object is found.
 155
 156 =head2 C<Indirect call of method "%s" on a block at %s line %d.>
 157
 158 The default warning/exception message thrown when an indirect call on a block is found.
 159
 160 =head1 ENVIRONMENT
 161
 162 =head2 C<PERL_INDIRECT_PM_DISABLE>
 163
 164 If this environment variable is set to true when the pragma is used for the first time, the XS code won't be loaded and, although the C<'indirect'> lexical hint will be set to true in the scope of use, the pragma itself won't do anything.
 165 This is useful for disabling C<indirect> in production environments.
 166
 167 Note that clearing this variable after C<indirect> was loaded has no effect.
 168 If you want to reenable the pragma later, you also need to reload it by deleting the C<'indirect.pm'> entry from C<%INC>.
 169
 170 =head1 CAVEATS
 171
 172 The implementation was tweaked to work around several limitations of vanilla C<perl> pragmas : it's thread safe, and doesn't suffer from a C<perl 5.8.x-5.10.0> bug that causes all pragmas to propagate into C<require>d scopes.
 173
 174 C<meth $obj> (no semicolon) at the end of a file won't be seen as an indirect object syntax, although it will as soon as there is another token before the end (as in C<meth $obj;> or C<meth $obj 1>).
 175
 176 With 5.8 perls, the pragma does not propagate into C<eval STRING>.
 177 This is due to a shortcoming in the way perl handles the hints hash, which is addressed in perl 5.10.
 178
 179 The search for indirect method calls happens before constant folding.
 180 Hence C<my $x = new Class if 0> will be caught.
 181
 182 =head1 DEPENDENCIES
 183
 184 L<perl> 5.8.
 185
 186 L<XSLoader> (standard since perl 5.006).
 187
 188 =head1 AUTHOR
 189
 190 Vincent Pit, C<< <perl at profvince.com> >>, L<http://www.profvince.com>.
 191
 192 You can contact me by mail or on C<irc.perl.org> (vincent).
 193
 194 =head1 BUGS
 195
 196 Please report any bugs or feature requests to C<bug-indirect at rt.cpan.org>, or through the web interface at L<http://rt.cpan.org/NoAuth/ReportBug.html?Queue=indirect>.
 197 I will be notified, and then you'll automatically be notified of progress on your bug as I make changes.
 198
 199 =head1 SUPPORT
 200
 201 You can find documentation for this module with the perldoc command.
 202
 203     perldoc indirect
 204
 205 Tests code coverage report is available at L<http://www.profvince.com/perl/cover/indirect>.
 206
 207 =head1 ACKNOWLEDGEMENTS
 208
 209 Bram, for motivation and advices.
 210
 211 Andrew Main and Florian Ragwitz, for testing on real-life code and reporting issues.
 212
 213 =head1 COPYRIGHT & LICENSE
 214
 215 Copyright 2008-2009 Vincent Pit, all rights reserved.
 216
 217 This program is free software; you can redistribute it and/or modify it under the same terms as Perl itself.
 218
 219 =cut
 220
 221 1; # End of indirect