lib/indirect.pm

   1 package indirect;
   2
   3 use 5.008001;
   4
   5 use strict;
   6 use warnings;
   7
   8 =head1 NAME
   9
  10 indirect - Lexically warn about using the indirect object syntax.
  11
  12 =head1 VERSION
  13
  14 Version 0.25
  15
  16 =cut
  17
  18 our $VERSION;
  19 BEGIN {
  20  $VERSION = '0.25';
  21 }
  22
  23 =head1 SYNOPSIS
  24
  25     # In a script
  26     no indirect;
  27     my $x = new Apple 1, 2, 3; # warns
  28     {
  29      use indirect;
  30      my $y = new Pear; # ok
  31      {
  32       no indirect hook => sub { die "You really wanted $_[0]\->$_[1] at $_[2]:$_[3]" };
  33       my $z = new Pineapple 'fresh'; # croaks 'You really wanted Pineapple->new at blurp.pm:13'
  34      }
  35     }
  36     try { ... }; # warns
  37
  38     no indirect ':fatal';    # or 'FATAL', or ':Fatal' ...
  39     if (defied $foo) { ... } # croaks, note the typo
  40
  41     # Globally enabled from the command-line
  42     perl -M-indirect=global -e 'my $x = new Banana;' # warns
  43
  44     # Or globally enabled each time perl is executed
  45     export PERL5OPT="-M-indirect=global"
  46     perl -e 'my $y = new Coconut;' # warns
  47
  48 =head1 DESCRIPTION
  49
  50 When enabled (or disabled as some may prefer to say, since you actually turn it on by calling C<no indirect>), this pragma warns about indirect object syntax constructs that may have slipped into your code.
  51
  52 This syntax is now considered harmful, since its parsing has many quirks and its use is error prone (when C<swoosh> is not defined, C<swoosh $x> actually compiles to C<< $x->swoosh >>).
  53 In L<http://www.shadowcat.co.uk/blog/matt-s-trout/indirect-but-still-fatal>, Matt S. Trout gives an example of an indirect construct that can cause a particularly bewildering error.
  54
  55 It currently does not warn for core functions (C<print>, C<say>, C<exec> or C<system>).
  56 This may change in the future, or may be added as optional features that would be enabled by passing options to C<unimport>.
  57
  58 This module is B<not> a source filter.
  59
  60 =cut
  61
  62 BEGIN {
  63  if ($ENV{PERL_INDIRECT_PM_DISABLE}) {
  64   *_tag = sub ($) { 1 };
  65   *I_THREADSAFE = sub () { 1 };
  66   *I_FORKSAFE   = sub () { 1 };
  67  } else {
  68   require XSLoader;
  69   XSLoader::load(__PACKAGE__, $VERSION);
  70  }
  71 }
  72
  73 =head1 METHODS
  74
  75 =head2 C<< unimport [ 'global', hook => $hook | 'fatal' ] >>
  76
  77 Magically called when C<no indirect @opts> is encountered.
  78 Turns the module on.
  79 The policy to apply depends on what is first found in C<@opts> :
  80
  81 =over 4
  82
  83 =item *
  84
  85 If it is a string that matches C</^:?fatal$/i>, the compilation will croak on the first indirect syntax met.
  86
  87 =item *
  88
  89 If the key/value pair C<< hook => $hook >> comes first, C<$hook> will be called for each error with a string representation of the object as C<$_[0]>, the method name as C<$_[1]>, the current file as C<$_[2]> and the line number as C<$_[3]>.
  90 If and only if the object is actually a block, C<$_[0]> is assured to start by C<'{'>.
  91
  92 =item *
  93
  94 If none of C<fatal> and C<hook> are specified, a warning will be emitted for each indirect construct.
  95
  96 =item *
  97
  98 If C<@opts> contains a string that matches C</^:?global$/i>, the pragma will be globally enabled for B<all> code compiled after the current C<no indirect> statement, except for code that is in the lexical scope of C<use indirect>.
  99 This option may come indifferently before or after the C<fatal> or C<hook> options, in the case they are also passed to L</unimport>.
 100
 101 The global policy applied is the one resulting of the C<fatal> or C<hook> options, thus defaults to a warning when none of those are specified :
 102
 103     no indirect 'global';                # warn for any indirect call
 104     no indirect qw<global fatal>;        # die on any indirect call
 105     no indirect 'global', hook => \&hook # custom global action
 106
 107 Note that if another policy is installed by a C<no indirect> statement further in the code, it will overrule the global policy :
 108
 109     no indirect 'global';  # warn globally
 110     {
 111      no indirect 'fatal';  # throw exceptions for this lexical scope
 112      ...
 113      require Some::Module; # the global policy will apply for the
 114                            # compilation phase of this module
 115     }
 116
 117 =back
 118
 119 =cut
 120
 121 sub unimport {
 122  shift;
 123
 124  my $hook;
 125  my $global;
 126  while (@_) {
 127   my $arg = shift;
 128   if ($arg eq 'hook') {
 129    last if $hook;
 130    $hook = shift;
 131   } elsif ($arg =~ /^:?fatal$/i) {
 132    last if $hook;
 133    $hook = sub { die msg(@_) };
 134   } elsif ($arg =~ /^:?global$/i) {
 135    $global = 1;
 136   }
 137  }
 138  $hook = sub { warn msg(@_) } unless defined $hook;
 139
 140  $^H |= 0x00020000;
 141  if ($global) {
 142   delete $^H{+(__PACKAGE__)};
 143   _global($hook);
 144  } else {
 145   $^H{+(__PACKAGE__)} = _tag($hook);
 146  }
 147
 148  ();
 149 }
 150
 151 =head2 C<import>
 152
 153 Magically called at each C<use indirect>. Turns the module off.
 154
 155 As explained in L</unimport>'s description, an C<use indirect> statement will lexically override a global policy previously installed by C<no indirect 'global', ...> (if there's one).
 156
 157 =cut
 158
 159 sub import {
 160  $^H{+(__PACKAGE__)} = _tag(undef);
 161  ();
 162 }
 163
 164 =head1 FUNCTIONS
 165
 166 =head2 C<msg $object, $method, $file, $line>
 167
 168 Returns the default error message generated by C<indirect> when an invalid construct is reported.
 169
 170 =cut
 171
 172 sub msg {
 173  my $obj = $_[0];
 174
 175  join ' ', "Indirect call of method \"$_[1]\" on",
 176            ($obj =~ /^\s*\{/ ? "a block" : "object \"$obj\""),
 177            "at $_[2] line $_[3].\n";
 178 };
 179
 180 =head1 CONSTANTS
 181
 182 =head2 C<I_THREADSAFE>
 183
 184 True iff the module could have been built with thread-safety features enabled.
 185
 186 =head2 C<I_FORKSAFE>
 187
 188 True iff this module could have been built with fork-safety features enabled.
 189 This will always be true except on Windows where it's false for perl 5.10.0 and below .
 190
 191 =head1 DIAGNOSTICS
 192
 193 =head2 C<Indirect call of method "%s" on object "%s" at %s line %d.>
 194
 195 The default warning/exception message thrown when an indirect call on an object is found.
 196
 197 =head2 C<Indirect call of method "%s" on a block at %s line %d.>
 198
 199 The default warning/exception message thrown when an indirect call on a block is found.
 200
 201 =head1 ENVIRONMENT
 202
 203 =head2 C<PERL_INDIRECT_PM_DISABLE>
 204
 205 If this environment variable is set to true when the pragma is used for the first time, the XS code won't be loaded and, although the C<'indirect'> lexical hint will be set to true in the scope of use, the pragma itself won't do anything.
 206 In this case, the pragma will always be considered to be thread-safe, and as such L</I_THREADSAFE> will be true.
 207 This is useful for disabling C<indirect> in production environments.
 208
 209 Note that clearing this variable after C<indirect> was loaded has no effect.
 210 If you want to re-enable the pragma later, you also need to reload it by deleting the C<'indirect.pm'> entry from C<%INC>.
 211
 212 =head1 CAVEATS
 213
 214 The implementation was tweaked to work around several limitations of vanilla C<perl> pragmas : it's thread safe, and does not suffer from a C<perl 5.8.x-5.10.0> bug that causes all pragmas to propagate into C<require>d scopes.
 215
 216 Before C<perl> 5.12, C<meth $obj> (no semicolon) at the end of a file is not seen as an indirect object syntax, although it is as soon as there is another token before the end (as in C<meth $obj;> or C<meth $obj 1>).
 217 If you use C<perl> 5.12 or greater, those constructs are correctly reported.
 218
 219 With 5.8 perls, the pragma does not propagate into C<eval STRING>.
 220 This is due to a shortcoming in the way perl handles the hints hash, which is addressed in perl 5.10.
 221
 222 The search for indirect method calls happens before constant folding.
 223 Hence C<my $x = new Class if 0> will be caught.
 224
 225 =head1 DEPENDENCIES
 226
 227 L<perl> 5.8.1.
 228
 229 A C compiler.
 230 This module may happen to build with a C++ compiler as well, but don't rely on it, as no guarantee is made in this regard.
 231
 232 L<XSLoader> (standard since perl 5.006).
 233
 234 =head1 AUTHOR
 235
 236 Vincent Pit, C<< <perl at profvince.com> >>, L<http://www.profvince.com>.
 237
 238 You can contact me by mail or on C<irc.perl.org> (vincent).
 239
 240 =head1 BUGS
 241
 242 Please report any bugs or feature requests to C<bug-indirect at rt.cpan.org>, or through the web interface at L<http://rt.cpan.org/NoAuth/ReportBug.html?Queue=indirect>.
 243 I will be notified, and then you'll automatically be notified of progress on your bug as I make changes.
 244
 245 =head1 SUPPORT
 246
 247 You can find documentation for this module with the perldoc command.
 248
 249     perldoc indirect
 250
 251 Tests code coverage report is available at L<http://www.profvince.com/perl/cover/indirect>.
 252
 253 =head1 ACKNOWLEDGEMENTS
 254
 255 Bram, for motivation and advices.
 256
 257 Andrew Main and Florian Ragwitz, for testing on real-life code and reporting issues.
 258
 259 =head1 COPYRIGHT & LICENSE
 260
 261 Copyright 2008,2009,2010,2011 Vincent Pit, all rights reserved.
 262
 263 This program is free software; you can redistribute it and/or modify it under the same terms as Perl itself.
 264
 265 =cut
 266
 267 1; # End of indirect